Hi, I'm new to focus converting from WF 7.1.7 to WF 7.7.04. I am assigned testing about 1,000 programs(fun, fun). Any this code works in 7.1.7 and bombs in 7.7.04??? No idea why. I tried lots of changes. The full error is. (FOC32498) FOCEXEC PARSER ERROR. INVALID SYMBOL: ;
0 ERROR AT OR NEAR LINE 889 IN PROCEDURE RORDLISTFOCEXEC *
(FOC003) THE FIELDNAME IS NOT RECOGNIZED: DESCR/A20

Help is GREATLY appreciated. They want this done yesterday. Think I should learn it overnite.
-*------------------------------------------------------------------------------
-* Generate the HTML output
-*------------------------------------------------------------------------------
-WRITE HTMLOUT <script LANGUAGE="JavaScript" ,
- SRC="/twgiapps/localsrv/html/usetsite.js">
-WRITE HTMLOUT

-WRITE HTMLOUT <script LANGUAGE="JavaScript" ,
- SRC="/twgiapps/CPTS/html/drillDn.js">
-WRITE HTMLOUT

-WRITE HTMLOUT <script language="JavaScript">< !--

-WRITE HTMLOUT function rDRSMini(PRJ_NBR) {
-WRITE HTMLOUT drillDn("rDRSMini","&FOCNAME..","&SUITS..","&PARM..",
-,"&USRPARMS..","ddPRJ_NBR",PRJ_NBR,"DBSERV_","&DBSERV_..");
-WRITE HTMLOUT }

-WRITE HTMLOUT function rPeople(ENGINEER_ID) {
-WRITE HTMLOUT drillDn("rPeople","&FOCNAME..","&SUITS..","&PARM..",
-,"&USRPARMS..","UPRMIGNORE","Y","ddSUITS",ENGINEER_ID);
-WRITE HTMLOUT }

-WRITE HTMLOUT // script ends here-->

DEFINE FILE HOLD
-* clear LF/CR from alpha fields
-SET &FLD_NAME = &DESCRIP ;
-SET &FLD_LEN = IF (&DESCRIP EQ 'PRJ_DESCR') THEN 40
- ELSE 25 ;
-INCLUDE UBCPALPH

-* Translate "(34) to space(32)
DESCR1 /A25 = CTRAN(25,NEW_&DESCRIP,34,32,DESCR1);

-* Translate CRLF(10) to space(32)
DESCR /A25 = CTRAN(25,DESCR1,10,32,DESCR);

-* clear LF/CR from alpha fields
-SET &FLD_NAME = 'REMARKS';
-SET &FLD_LEN = 50 ;
-INCLUDE UBCPALPH

-* assume trigger letter data exists if : or ; exists in remarks fld
TRL_LN1 /A128 = IF (NEW_REMARKS CONTAINS ';' OR ':')
THEN SUBSTR(50,NEW_REMARKS,1,50,50,TRL_LN1)
ELSE ' ';

-* clear LF/CR from alpha fields
-SET &FLD_NAME = 'RECOMMENDATION_NUMBER';
-SET &FLD_LEN = 25 ;
-INCLUDE UBCPALPH

-* assume recommendation data exists if : or ; exists in rec# fld
REC_LN1 /A25 = IF (NEW_RECOMMENDATION_NUMBER CONTAINS ';' OR ':')
THEN SUBSTR(25,NEW_RECOMMENDATION_NUMBER,1,25,25,REC_LN1)
ELSE ' ';

SKIP_CTRL /A1 = IF (NEW_RECOMMENDATION_NUMBER NE ' ') THEN 'Y'
ELSE 'N' ;


BLDG_ID /A8 = EDIT(CLLI,'99999999');

-* Determine Last Expenditure Status if requested
&EXPYES.EVAL EXPYR /YY = ACCTG_PER;
&EXPYES.EVAL EXPMO /M = ACCTG_PER;
-SET &T = EDIT(&YYMD,'9999');
&EXPYES.EVAL NOWYR /I4 WITH ACCTG_PER = EDIT('&T') ;
-SET &T = EDIT(&MDY,'99') ;
&EXPYES.EVAL NOWMO /I2 WITH ACCTG_PER = EDIT('&T') ;
&EXPYES.EVAL MLT /I2 = NOWYR - EXPYR ;
&EXPYES.EVAL MO /I4 = IF (EXPYR EQ 0) THEN 0
&EXPYES.EVAL ELSE IF (NOWYR NE EXPYR)
&EXPYES.EVAL THEN ((MLT * 12) - EXPMO) + NOWMO
&EXPYES.EVAL ELSE NOWMO - EXPMO ;
&EXPYES.EVAL EXP_STATUS /A16 = IF (EXPYR EQ 0) THEN 'UNKNOWN'
&EXPYES.EVAL ELSE IF (MO LE 3) THEN '0-3 months'
&EXPYES.EVAL ELSE IF (MO FROM 4 TO 5) THEN '4-5 months'
&EXPYES.EVAL ELSE '6 or more months' ;

XPRJ_NBR /A7 = PRJ_NBR ;
XENGINEER_ID/A9 = ENGINEER_ID ;
ORDMGR /A6 = EDIT(ENGINEER_ID,'999999'); ;

ANCHOR_ST /A44 = '';
ANCHOR_END /A4 = '';

HDPART /A116 = 'FUNDING STATUS: ' | FUNDING_STATUS |
' PRJ MGR: ' | PRJMGR |
' PLANNER: ' | PLAN |
' DESIGNER: ' | DESIGN |
' ENGINEER: ' | ENG ;

VRF_VNDR_SENT_DATE_CODE/A1 = IF (VRF_VNDR_SENT_MDYY EQ '12/31/9999')
THEN ' '
ELSE VRF_VNDR_SENT_DATE_CODE;
ENGRG_ISU_DATE_CODE/A1 = IF (ENGRG_ISU_MDYY EQ '12/31/9999')
THEN ' '
ELSE ENGRG_ISU_DATE_CODE;
MATL_SHIP_DATE_CODE/A1 = IF (MATL_SHIP_MDYY EQ '12/31/9999')
THEN ' '
ELSE MATL_SHIP_DATE_CODE;
ORDER_START_DATE_CODE/A1 = IF (ORDER_START_MDYY EQ '12/31/9999')
THEN ' '
ELSE ORDER_START_DATE_CODE;
VNDR_COMPLT_DATE_CODE/A1 = IF (VNDR_COMPLT_MDYY EQ '12/31/9999')
THEN ' '
ELSE VNDR_COMPLT_DATE_CODE;
COMPLT_DATE_CODE/A1 = IF (COMPLT_MDYY EQ '12/31/9999')
THEN ' '
ELSE COMPLT_DATE_CODE;
PLANT_RETIREMENT_DATE_CODE/A1 = IF (PLANT_RETIREMENT_MDYY EQ '12/31/9999')
THEN ' '
ELSE PLANT_RETIREMENT_DATE_CODE;

ORIGINAL_BASELINE_MDYY/MDYY = IF (ORIGINAL_BASELINE_MDYY EQ '12/31/9999')
THEN ' '
ELSE ORIGINAL_BASELINE_MDYY;
PLANNING_TURNOVER_MDYY/MDYY = IF (PLANNING_TURNOVER_MDYY EQ '12/31/9999')
THEN ' '
ELSE PLANNING_TURNOVER_MDYY;
ALL_TRAN_MDYY/MDYY = IF (ALL_TRAN_MDYY EQ '12/31/9999')
THEN ' '
ELSE ALL_TRAN_MDYY;
VRF_VNDR_SENT_MDYY/MDYY = IF (VRF_VNDR_SENT_MDYY EQ '12/31/9999')
THEN ' '
ELSE VRF_VNDR_SENT_MDYY;
ENGRG_ISU_MDYY/MDYY = IF (ENGRG_ISU_MDYY EQ '12/31/9999')
THEN ' '
ELSE ENGRG_ISU_MDYY;
DETAIL_SPEC_DUE_MDYY/MDYY = IF (DETAIL_SPEC_DUE_MDYY EQ '12/31/9999')
THEN ' '
ELSE DETAIL_SPEC_DUE_MDYY;
MATL_SHIP_MDYY/MDYY = IF (MATL_SHIP_MDYY EQ '12/31/9999')
THEN ' '
ELSE MATL_SHIP_MDYY;
ORDER_START_MDYY/MDYY = IF (ORDER_START_MDYY EQ '12/31/9999')
THEN ' '
ELSE ORDER_START_MDYY;
COMPLT_MDYY/MDYY = IF (COMPLT_MDYY EQ '12/31/9999')
THEN ' '
ELSE COMPLT_MDYY;
VNDR_COMPLT_MDYY/MDYY = IF (VNDR_COMPLT_MDYY EQ '12/31/9999')
THEN ' '
ELSE VNDR_COMPLT_MDYY;
PLANT_RETIREMENT_MDYY/MDYY = IF (PLANT_RETIREMENT_MDYY EQ '12/31/9999')
THEN ' '
ELSE PLANT_RETIREMENT_MDYY;
REQ_SRVC_MDYY/MDYY = IF (REQ_SRVC_MDYY EQ '12/31/9999')
THEN ' '
ELSE REQ_SRVC_MDYY;

-SET &UDEFRCHI_RC = PRJ_MGR_RC ;
-INCLUDE UDEFRCHI

-SET &WITHFIELD = 'WITH E01' ;
-INCLUDE UHTMDEF1
END

TABLE FILE HOLD
PRINT
DESCR/A20 AS 'DESCRIPTION'
&EXPSH.EVAL EXP_STATUS AS 'LAST,EXPENDITURE,STATUS'
FUNDING_STATUS AS 'FS'
-* people selected from the criteria screen
&STYPD1_
&STYPD2_
ORIGINAL_BASELINE_MDYY/MDY AS 'BASELINE,DATE'
PLANNING_TURNOVER_MDYY/MDY AS 'PLANNING,TURNOVER,DUE'
ALL_TRAN_MDYY/MDY AS 'ALL,TRAN,DATE'
VRF_VNDR_SENT_MDYY/MDY AS 'VRF VNDR,SENT,DATE'
VRF_VNDR_SENT_DATE_CODE AS '' IN +0
ENGRG_ISU_MDYY/MDY AS 'ENGR,ISSUED,DATE'
ENGRG_ISU_DATE_CODE AS '' IN +0
DETAIL_SPEC_DUE_MDYY/MDY AS 'DETAILED,SPEC DUE,DATE'
MATL_SHIP_MDYY/MDY AS 'MATERIAL,SHIP,DATE'
MATL_SHIP_DATE_CODE AS '' IN +0
ORDER_START_MDYY/MDY AS 'START,DATE'
ORDER_START_DATE_CODE AS '' IN +0
&ORD1ST.EVAL COMPLT_MDYY/MDY AS 'COMPLETE,DATE'
&ORD1ST.EVAL COMPLT_DATE_CODE AS '' IN +0
VNDR_COMPLT_MDYY/MDY AS 'VNDR,COMPLETE,DATE'
VNDR_COMPLT_DATE_CODE AS '' IN +0
&ORD2ND.EVAL COMPLT_MDYY/MDY AS 'COMPLETE,DATE'
&ORD2ND.EVAL COMPLT_DATE_CODE AS '' IN +0
PLANT_RETIREMENT_MDYY/MDY AS 'PLANT,RETIRED,DATE'
PLANT_RETIREMENT_DATE_CODE AS '' IN +0
REQ_SRVC_MDYY/MDY AS 'REQ,SRVC,DATE'

This message has been edited. Last edited by: steveyosteve,

(FOC32498) FOCEXEC PARSER ERROR. INVALID SYMBOL: ;
 ERROR AT OR NEAR LINE 889 IN PROCEDURE RORDLISTFOCEXEC *
(FOC003) THE FIELDNAME IS NOT RECOGNIZED: DESCR/A20

My guess is the FOC32498 message is generated upstream, in the TABLE code that creates the HOLD - perhaps in a COMPUTE. It might be a
TABLE FILE HOLD
...
ON TABLE HOLD
- such that a HOLD.mas exists, but does not describe DESCR.

-* Translate "(34) to space(32)
DESCR1 /A25 = CTRAN(25,NEW_&DESCRIP,34,32,DESCR1);

-* Translate CRLF(10) to space(32)
DESCR /A25 = CTRAN(25,DESCR1,10,32,DESCR);

When we migrated from 7.6.11 to 7.7.03, any define with 2 semi-colons blew up; code-tightening...

Example:

 TEST1/A1 = 'A';; 

This errored out with the same message you have; might be in the -INCLUDE UHTMDEF1

thanks. I will look into this.

...or the problem may lie hidden in one of your -INCLUDE files,

UBCPALPH
UDEFRCHI
UHTMDEF1

The culprit is probably here:

DEFINE FILE HOLD
-* clear LF/CR from alpha fields
-SET &FLD_NAME = &DESCRIP ;
-SET &FLD_LEN = IF (&DESCRIP EQ 'PRJ_DESCR') THEN 40
- ELSE 25 ;
-INCLUDE UBCPALPH

-* Translate "(34) to space(32)
DESCR1 /A25 = CTRAN(25,NEW_&DESCRIP,34,32,DESCR1);

-* Translate CRLF(10) to space(32)
DESCR /A25 = CTRAN(25,DESCR1,10,32,DESCR);

I would add
-SET &ECHO=ON;
-RUN
just before the DEFINE, and

END
-EXIT

right after this chunk, and run it.

Capture and analyze the ECHO output. It will show the resolved code in the -INCLUDE file, and will probably reveal the extraneous ";".

Many thanks. exactly as you said.

double ;;

I don't understand why that error is so common, but shops contemplating the upgrade would do well to include a textsearch of the fex library for ";;" as part of the preparation.