Hi,
I'm wanting a field that increments everytime a subhead is printed. I tried this but didn't quite get what I wanted...

DEFINE FILE CAR
KOUNT3/I1=3;
KOUNT/I4 WITH COUNTRY=IF KOUNT GT KOUNT3 THEN KOUNT+1 ELSE 4;
END
TABLE FILE CAR
SUM
     DEALER_COST
     RETAIL_COST
BY COUNTRY
BY CAR
BY BODYTYPE
ON COUNTRY SUBHEAD
" INCREMENTER HEADING VALUE IS <KOUNT "
ON COUNTRY SUBTOTAL AS '*TOTAL COUNTRY'
ON CAR SUBTOTAL AS '*TOTAL CAR'
ON BODYTYPE SUBTOTAL MULTILINES AS '*TOTAL BODYTYPE'
HEADING
""
FOOTING
""
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
ENDSTYLE
END

I wanted the increments to go in numerical order. The defines doesn't quite work because it gets processed before the sort and the where clauses. So, it increments in the original file order and it increments even if the country is eliminated in a where clause.

Any ideas?

Anatess,

Convert them to COMPUTEs with NOPRINT and make sure KOUNT3 is also specified WITH COUNTRY.

T

 TABLE FILE CAR
SUM
     DEALER_COST
     RETAIL_COST
	 COMPUTE COUNTIT/I4 = IF COUNTRY EQ LAST COUNTRY THEN COUNTIT ELSE COUNTIT + 1;  NOPRINT
BY COUNTRY
BY CAR
BY BODYTYPE
ON COUNTRY SUBHEAD
" INCREMENTER HEADING VALUE IS <COUNTIT "
ON COUNTRY SUBTOTAL AS '*TOTAL COUNTRY'
ON CAR SUBTOTAL AS '*TOTAL CAR'
ON BODYTYPE SUBTOTAL MULTILINES AS '*TOTAL BODYTYPE'
HEADING
""
FOOTING
""
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
ENDSTYLE
END

Tony is too fast for me, code above shows what he is talking about.

Ah, but it just goes to prove that great minds think alike?

T

Awesome! Thank you Leah and Tony (the great minds network). I added a tweak since my data has a null BY value and

COMPUTE COUNTIT/I4 = IF COUNTRY EQ LAST COUNTRY THEN COUNTIT ELSE COUNTIT + 1;

will not increment on that first null record.

So now its something like this:

COMPUTE COUNTIT/I4 = IF COUNTRY EQ LAST COUNTRY AND (COUNTIT GT 0) THEN COUNTIT ELSE COUNTIT + 1;

This forum is awesome.