So, I know you can do a statement like this:

ON TABLE PCHOLD FORMAT PDF OPEN

and append one pdf to another. Wondering if you can do that in a regular hold file so that I can use it later on in the program.

I'm trying to create a hold file that will contain all the dates in between two dates... so the output would basically have one field, called "DATE" that would have a record for each date in between two dates. My beginning date might be 20100205 and my ending date might be 20100210 and my hold file would look like this:

DATE
20100205
20100206
20100207
20100208
20100209
20100210

My original thought was to create a loop... incrementing a variable by one on each iteration and using that in the HADD function. Something like:

DEFINE FILE CAR
BEG1/HYYMDS WITH BODYTYPE = DT(&BEG1 00:00:00.000);
END1/HYYMDS = DT(&END1 00:00:00.000);
ADD_DAY/HYYMDS = HADD(BEG1, 'DAY', &MYVAR, 8, 'HYYMDS');
END

This message has been edited. Last edited by: Mark1,

Look up the (APPEND option on the APP FI or FILEDEF command. I think that is exactly what you want.

You can also use the MORE command, i.e. Universal Concatenation.

quote:

Wondering if you can do that in a regular hold file so that I can use it later on in the program

That is not supported for a regular hold file. However, as Ginny mentions, you can FILEDEF a file with the (APPEND option. In this case, you could do everything you need with Dialogue Manager and you wouldn't even need to do a table file.

Here is an example of using Dialogue Manager to build the hold file and master. As coded here, these files are temporary and will disappear at the end of the session unless you create them in a permanent location. If you need to generate more than 100 dates, then you would need to increase the -REPEAT limit to something greater than 100.

APP FILEDEF DATEMAS DISK datedata.mas
-RUN
-WRITE DATEMAS FILENAME=DATEDATA,SUFFIX=FIX
-WRITE DATEMAS SEGNAME=DATEDATA,SEGTYPE=S0
-WRITE DATEMAS FIELDNAME=DATEVAL ,ALIAS=DATEVAL ,FORMAT=YYMD, ACTUAL=A8,$
-*
APP FI DATEDATA DISK datedata.ftm
-RUN
-SET &START_DATE = '20100205';
-SET &END_DATE   = '20100210';
-*
-REPEAT ENDREPEAT1 FOR &I FROM 0 TO 100
-SET &DATEVAL = AYMD(&START_DATE,&I,'I8');
-WRITE DATEDATA &DATEVAL
-IF &DATEVAL EQ &END_DATE GOTO QUITREPEAT1 ;
-ENDREPEAT1
-QUITREPEAT1
-RUN
-*
TABLE FILE DATEDATA
 PRINT DATEVAL
END

This message has been edited. Last edited by: Dan Satchell,

This is what I needed. Thanks for the help!