Hi All,

I am rewriting an existing report in FML and the following code captures the essence of what I'm trying to accomplish:

SET HOLDLIST = PRINTONLY
SET ASNAMES = ON

TABLE FILE GGSALES
SUM UNITS
BY REGION
BY CATEGORY
ON TABLE HOLD AS GGDATA
END

TABLE FILE GGDATA
SUM MIN.UNITS AS 'MIN_UNITS'
MAX.UNITS AS 'MAX_UNITS'
AVE.UNITS AS 'AVE_UNITS'
BY CATEGORY
SUM UNITS
BY CATEGORY
BY REGION
ON TABLE HOLD AS TESTING
END

TABLE FILE TESTING
SUM UNITS AS ''
MIN_UNITS NOPRINT
MAX_UNITS NOPRINT
AVE_UNITS NOPRINT
ACROSS REGION
COMPUTE NEW_MIN/I8 = MIN_UNITS ; AS 'Min'
COMPUTE NEW_MAX/I8 = MAX_UNITS ; AS 'Max'
COMPUTE NEW_AVE/I8 = AVE_UNITS ; AS 'Avg'

FOR CATEGORY
'Coffee' LABEL R1 AS 'COFFEE' OVER
'Food' LABEL R2 AS 'FOOD' OVER
'Gifts' LABEL R3 AS 'GIFTS'

ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=N2, BACKCOLOR=BLUE,COLOR=WHITE,$
TYPE=REPORT, COLUMN=NEW_MIN, BACKCOLOR=BLUE, COLOR=WHITE,$
TYPE=REPORT, COLUMN=NEW_MAX, BACKCOLOR=BLUE, COLOR=WHITE,$
TYPE=REPORT, COLUMN=NEW_AVE, BACKCOLOR=BLUE, COLOR=WHITE,$
ENDSTYLE
END

My question is why isn't the styling for NEW_MAX and NEW_AVE recognized?

The current report I have contains styling similar to the above and the clients has historically been extremely picky regarding their styling requests. This is something they're not willing to part from.

Is there anyway I can accomplish this? I've exhausted many options to try to get this to work.

Ken

TYPE=REPORT, COLUMN=NEW_MIN, BACKCOLOR=BLUE, COLOR=WHITE,$
TYPE=REPORT, COLUMN=NEW_MAX(*), BACKCOLOR=RED, COLOR=WHITE,$
TYPE=REPORT, COLUMN=NEW_AVE(*), BACKCOLOR=ORANGE, COLOR=WHITE,$

I don't know why, but this worked for me (WF 5.3.2).

Thanks Francis. It worked great!

Ken