Hi Everyone.!

so I am back again with a small issue and need your help.

Its that I want the '%' sign to display in a particular column and also in the subfoot while doing subtotal i want the '%' sign to be displayed in that column.

I am using the below code for that, it is displaying '%' sign in subfoot only in HTML format

and not in EXL2K format. I want it to be thr in EXL2K format. so how should I do that. Please suggest.

 

DEFINE FILE CAR
FUEL_CAP_N/I3% = FUEL_CAP;
END

TABLE FILE CAR
PRINT
FUEL_CAP_N
SALES
BY COUNTRY
BY MODEL

ON COUNTRY SUBFOOT
"<COUNTRY<+0>TOTAL<+0><ST.FUEL_CAP_N<+0><ST.SALES"

ON TABLE PCHOLD FORMAT EXL2K

ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=OFF,
     ORIENTATION=PORTRAIT,
  BORDER=ON,
$

TYPE=SUBFOOT,
 HEADALIGN=BODY,
  STYLE=BOLD,
   JUSTIFY=CENTER,
   BACKCOLOR=SILVER,
$
TYPE=SUBFOOT,
BY=COUNTRY,
ITEM=1,
JUSTIFY=CENTER,
COLSPAN=1,
$
TYPE=SUBFOOT,
BY=COUNTRY,
ITEM=2,
JUSTIFY=CENTER,
COLSPAN=1,
$

TYPE=SUBFOOT,
BY=COUNTRY,
OBJECT=FIELD,
COLSPAN=1,
JUSTIFY=CENTER,
$

ENDSTYLE
END
-EXIT

 

if m giving:-
ON TABLE PCHOLD FORMAT HTML
then % sign is coming in subfoot otherwise not.

This message has been edited. Last edited by: Kerry,

DEFINE FILE CAR
FUEL_CAP_N/I3% = FUEL_CAP;
END

TABLE FILE CAR
PRINT
FUEL_CAP_N
SALES
BY COUNTRY
BY MODEL

ON COUNTRY SUBFOOT
"<COUNTRY TOTAL <ST.FUEL_CAP_N<ST.SALES"

ON TABLE PCHOLD FORMAT HTML

ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN, SQUEEZE=OFF, ORIENTATION=PORTRAIT, BORDER=ON,$

TYPE=SUBFOOT, HEADALIGN=BODY, STYLE=BOLD, BACKCOLOR=SILVER,$

TYPE=SUBFOOT, ITEM=1, POSITION=N1, $
TYPE=SUBFOOT, ITEM=2, POSITION=N2, $
TYPE=SUBFOOT, ITEM=3, POSITION=N3, JUSTIFY=RIGHT, $
TYPE=SUBFOOT, ITEM=4, POSITION=N4, JUSTIFY=RIGHT, $

ENDSTYLE
END

The % appears in the subtotal of HTML, PDF and EXL2K versions of the report.
HEADALIGN is used for HTML and EXL2K alignment.
POSITION is used for PDF alignment.

You have to be careful about counting the objects in the subfoot (a blank may be counted as an object).
HTML


PDF


EXL2K


The only thing I can't explain is why the subfoot styling expands past the right edge of the report columns in the PDF version.

Thanks Francis,

I copy pasted your code as it is, just changed:-

 
ON TABLE PCHOLD FORMAT EXL2K
 

but still I am not getting that % sign in subfoot on FUEL_CAP_N column

Both versions work for me. Maybe it is your release. You might need to open a case.

Francis, did you test in 7.6 as I did?

I tested this on v7.6.5 and v5.3.2.

Francis,

SQUEEZE=ON will fix the issue with the SUBFOOT strectching past the right edge.

Thank you Mickey!

Thanks Francis, Ginny n Mickey.

So it seems to be the problem with my WebFOCUS version 7.1.4

Can anyone please test it in WF 7.1.4 and suggest me the appropriate solution. Any help appreciated.

Hi again..

one more problem regarding the same code..
When the subtotal value for "FUEL_CAP_N" column exceeds 100 then I want to display the value in the subfoot as 100 only, otherwise the actual value..

for example in the output of the code above, in the last subfoot row for country = W GERMANY, the subtotal value for FUEL_CAP_N is 116, so I want to display 100 whenever value exceeds 100.
Please help!!

You need to use RECAP

 
TABLE FILE CAR
PRINT
FUEL_CAP_N
SALES
BY COUNTRY
BY MODEL
ON COUNTRY RECAP SUBTOTVAL/I3%= IF FUEL_CAP_N GT 100 THEN 100 ELSE FUEL_CAP_N;

ON COUNTRY SUBFOOT
"<COUNTRY TOTAL <SUBTOTVAL<ST.SALES" 

Thanks JG