Hi
I want to draw a line in my report ,
can anyone help me doing in this.
Thanks in advance

As in a subfooting or on a break in the sort? The UNDER-LINE option on a by field will give you a line.

No i want to devide the box with lines to get more number of boxses as the data can fit in individual box ,i want to make some thing like table in my report.

John,

What box do you want to divide with lines?

Could you please be more specific, what is the report format, HTML, PDF, EXL2K? If it's HTML, you can turn the GRID ON in the style sheet.

One example of lines and boxes:

TABLE FILE CAR
PRINT
*
HEADING
"WEBFOCUS REPORT"
WHERE READLIMIT EQ 100
WHERE RECORDLIMIT EQ 100
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLESHEET *
GRID=ON, FONT='ARIAL', SIZE=8, $
END

Another example:

TABLE FILE CAR
PRINT
*
HEADING
"WEBFOCUS REPORT"
WHERE READLIMIT EQ 100
WHERE RECORDLIMIT EQ 100
ON TABLE SET PAGE NOLEAD
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
BORDER=1, BORDER-COLOR=SILVER,
FONT='ARIAL', SIZE=8, $
END

As asked, what do you want to do?

TABLE FILE CAR
PRINT SALES
BY COUNTRY
BY CAR
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
TYPE=REPORT,BORDER=HEAVY,BORDER-STYLE=GROOVE,BORDER-COLOR=GREEN,$
TYPE=TITLE, BORDER=LIGHT, BORDER-STYLE=RIDGE, BORDER-COLOR=RED, $
TYPE=DATA, BORDER=LIGHT, BORDER-STYLE=SOLID, BORDER-COLOR=BLUE,$
ENDSTYLE
END

This is an old-style approach, as the new version of WF is supposed to have line/box-draw capabilities , but it's tried an true.
I have some images in our image library that are called HLINE, VLINE (for horizontal line and vertical line) and BOX. I can insert these images anywhere on the page with good precision and stretch them long and wide to whatever size and thickness I need. The image is placed in HEADING or FOOTING.
I also use UNDER_LINE for dynamic placement on sort fields and sometimes resort to defining a field that contains x number of underscores and placing it in subheads, subfoots, etc. This also looks nice in the finished output. (but is controlled by font size which is a pain sometimes, because 10 underscores in 12 point bold is much longer than 10 underscores in 8 point.)
I should mention that i only use these for PDF output. Locations are not necessarily respected for HTML output. But it makes excellent, professional-looking forms with boxes, grids, lines, etc.

I want to draw an horizontal line on my "HEADING".

Is there a solution to add this line on the STYLE * part of my report like this:

  
TYPE=HEADING, LINE=24, ... MY HORIZONTAL LINE,$

Thanks.

i wld suggest you to migrate to -HTMLFORM and do all formating over there....

I have ton generate a PDF report, I can't switch to HTML.

Jérény,

Try -

TYPE=HEADING, LINE=24, item=nn, STYLE=+UNDERLINE, $

T

I already tryed this but the line isn't complete, that underlines the content of the line but I want o draw an horizontal line on all the page.

try with Border option...
like

  
TYPE=HEADING,BORDER-TOP=OFF,BORDER-BOTTOM=LIGHT,BORDER-LEFT=OFF,BORDER-RIGHT=OFF,$

AND cntrol the thickness...i don't recall the exact syntax...see in GUI...

If that does not fit in...create a GIF and position it....

tks/sam

What abt this idea....

  
TABLE FILE CAR
PRINT 
     COUNTRY
ON TABLE SUBHEAD
"aaAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA"
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=TABHEADING,
     BORDER-BOTTOM=LIGHT,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     COLOR='WHITE',
$
ENDSTYLE
END

if you don't wanna go this way....go for image embedding....

Thx focuzsambit, but it's isn't thant I want. I will try to create a GIF.

Here is the solution I looked for:

object=box, name='line1', position = (1.0 1.0), dimension = (10.0 0.005), backcolor=NAVY, border-color=NAVY,$

Ah an underline across the page. In the old days I would create a blank field and print it as the last field on the line to get the underline to spread across the page without using some fancy code. It was such a pain to get the underline long enough in the 80 column partiioned data set days. Of course sometimes that is why the code still does what it does because of the grandfathering of the code.

When was OBJECT=BOX added to the WebFOCUS Style Sheet syntax?

I found the following on IBI Tech Support by doing a search on 'OBJECT=BOX'.

http://techsupport.informationbuilders.com/sps/30992016.html

Has anyone seen this before?

Searched the 1446 page Creating Reports With WebFOCUS Language v7.6 documentation and did not find object=box.

The only object stuff I found were the usual object=text|field styling subtype and some HTML Active report styling like TYPE=REPORT,OBJECT=MENU, etc.

I did find this ACROSS related thing that may come in handy:

Controlling Underlines for ACROSS Objects

SET ACROSSLINE= (ON|OFF|SKIP)

I can't see what that does and how it relates to "How to remove the extra line spacing in the SUBFOOT?".

I changed the position and dimensions and it still looks the same.

And what does "How to remove the extra line spacing in the SUBFOOT" mean?

Francis,

I don't think the article was meant to be, in any way, about the OBJECT=BOX. More likely to be the TYPE=FOOTING, LINE=1, POSITION=(0, 10.5) used to move the text to the edge of the paper.

I think the object=box was used to highlight the area concerned?

T

IBI is hiding something. Take a look at the following code. I am able to run this with WF713.

TABLE FILE CAR
SUM RCOST DCOST
BY COUNTRY
BY CAR
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLESHEET *
TYPE=REPORT, COLUMN=COUNTRY, WRAP=1.00,$
TYPE=REPORT, COLUMN=CAR , WRAP=1.00,$
TYPE=REPORT, COLUMN=RCOST , WRAP=1.25,$
TYPE=REPORT, COLUMN=DCOST , WRAP=1.25,$
TYPE=REPORT, NAME='BOX001', OBJECT=BOX, POSITION=(0.200 0.400),
DIMENSION=(8.10 5.00),
BORDER-COLOR=RED, BORDER=HEAVY,
BACKCOLOR=RGB(212 212 212),$
TYPE=REPORT, NAME='BOX002', OBJECT=BOX, POSITION=(1.40 0.425),
DIMENSION=(1.20 4.75),
BORDER-COLOR=BLUE, BORDER=HEAVY,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX003', OBJECT=BOX, POSITION=(2.70 0.425),
DIMENSION=(1.40 4.75),
BORDER-COLOR=GREEN, BORDER=HEAVY,
BACKCOLOR=YELLOW,$
ENDSTYLE
END

This message has been edited. Last edited by: mgrackin,

The only reference I could find to "object=box" was for the pdf layout painter.

Interesting.

"how to remove the extra line spacing in the subfoot" my reaction as well, Frankie. Its the hoch-gibberish i was talking about yesterday... i'm reading this manual from cover to cover ... its *loaded* with it...

Susannah,

Put the manual down and step away ....

Then go and live a little

T

hey...you been talking to Mike????

I did more testing and apparently OBJECT=STRING and OBJECT=IMAGE work in the WF StyleSheet as well.

Try the code below:

TABLE FILE CAR
SUM RCOST DCOST
BY COUNTRY
BY CAR
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLESHEET *
TYPE=REPORT, TOPMARGIN=1.25,$
TYPE=REPORT, COLUMN=COUNTRY, WRAP=1.00,$
TYPE=REPORT, COLUMN=CAR , WRAP=1.00,$
TYPE=REPORT, COLUMN=RCOST , WRAP=1.25,$
TYPE=REPORT, COLUMN=DCOST , WRAP=1.25,$
TYPE=REPORT, NAME='STR001', OBJECT=STRING,
TEXT='Draft Copy. Do Not Distribute &DATE',
POSITION=(2.25 7.00),
FONT='ARIAL', SIZE=24,$
TYPE=REPORT, NAME='GIF001', OBJECT=IMAGE,
IMAGE='nistbanner.gif',
POSITION=(0.225 0.225),
DIMENSION=(3.00 0.50),$
TYPE=REPORT, NAME='BOX001', OBJECT=BOX,
POSITION=(0.175 0.175),
DIMENSION=(8.15 10.65),
BORDER-COLOR=RED, BORDER=15,
BACKCOLOR=SILVER,$
TYPE=REPORT, NAME='BOX002', OBJECT=BOX,
POSITION=(1.40 1.425),
DIMENSION=(1.20 4.75),
BORDER-COLOR=BLUE, BORDER=HEAVY,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX003', OBJECT=BOX,
POSITION=(2.70 1.425),
DIMENSION=(1.40 4.75),
BORDER-COLOR=GREEN, BORDER=HEAVY,
BACKCOLOR=YELLOW,$
ENDSTYLE
END

Very nice Mickey. Also try FORMAT DHTML.....