Given the following code example, how can I remove the spaces before each result line, so that each line in the heading has equal spacing?
Is there a more efficient or elegant way to achieve this type of formatting? (note: I do want to use this style sheet in my reports.)
TABLE FILE CAR
PRINT COUNTRY NOPRINT
COMPUTE V1/A3 = 'AAA'; NOPRINT
COMPUTE V2/A3 = 'BBB'; NOPRINT
COMPUTE V3/A3 = 'CCC'; NOPRINT
COMPUTE V4/A3 = 'DDD'; NOPRINT
COMPUTE V5/A3 = 'EEE'; NOPRINT
HEADING
"Title"
"Results 1: <V1"
"Results 2: <V2"
"Results 3: <V3"
"Results 4: <V4"
"Results 5: <V5"
"Results ALL: AAA BBB CCC DDD EEE"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
TYPE=HEADING,LINE=1,OBJECT=TEXT,ITEM=1,SIZE=8,JUSTIFY=LEFT,STYLE=BOLD+UNDERLINE,$
TYPE=HEADING,LINE=2,OBJECT=TEXT,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=2,OBJECT=FIELD,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=2,JUSTIFY=LEFT, $
TYPE=HEADING,LINE=3,OBJECT=TEXT,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=3,OBJECT=FIELD,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=3,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=4,OBJECT=TEXT,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=4,OBJECT=FIELD,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=4,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=5,OBJECT=TEXT,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=5,OBJECT=FIELD,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=5,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=6,OBJECT=TEXT,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=6,OBJECT=FIELD,ITEM=1,SIZE=8,$
TYPE=HEADING,LINE=6,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=7,OBJECT=TEXT,ITEM=1,SIZE=8,JUSTIFY=LEFT,$
END
This message has been edited. Last edited by: Joey Sandoval,
Prod/Dev: WebFOCUS 8.0.08 on Windows Server 2008/Tomcat , WebFOCUS DevStudio 8.0.08 on Windows 7 Pro
October 08, 2012, 10:38 PM
Dan Satchell
You can specify styling that applies to all lines of a heading and then specify additional styling for specific lines or parts of a line. See if this helps:
TABLE FILE CAR
PRINT COUNTRY NOPRINT
COMPUTE V1/A3 = 'AAA'; NOPRINT
COMPUTE V2/A3 = 'BBB'; NOPRINT
COMPUTE V3/A3 = 'CCC'; NOPRINT
COMPUTE V4/A3 = 'DDD'; NOPRINT
COMPUTE V5/A3 = 'EEE'; NOPRINT
HEADING
"Title"
"Results 1: <V1"
"Results 2: <V2"
"Results 3: <V3"
"Results 4: <V4"
"Results 5: <V5"
"Results ALL: <V1<V2<V3<V4<V5"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOPAGE
ON TABLE SET STYLE *
INCLUDE = endeflt,$
TYPE=REPORT,LEFTGAP=0.05,RIGHTGAP=0.05,$
TYPE=HEADING,SIZE=8,JUSTIFY=LEFT,HEADALIGN=BODY,$
TYPE=HEADING,LINE=1,STYLE=BOLD+UNDERLINE,$
ENDSTYLE
END
WebFOCUS 7.7.05
October 09, 2012, 09:42 AM
Joey Sandoval
Thank you Dan. I guess the Report Painter does not always create the most efficient formatting code to work with. I will use this going forward. Thanks again!
Prod/Dev: WebFOCUS 8.0.08 on Windows Server 2008/Tomcat , WebFOCUS DevStudio 8.0.08 on Windows 7 Pro
October 09, 2012, 09:57 AM
Joey Sandoval
Dan, when removing the NOPRINT commands from the computed field, dashes appear on the very first line for each column. How do you suppress that?
TABLE FILE CAR
PRINT COUNTRY NOPRINT
COMPUTE V1/A3 = 'AAA';
COMPUTE V2/A3 = 'BBB';
COMPUTE V3/A3 = 'CCC';
COMPUTE V4/A3 = 'DDD';
COMPUTE V5/A3 = 'EEE';
HEADING
"Title"
"LINE 1: <V1"
"LINE 2: <V2"
"LINE 3: <V3"
"LINE 4: <V4"
"LINE 5: <V5"
"ALL LINES: <V1<V2<V3<V4<V5"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOPAGE
ON TABLE SET STYLE *
INCLUDE = endeflt,$
TYPE=REPORT,LEFTGAP=0.05,RIGHTGAP=0.05,$
TYPE=HEADING,SIZE=8,JUSTIFY=LEFT,HEADALIGN=BODY,$
TYPE=HEADING,LINE=1,STYLE=BOLD+UNDERLINE,$
ENDSTYLE
END
Prod/Dev: WebFOCUS 8.0.08 on Windows Server 2008/Tomcat , WebFOCUS DevStudio 8.0.08 on Windows 7 Pro
October 09, 2012, 10:33 AM
jfr99
Not sure why, but change this line:
TYPE=HEADING,LINE=1,STYLE=BOLD+UNDERLINE,$
to this:
TYPE=HEADING,LINE=1,ITEM=1,STYLE=BOLD+UNDERLINE,$
and try again.
~Jim
WebFocus 8.201M, Windows, App Studio
October 09, 2012, 10:42 AM
Joey Sandoval
Thanks Jim. I guess that prevents blank spaces in each column from being underlined.
Prod/Dev: WebFOCUS 8.0.08 on Windows Server 2008/Tomcat , WebFOCUS DevStudio 8.0.08 on Windows 7 Pro