I am trying to set up a procedure which can switch between an Accordian report and an Autodrill report. The Accordian comes up without a problem however the Autodrill fails with a message: "Error code is: 32027Could not get error message".
Codee using the CAR file follows.

-OLAP &OLAP_ON_OFF
-*Set&OLAP_ON_OFF to "ON" (Autodrill) or "OFF" (Accordian) and &AD_FLAG to 1 (Accordian) or 2 (Autodrill)

-*-DEFAULT &AD_FLAG = 1, &RP_FN01B_Sort1 = 'CAR.ORIGIN.COUNTRY BY CAR.COMP.CAR BY CAR.CARREC.MODEL BY CAR';

-SET &RP_NEW = CTRAN(&RP_FN01B_Sort1.LENGTH, &RP_FN01B_Sort1, 32, 44, 'A200');
-SET &RP_NEW1 = STRREP (&RP_FN01B_Sort1.LENGTH, &RP_FN01B_Sort1, 4, ' BY ', 2, ', ', 200, 'A200');

-SET &RP_LN = &RP_NEW.LENGTH;
-SET &NEW_BY = GETTOK(&RP_NEW, &RP_LN, 1, ',', 200, 'A200');

-* The variables below are to turn on or off code for used for Autodrill or for Accorian reports
-SET &LOC = 'Location: ' | &RP_NEW1 || ';';
-SET &CMT1 = IF &AD_FLAG EQ 1 THEN '' ELSE '-*';
-SET &CMT2 = IF &AD_FLAG EQ 1 THEN '-*' ELSE '';

&CMT1.EVAL SET EXPANDBYROW ON
-*When Autodrill is selected the fex fails at this point with "Error code is: 32027Could not get error message"
&CMT2.EVAL OLAP DIMENSIONS
&CMT2.EVAL DIMENSIONS FILE CAR
&CMT2.EVAL &LOC

TABLE FILE CAR
SUM
     CAR.BODY.SEATS
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
&CMT2.EVAL BY  LOWEST &NEW_BY
&CMT1.EVAL BY  LOWEST &RP_FN01B_Sort1.(BY(<COUNTRY,CAR.ORIGIN.COUNTRY>,<CAR,CAR.COMP.CAR>,<MODEL,CAR.CARREC.MODEL>,<BODYTYPE,CAR.BODY.BODYTYPE>)).Please select sort field(s).
&CMT1.EVAL ON TABLE SET ONFIELD IGNORE
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
&CMT1.EVAL ON TABLE SET EXPANDABLE ON
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
&CMT2.EVAL ON TABLE SET AUTODRILL ON
&CMT2.EVAL ON TABLE SET OLAPPANE NONE
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
ENDSTYLE
END


  

This message has been edited. Last edited by: <Kathryn Henning>,

You forgot the END statement after your OLAP DIMENSIONS -

&CMT2.EVAL OLAP DIMENSIONS
&CMT2.EVAL DIMENSIONS FILE CAR
&CMT2.EVAL &LOC
&CMT2.EVAL END

T

Thank you Tony. I needed that look over the shoulder.