Border is not working in TABFOOTING.

TABLE FILE CAR
ON TABLE SUBHEAD
"Page HEADING
"COUNTRY "
BY COUNTRY
ON TABLE SUBFOOT
""******TEST****"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=HEADING,BORDER-TOP=1.0,BORDER-BOTTOM=1.0,BORDER-STYLE=SOLID,$
TYPE=TABFOOTING,LINE=3,BORDER-TOP=1.0,BORDER-BOTTOM=1.0,BORDER-STYLE=SOLID,$
ENDSTYLE
END
-RUN

This message has been edited. Last edited by: WFDevConsultant,

8.2.06
Windows, All Formats

In this example there is no line 3. If you take that out it works, along with the extra "

works fine.
probably b/c you are asking for the border around line 3, but you only have 1 line in your tabfooting, and you have one too many " in that line.

Hey Susannah!

I agree with what you are saying but I want to get the border on the alternate lines. See the code below.

TABLE FILE CAR
ON TABLE SUBHEAD
"Page HEADING
"COUNTRY "
BY COUNTRY
ON TABLE SUBFOOT
"testing the border"
" NO BORDER NEEDED"
"******TEST****"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=HEADING,BORDER-TOP=1.0,BORDER-BOTTOM=1.0,BORDER-STYLE=SOLID,$
TYPE=TABFOOTING,LINE=1,BORDER-TOP=1.0,BORDER-BOTTOM=1.0,BORDER-STYLE=SOLID,$
TYPE=TABFOOTING,LINE=3,BORDER-TOP=1.0,BORDER-BOTTOM=1.0,BORDER-STYLE=SOLID,$
ENDSTYLE
END
-RUN

8.2.06
Windows, All Formats

Not sure that it's feasible what you're requesting but if it's to highlight some footing and not others, the following maybe an alternative where you use the Alignment grid option and color pattern.

TABLE FILE CAR
BY  CAR.ORIGIN.COUNTRY
ON TABLE SUBHEAD
"Page HEADING"
"COUNTRY"
ON TABLE SUBFOOT
"testing the border"
" NO BORDER NEEDED"
"******TEST****"
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
$
TYPE=TABFOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     COLOR='WHITE',
     BACKCOLOR='SILVER',
     JUSTIFY=LEFT,
     WIDTH=2.000,
$
TYPE=TABFOOTING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=2.000,
$
TYPE=TABFOOTING,
     LINE=3,
     OBJECT=TEXT,
     ITEM=1,
     COLOR='WHITE',
     BACKCOLOR=RGB(51 102 255),
     JUSTIFY=LEFT,
     WIDTH=2.000,
$
TYPE=HEADING,
     BORDER-TOP=1.00,
     BORDER-BOTTOM=1.00,
     BORDER-TOP-STYLE=SOLID,
     BORDER-BOTTOM-STYLE=SOLID,
     BORDER-LEFT-STYLE=SOLID,
     BORDER-RIGHT-STYLE=SOLID,
$
ENDSTYLE
END
-RUN

I am trying to achieve the following.

=============================================
Total count of main items - 150
============================================

OTHER ITEM Count
============================================
Other items count - 50
============================================

I can get this by doing the below code but I want to use BORDER instead of "===".

ON TABLE SUBFOOT
"=========================================="
"Total count of main items "=========================================="
""OTHER ITEM COUNT"
"=========================================="
"Other item count "==========================================="

8.2.06
Windows, All Formats

Adding borders to individual lines in a heading, subheading etc. is not supported. However, as is often the case, there is a way of making it look as you want, messy though it is:

TABLE FILE CAR
BY  CAR.ORIGIN.COUNTRY
ON TABLE SUBHEAD
"Page <TABPAGENO"
HEADING
"COUNTRY"
ON TABLE SUBFOOT
" "
"Total count of main items - 150"
" "
" "
"OTHER ITEM Count"
" "
"Other items count - 50"
" "
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=PTS,
$
TYPE=TABFOOTING,
     LINE=1,
     BACKCOLOR='BLACK',
     SIZE=1,
     TOPGAP=0.000,
     BOTTOMGAP=0.000,
$
TYPE=TABFOOTING,
     LINE=2,
     TOPGAP=3.500,
     BOTTOMGAP=2.000,
     BACKCOLOR='WHITE',
$
TYPE=TABFOOTING,
     LINE=3,
     BACKCOLOR='BLACK',
     SIZE=1,
     TOPGAP=0.000,
     BOTTOMGAP=0.000,
$
TYPE=TABFOOTING,
     LINE=4,
     BACKCOLOR='WHITE',
     TOPGAP=3.500,
     BOTTOMGAP=3.000,
$
TYPE=TABFOOTING,
     LINE=5,
     BACKCOLOR='WHITE',
     TOPGAP=3.000,
     BOTTOMGAP=3.000,
$
TYPE=TABFOOTING,
     LINE=6,
     BACKCOLOR='BLACK',
     SIZE=1,
     TOPGAP=0.000,
     BOTTOMGAP=0.000,
$
TYPE=TABFOOTING,
     LINE=7,
     BACKCOLOR='WHITE',
     TOPGAP=3.500,
     BOTTOMGAP=3.000,
$
TYPE=TABFOOTING,
     LINE=8,
     BACKCOLOR='BLACK',
     SIZE=1,
     TOPGAP=0.000,
     BOTTOMGAP=0.000,
$
TYPE=TABFOOTING,
     LINE=9,
     BACKCOLOR='WHITE',
     TOPGAP=4.000,
     BOTTOMGAP=0.000,
$
TYPE=HEADING,
     BORDER-TOP=1.00,
     BORDER-BOTTOM=1.00,
     BORDER-TOP-STYLE=SOLID,
     BORDER-BOTTOM-STYLE=SOLID,
     BORDER-LEFT-STYLE=SOLID,
     BORDER-RIGHT-STYLE=SOLID,
$
ENDSTYLE
END

Thanks Alan. That works.

Thanks Alan. That works