I am trying to run a table request into a save file and read the value in the save file into an &VAR via loop, my question is how can I change the &VAR to read into &VAR1, &VAR2, &VAR3, ect depending on the number of the count.

Here is an example of what I'm trying to accomplish:

DEFINE FILE CAR
CNTR/I2 WITH MODEL = CNTR + 1;
END

TABLE FILE CAR
BY CNTR
BY MODEL
ON TABLE HOLD AS MODEL
END

-RUN

-SET &ENDCNT = &LINES;
-SET &LOOPCNTR = 1;
-REPEAT ENDREPEAT &ENDCNT TIMES
TABLE FILE MODEL
PRINT MODEL
WHERE CNTR EQ '&LOOPCNTR'
ON TABLE SAVE AS SAVEMODEL
END
-RUN
-READ SAVEMODEL, &VAR
-SET &LOOPCNTR = &LOOPCNTR + 1;
-ENDREPEAT

Eric

This may do the job:

-SET &ECHO=ALL;
SET HOLDFORMAT=ALPHA
-RUN

TABLE FILE CAR
SUM
MODEL
BY MODEL NOPRINT
ON TABLE HOLD AS HMODEL
END
-RUN

-SET &MODEL_COUNT = &LINES;

-REPEAT ENDREP1 FOR &N FROM 1 TO &MODEL_COUNT STEP 1;

-READ HMODEL &MODEL.&N.A24

-ENDREP1

-? &MODEL

That's exactly what I needed, I also never even knew about the -? either.

Thanks!

Eric