I need to conditonally format the data based on the grand total values(which is actually average of all columns in this example)

TYPE=DATA,
COLUMN=N3,
COLOR='RED',
WHEN=N3 GE 11578,

Right now I have hard coded the value. I want to do this without hardcoding like something WHEN=N3 GE AVE. SALES


SET SUMMARYLINES=NEW
TABLE FILE CAR
PRINT
DEALER_COST
SALES
RETAIL_COST
BY CAR
ON TABLE SUBTOTAL AVE. DEALER_COST AVE. SALES AVE. RETAIL_COST
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='SCREEN',
LEFTMARGIN=0.000000,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='TIMES NEW ROMAN',
SIZE=10,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
RIGHTGAP=0.125000,
$
TYPE=DATA,
COLUMN=N3,
COLOR='RED',
WHEN=N3 GE 11578,
$
TYPE=GRANDTOTAL,
COLUMN=N4,
COLOR=BLUE,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=OFF,
BORDER-RIGHT=LIGHT,
BORDER-COLOR='BLACK',
$
TYPE=GRANDTOTAL,
COLUMN=N3,
COLOR=BLUE,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=OFF,
BORDER-RIGHT=LIGHT,
BORDER-COLOR='BLACK',
$
TYPE=GRANDTOTAL,
COLUMN=N2,
COLOR=BLUE,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=OFF,
BORDER-RIGHT=LIGHT,
BORDER-COLOR='BLACK',
$
ENDSTYLE
END



Thank you

Madhu

I have never tried this but when it works you can use amper values

WHEN=N3 GE '&VALUE'

If this does work, you can first calculate the wanted value, put it in a amper value and use it.

An other solution might be

TABLE FILE CAR
SUM AVE. SALES NOPRINT
BY CAR NOPRINT
PRINT  DEALER_COST
SALES
RETAIL_COST
BY CAR
....
...
TYPE=DATA,
COLUMN=N5,
COLOR='RED',
WHEN=N5 GE N2,

Hi Frank,

The second solution works very good. I haven't tried the first solution yet. This is the code for the second solution.


SET SUMMARYLINES=NEW
TABLE FILE CAR
SUM
AVE.DEALER_COST NOPRINT
AVE.SALES NOPRINT
AVE.RETAIL_COST NOPRINT
PRINT
DEALER_COST
SALES
RETAIL_COST
BY CAR
ON TABLE SUBTOTAL AVE. DEALER_COST AVE. SALES AVE. RETAIL_COST
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='SCREEN',
LEFTMARGIN=0.000000,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='TIMES NEW ROMAN',
SIZE=10,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
RIGHTGAP=0.125000,
$
TYPE=DATA,
COLUMN=N6,
COLOR='RED',
WHEN=N6 LE N2,
$
TYPE=DATA,
COLUMN=N5,
COLOR='RED',
WHEN=N5 LE N1,
$
TYPE=DATA,
COLUMN=N7,
COLOR='RED',
WHEN=N7 LE N3,
$
TYPE=GRANDTOTAL,
COLUMN=N7,
COLOR=BLUE,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=OFF,
BORDER-RIGHT=LIGHT,
BORDER-COLOR='BLACK',
$
TYPE=GRANDTOTAL,
COLUMN=N6,
COLOR=BLUE,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=OFF,
BORDER-RIGHT=LIGHT,
BORDER-COLOR='BLACK',
$
TYPE=GRANDTOTAL,
COLUMN=N5,
COLOR=BLUE,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=OFF,
BORDER-RIGHT=LIGHT,
BORDER-COLOR='BLACK',
$
ENDSTYLE
END