Having trouble styling (or removing) a particular component in an active report. The area in question is in an across under the ACROSSVALUE where the TITLE element would be for a normal column. Strange thing is these row titles don't show up at all in other formats, like HTML, PDF, Excel, etc.

Broken Active report:


Working Excel:


Working HTML:


Working PDF:


Any ideas on which TYPE and OBJECT I would need to use to reference this element, or how to make it go away altogether?

This message has been edited. Last edited by: Kerry,

If you haven't already, try setting the AS title for SALES to null or blank. For example:

TABLE FILE CAR
 SUM SALES AS ''
 BY COUNTRY NOPRINT SUBTOTAL
 BY CAR
 BY COUNTRY
 BY MODEL
 ACROSS COUNTRY
 ACROSS SEATS
END

Nice screen shots... How about posting your code for the above to give us something to play with?

Oh come on Doug, you should be able to determine the basic code from that -

TABLE FILE CAR
SUM DCOST
 BY CAR
 BY COUNTRY
 BY MODEL
ACROSS COUNTRY SUBTOTAL MULTILINES
ACROSS SEATS
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOLEAD
ON TABLE ROW-TOTAL
END

Of course someone has just woken you up

T

This message has been edited. Last edited by: Tony A,

Weel, the SUM SALES AS '' didn't work. It just did this:



So I guess I am back to the original question... How to make it disappear or allow me to style it. Which TYPE and OBJECT would I use?

How about finally posting your code, including the styling? It seems odd you're getting Column3, Column4, etc.

I just played around with this to what was going on. For Active Reports with ACROSS, you get the name of the field repeated on the same line as the titles for the BY fields. If you use AS '' to remove the 'title' for the across, you get the COLUMN1, COLUMN2, etc. I think that is generated because of the control that gets generated for each column to allow you to operate on that column, i.e. sort, hide, graph, etc.

The only way I can think to remove that is to do the ACROSS into a HOLD file then do the active report on the hold file.

Here is a simplified version of the code that gets the same results:

TABLE FILE CAR
SUM
'CAR.BODY.SALES' AS ''
BY 'CAR.COMP.CAR'
BY 'CAR.ORIGIN.COUNTRY'
BY 'CAR.CARREC.MODEL'
ACROSS 'CAR.ORIGIN.COUNTRY'
ACROSS 'CAR.BODY.SEATS'

ON CAR.ORIGIN.COUNTRY SUBTOTAL MULTILINES AS '*TOTAL'
HEADING
"Title of the Report"
ON TABLE SET PAGE-NUM OFF
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='VERDANA',
SIZE=10,
$
TYPE=DATA,
SIZE=8,
COLOR='BLACK',
BACKCOLOR=( 'WHITE' RGB(235 235 235) ),
$
TYPE=TITLE,
SIZE=8,
COLOR='WHITE',
BACKCOLOR=RGB(0 51 102),
STYLE=-UNDERLINE+BOLD,
JUSTIFY=CENTER,
$
TYPE=TABHEADING,
SIZE=12,
COLOR=RGB(0 51 102),
STYLE=BOLD,
$
TYPE=TABFOOTING,
COLOR=RGB(150 150 150),
STYLE=BOLD,
$
TYPE=HEADING,
LINE=1,
OBJECT=TEXT,
ITEM=1,
SIZE=14,
COLOR=RGB(0 51 102),
STYLE=BOLD,
$
TYPE=HEADING,
LINE=2,
OBJECT=TEXT,
ITEM=1,
SIZE=8,
COLOR=RGB(0 51 102),
JUSTIFY=LEFT,
$
TYPE=HEADING,
LINE=2,
OBJECT=TEXT,
ITEM=2,
SIZE=8,
COLOR=RGB(0 51 102),
JUSTIFY=LEFT,
$
TYPE=HEADING,
LINE=3,
SIZE=12,
COLOR=RGB(0 51 102),
STYLE=BOLD,
JUSTIFY=LEFT,
$
TYPE=FOOTING,
COLOR=RGB(150 150 150),
STYLE=BOLD,
JUSTIFY=RIGHT,
HEADALIGN=BODY,
$
TYPE=SUBHEAD,
SIZE=8,
COLOR=RGB(0 51 102),
STYLE=BOLD,
$
TYPE=SUBFOOT,
SIZE=8,
COLOR=RGB(0 51 102),
STYLE=BOLD,
$
TYPE=SUBTOTAL,
SIZE=8,
COLOR='WHITE',
BACKCOLOR=RGB(150 150 150),
STYLE=BOLD,
$
TYPE=ACROSSVALUE,
SIZE=8,
COLOR='WHITE',
BACKCOLOR='GRAY',
STYLE=-UNDERLINE+BOLD,
JUSTIFY=CENTER,
$
TYPE=ACROSSVALUE,
COLUMN=ROWTOTAL(1),
BACKCOLOR='WHITE',
$
TYPE=ACROSSTITLE,
SIZE=8,
COLOR='DIM GRAY',
STYLE=-UNDERLINE+BOLD,
JUSTIFY=CENTER,
$
TYPE=GRANDTOTAL,
SIZE=8,
COLOR='WHITE',
BACKCOLOR=RGB(51 51 51),
STYLE=BOLD,
$
TYPE=REPORT,
OBJECT=STATUS-AREA,
PAGE-LOCATION=BOTTOM,
$
TYPE=REPORT,
OBJECT=CURRENT-ROW,
HOVER-BACKCOLOR=RGB(154 191 226),
BACKCOLOR=RGB(40 81 120),
$
ENDSTYLE
END

In the Report Painter GUI, if I select the data column in the SUM (SALES) and choose to style the Title, it looks correct on the sample report on the painter page, and generates the following code:

TYPE=TITLE,
ACROSSCOLUMN=N1,
BACKCOLOR=RGB(255 204 0),
$

Thus, report painter tries to style this area with TYPE=TITLE and ACROSSCOLUMN=N1 (or, I assume, N* would work as well).

But active reports do not reflect this styling. Thinking this is a bug.

Try this to get rid of the column names:

SUM
'CAR.BODY.SALES' AS '&|nbsp;'

Worked great. Good thinking on that one.

Thanks!