Hi All,

I am trying to limit the no. of lines displaying in the pdf format page. i can do this in HTML, i am unable to do this please give any suggessions.
thanks in advance
this is the example
SET LINES = 25
TABLE FILE CAR
PRINT *
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
LINES-PER-PAGE=20,
$
ENDSTYLE
END

WEBFOCUS 7.6.4,WINDOWS XP,ORACLE,PDF,HTML,EXL2K

This message has been edited. Last edited by: Koteswar,

hi koteswar,

Pagination using SET LINES clause gets reflected only in HTML format ..IT wont work in PDF.

Pagination in PDF is controlled using PAGE-BREAK command for a BY field.

Please search pagination PDF in the forum.
You might find some useful links like this

https://forums.informationbuilders.com/eve/forums/a/tpc/...401035061#5401035061


or there might be some more options in 7.6.6..

thanks

HI Arvind,

I was checked out the link given by you. I din't found any topics related to my question.
So can u please give anyother suggessions.
Thanks in advance.

WEBFOCUS 7.6.4
WINDOWS XP
Output:PDF,HTML,Excel

Did you read any of the information in Arvind's response other than the link? His post has given you the biggest hint for what you need. So your options are:

Create a line counter which is a sort value and page-break after each 25 lines

or

Play with formatting options like pagesize, orientation, bottommargin, etc.

Second option is less coding - you just need to play with the settings until you get what you need.

Here's one:

TABLE FILE CAR
PRINT CAR
BY COUNTRY
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
	 BOTTOMMARGIN=7.0,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=10,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
ENDSTYLE
END

DEFINE FILE CAR
CTR/I5 WITH CARFIELD = 1 + LAST CTR;
CTR2/I1=IF IMOD(CTR,25,'I1') EQ 0 THEN 1 ELSE 0;
CTR0/I5=1;
CTR3/I5=IF CTR2 EQ 1 THEN 25 ELSE IF CTR3 GE 24 THEN CTR0 ELSE 1 + LAST CTR3;
END
-*
TABLE FILE LAVEHA03
PRINT
CTR3 AS '' IN 08
etc......
FOOTING
" "
" "
BY CTR NOPRINT
BY CTR2 NOPRINT
ON CTR2 PAGE-BREAK WHEN CTR2 EQ 1;

correction:

DEFINE FILE CAR
CTR/I5 WITH CARFIELD = 1 + LAST CTR;
CTR2/I1=IF IMOD(CTR,25,'I1') EQ 0 THEN 1 ELSE 0;
CTR0/I5=1;
CTR3/I5=IF CTR2 EQ 1 THEN 25 ELSE IF CTR3 GE 24 THEN CTR0 ELSE 1 + LAST CTR3;
END
-*
TABLE FILE CAR
PRINT
CTR3 AS '' IN 08
etc......
FOOTING
" "
" "
BY CTR NOPRINT
BY CTR2 NOPRINT
ON CTR2 PAGE-BREAK WHEN CTR2 EQ 1;

Hi Timpy,

Thanks for your suggession. I am able to limit the lines in pdf with your logic.

Regards,
koteswar

Please edit the subject line to include [solved].
Thanx.

You may consider using the "Mailing Labels or Multi-Pane Report" technique. You set the matrix to 1 x 1 and give the element size (portion of the page you want to print on). No fussy counters to calculate.

Look for "Laying Out the Report Page - Working With Mailing Labels and Multi-Pane Pages" in the "Creating Reports With WebFOCUS Language" documentation.

-* File 1coltest.fex
TABLE FILE GGSALES
SUM
UNITS/D10 AS ''
BY CATEGORY
BY PRODUCT
BY DATE
ACROSS REGION AS ''

ON PRODUCT SUBTOTAL AS 'Total'
HEADING
"Gotham Grinds - Unit Sales"
" "

FOOTING BOTTOM
"Page <TABPAGENO"

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *

-*[TYPE=REPORT,]
-*PAGEMATRIX=(columns rows),
-*ELEMENT=(width height),
-*[GUTTER=(horizontal vertical),]
-*[MATRIXORDER={VERTICAL|HORIZONTAL},]
-*[LABELPROMPT={OFF|ON},] $

PAGEMATRIX=(1 1),
ELEMENT=(10 5),
GUTTER=(0.000000 0.000000),
MATRIXORDER=HORIZONTAL,
$

TYPE=REPORT, UNITS=IN, PAGESIZE='Letter', SQUEEZE=ON, ORIENTATION=LANDSCAPE,
             GRID=OFF, FONT='ARIAL', SIZE=9, STYLE=NORMAL, $
TYPE=HEADING, SIZE=12, STYLE=BOLD, $
TYPE=TITLE, STYLE=BOLD, $
TYPE=FOOTING, SIZE=9, $
TYPE=ACROSSVALUE, STYLE=BOLD, $
TYPE=SUBTOTAL, BACKCOLOR=RGB(210 210 210), $
ENDSTYLE
END