I've created a simple PDF report with subtotals placed within subfooting. My table spans anywhere from 1/2 the page width to a full page width. No matter what the width of the table my subfooting always spans accross the entire page. Does anyone know how to set the subfooting width = to the width of the data grid?

There's no "grid" in a PDF report, unlike HTML and Excel. What have you coded in the SUBFOOT? Could you post the code?

Sorry, I'm very new to WebFocus. I'm still learning the lingo.

Here's what I've done thus far...

 TABLE FILE VW_4PRS
PRINT 
     OUTCOME
     TOTAL
BY PROGRAMTYPE
BY REFERRALSOURCE
BY REFERRALSUMMARY
     
ON PROGRAMTYPE SUBFOOT
"SUBTOTAL <PROGRAMTYPE <ST.TOTAL"
     
ON REFERRALSOURCE SUBFOOT
"SUBTOTAL <REFERRALSOURCE <ST.TOTAL"
     
ON REFERRALSUMMARY SUBFOOT
"SUBTOTAL <REFERRALSUMMARY <ST.TOTAL"
HEADING
" "
"Report Title Goes Here"
"Reporting Period from 11/01/04 to 12/31/04"
" "
" "
FOOTING BOTTOM
" "
"Page <TABPAGENO"
"Produced on <+0>&DATEtrMDYY <+0> "
"The information contained in this report is proprietary and confidential."
ON TABLE SET PAGE-NUM OFF 
ON TABLE SET EXPANDABLE ON 
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=9,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=DATA,
     HGRID=ON,
     VGRID=OFF,
$
TYPE=TITLE,
     HGRID=ON,
     VGRID=OFF,
     COLOR='BLACK',
     BACKCOLOR=RGB(205 238 162),
$
TYPE=HEADING,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=16,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=.194,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     WIDTH=8.250,
$
TYPE=HEADING,
     LINE=3,
     SIZE=10,
$
TYPE=HEADING,
     LINE=3,
     OBJECT=TEXT,
     ITEM=1,
     WIDTH=8.250,
$
TYPE=HEADING,
     LINE=4,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=.194,
$
TYPE=HEADING,
     LINE=5,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=.194,
$
TYPE=HEADING,
     IMAGE=logo.gif,
     POSITION=(-0.055556 -0.013889),
     SIZE=(1.847222 1.208333),
$
TYPE=HEADING,
     IMAGE=OrangeLine.gif,
     POSITION=(+1.916667 +0.791667),
     SIZE=(6.000000 0.013889),
$
TYPE=FOOTING,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=8,
$
TYPE=FOOTING,
     IMAGE=logoNBHFooter.gif,
     POSITION=(+6.638889 +0.013889),
     SIZE=(1.430556 0.625000),
$
TYPE=SUBFOOT,
     BACKCOLOR=RGB(245 252 237),
$
TYPE=SUBFOOT,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     POSITION='N5',
$
TYPE=SUBFOOT,
     BY=2,
     POSITION='N2',
$
TYPE=SUBFOOT,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     POSITION='N5',
$
TYPE=SUBFOOT,
     BY=3,
     POSITION='N3',
$
TYPE=SUBFOOT,
     BY=3,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     POSITION='N5',
$
TYPE=GRANDTOTAL,
     HGRID=HEAVY,
     VGRID=OFF,
     BACKCOLOR=RGB(205 238 162),
$
ENDSTYLE
END

I ran your code with slight modifications and created a snapshot of the result. I had to comment the EXPANDABLE setting as I am running on v5.3.

What is the issue?

-SET &ECHO=ALL;

TABLE FILE CAR

PRINT 
     RETAIL_COST
     SALES
BY COUNTRY
BY CAR
BY MODEL
     
ON COUNTRY SUBFOOT
"SUBTOTAL <COUNTRY <ST.SALES"
     
ON CAR SUBFOOT
"SUBTOTAL <CAR <ST.SALES"
     
ON MODEL SUBFOOT
"SUBTOTAL <MODEL <ST.SALES"
HEADING
" "
"Report Title Goes Here"
"Reporting Period from 11/01/04 to 12/31/04"
" "
" "
FOOTING BOTTOM
" "
"Page <TABPAGENO"
"Produced on <+0>&DATEtrMDYY <+0> "
"The information contained in this report is proprietary and confidential."
ON TABLE SET PAGE-NUM OFF 
-*ON TABLE SET EXPANDABLE ON 
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=9,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=DATA,
     HGRID=ON,
     VGRID=OFF,
$
TYPE=TITLE,
     HGRID=ON,
     VGRID=OFF,
     COLOR='BLACK',
     BACKCOLOR=RGB(205 238 162),
$
TYPE=HEADING,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=16,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=.194,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     WIDTH=8.250,
$
TYPE=HEADING,
     LINE=3,
     SIZE=10,
$
TYPE=HEADING,
     LINE=3,
     OBJECT=TEXT,
     ITEM=1,
     WIDTH=8.250,
$
TYPE=HEADING,
     LINE=4,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=.194,
$
TYPE=HEADING,
     LINE=5,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=.194,
$
TYPE=HEADING,
     IMAGE=CANADA_FLAG.jpg,
     POSITION=(-0.055556 -0.013889),
     SIZE=(1.847222 1.208333),
$
TYPE=HEADING,
     IMAGE=CANADA_FLAG.jpg,
     POSITION=(+1.916667 +0.791667),
     SIZE=(6.000000 0.013889),
$
TYPE=FOOTING,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=8,
$
TYPE=FOOTING,
     IMAGE=CANADA_FLAG.jpg,
     POSITION=(+6.638889 +0.013889),
     SIZE=(1.430556 0.625000),
$
TYPE=SUBFOOT,
     BACKCOLOR=RGB(245 252 237),
$
TYPE=SUBFOOT,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     POSITION='N5',
$
TYPE=SUBFOOT,
     BY=2,
     POSITION='N2',
$
TYPE=SUBFOOT,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     POSITION='N5',
$
TYPE=SUBFOOT,
     BY=3,
     POSITION='N3',
$
TYPE=SUBFOOT,
     BY=3,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     POSITION='N5',
$
TYPE=GRANDTOTAL,
     HGRID=HEAVY,
     VGRID=OFF,
     BACKCOLOR=RGB(205 238 162),
$
ENDSTYLE
END

The issue is the subfooting extends past the Total column. Notice the light green coloring that spans the width of the page. I'm trying to have the subfooting's right edge align with the right edge of the last column, in this case the Total column.

Thanks,
Michael

It appears that it's the "WIDTH=8.250" in the HEADING style that's causing the SUBFOOT to span the width of the report. Try removing the WIDTH=8.250. I'm not sure you need the WIDTH tags...

I tend to use combinations to suit most output formats that my client uses (HTML, PDF or EXL2K - don't give the users too much or they will want more ) so that I issue a width value. To control this I have a variable called &Orientation which is defaulted to PORTRAIT. In my style sheets I have something like -

-SET &Page_Width = IF &Orientation EQ 'LANDSCAPE' THEN '11.10' ELSE '7.70';
  TYPE=HEADING, GRID=ON, WIDTH=&Page_Width, $
  TYPE=HEADING, LINE=1, ITEM=1, CLASS=Headline1, WIDTH=&Page_Width, JUSTIFY=LEFT, STYLE=BOLD, SIZE=&Size_14, $

This suits most situations in controlling components widths in PDF output, just add the line for your component (e.g. TYPE=TABFOOTING etc.).

T

p.s. Bear in mind that our page size is A4 not LETTER.

Francis,
Here's the issue with removing the width in the Header. I'm centering the header text based on the width of the page (8.25"). If I remove the width tag the header text is no longer centered on the page. So I'm stuck with the issue of centering the Header text if I remove the width tags ...

Tony,
I'm not sure this will help either now that Francis has pointed out the issue. Do you know a way to make the data portion of the report span the entire page width? In other words, since I have the header set to 8.25 and the subfoot is using the same width why don't I just set the width of the data to 8.25? I guess I'll need to set each column to a specific width to accomplish this. What do you think?

Thanks,
Michael

Michael,

That's what I normally do. Of course it helps if you have a set number of columns otherwise you have to get messy with pre processing to determine column numbers and then decide on the WIDTH for each one.

T