Is it possible to insert a JPG in a free form report? I am doing a form letter and we have a JPG of the exec's signature that we want to place in it. Thanks!

This message has been edited. Last edited by: <Kathryn Henning>,

Have you given it a try?

"<6>Please contact your agent regarding these changes and any questions you may have. "
""<6>Sincerely, "
" "
" "<- image goes here
" "

tried "tried "image=jsd_signature.jpg"
tried image=jsd_signature.jpg (no double quotes)
tried image=IBFS:/servername/DEV_folder/applicationfolder/jsd_signature.jpg

I do not get an error whey I try the above...it simply doesn't put the jpg image there...thanks

This example creates a free-form PDF report:

SET PAGE=NOPAGE

TABLE FILE EMPLOYEE

HEADING
"<13>EMPLOYEE EDUCATION HOURS REPORT"
"<14>FOR THE <DEPARTMENT DEPARTMENT"
"</2"
"EMPLOYEE NAME:    <23><FIRST_NAME <LAST_NAME>"
"EMPLOYEE ADDRESS: <23><ADDRESS_LN1>"
"<23><ADDRESS_LN2>"
"<23><ADDRESS_LN3>"
"</1"
"JOB CODE: <JOBCODE>"
"JOB DESCRIPTION: <JOB_DESC>"
"</1"
"MOST RECENT COURSE TAKEN ON: <MAX.DATE_ATTEND>"
"TOTAL NUMBER OF EDUCATION HOURS: <ED_HRS>"

BY DEPARTMENT NOPRINT
BY EMP_ID NOPRINT PAGE-BREAK

FOOTING
"<15>PRIVATE AND CONFIDENTIAL"

ON TABLE NOTOTAL

ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='Letter', LEFTMARGIN=0.5, TOPMARGIN=0.5, SQUEEZE=ON, ORIENTATION=PORTRAIT, $
TYPE=REPORT, GRID=OFF, FONT='Arial', SIZE=9, $

TYPE=HEADING, OBJECT=TEXT, STYLE=BOLD, $
TYPE=HEADING, OBJECT=FIELD, COLOR=BLUE, $
TYPE=HEADING, IMAGE=smplogo1.gif, POSITION=(5.0 0.0), $
ENDSTYLE

ON TABLE PCHOLD FORMAT PDF
END
-RUN

smplogo1.gif is an image found in the application path (one of the app folders). Unfortunately, different code is required if you want to embed an image in an HTML version of the report.

Link to the generated PDF: freeform1.pdf

Thanks so much. That did it!