Hi,
When running a MAINTAIN code, I get a message at the end saying "Transactions : commits = 1, rollbacks = 0 Segements : Included = 0" etc. At this point the user needs to click OK for the code to proceed. However I want the execution of the code to continue without the user having to click anything.

Is there a way of suppressing these Focus Messages; I noticed a similar post in March this year suggesting the use of SET MESSAGES = OFF, but this didn't work in my case.

Any help will be greatly appreciated
Thanks,
Trevor Wilson (CPP UK)

Trevor
Are you running WebFOCUS or on the Mainframe? Are you running a series of Maintain procedures in a Focexec? How are you getting this message, and when comes next?

Mark

Hi Mark,
Thanks for getting back to me, sorry for the delay in replying (I'd just finished for the day).
I'm using Webfocus Desktop power reporter for Windows v 4.3.6.

This all stems from an earlier post I made November 17th regarding how to make changes to data using a MAINTAIN, which Mikel in Spain was kind enough to help me with. His solution worked well, but I found that when I deleted the TYPE commands to provide the user with information, I started getting the 'TRANSACTIONS, message instead. [with the TYPE commands included I didn't get the TRANSACTIONS message but I still needed to acknowledge the TYPE results).

Although there is only one MAINTAIN in my code, it is part of a larger procedure which takes some time to run, and I would prefer to be able to let the PC get on with it, without me having to click on message boxes.

Rather than go into detail of the code which is causing me problems (I could provide this if it would help), this is a much simpler example which still generates the Focus message, even with SET MESSAGE = OFF.

This example creates a HOLD file with 5 records, then adds 1 to each with a MAINTAIN command:

DEFINE FILE CAR
KEY/I2 = DECODE COUNTRY (
'ENGLAND' 1
'JAPAN' 2
'ITALY' 3
'W GERMANY' 4
'FRANCE' 5
ELSE 0) ;
VALUE/I2 = DECODE KEY (
1 10
2 15
3 20
4 25
5 30
ELSE 0) ;
END

TABLE FILE CAR
SUM VALUE BY KEY
ON TABLE HOLD AS HOLD1 FORMAT FOCUS
END

-RUN

MAINTAIN FILE HOLD1

FOR ALL NEXT HOLD1.KEY INTO STK
REPEAT STK.FOCCOUNT I/I5 = 1 ;
IF (I GE 1) AND (I LT STK.FOCCOUNT) THEN BEGIN
COMPUTE VALHOLD/I2 = STK(I).VALUE ;
COMPUTE VALPLUS/I2 = VALHOLD + 1;
STK(I).VALUE = VALPLUS;
UPDATE HOLD1.VALUE FROM STK(I);
ENDBEGIN
ENDREPEAT I = I + 1;
END

-RUN

TABLE FILE HOLD1
PRINT *
END

Before the last TABLE shows the correct result, I get the Focus Message : "Transactions : commits =1 , rollback = 0 Segments : Included = 0 , Updated = 4, deleted - 0". This is the message I want to suppress.

The use of SET MESSAGE = OFF only seems to supress the " No of records in table etc" messages you get at the bottom of the screen next to the "Focus:Idle" status bar.

Regards
Trevor Wilson
Corus Packaging Plus
UK

This message has been edited. Last edited by: Trevor M Wilson,

Trevor,

Not having 4.3.6 I can't test this (it doesn't happen using 5.3.2) but looking at it logically the only way to get rid of the message is to use TYPE, but that prompts for a response?

How about using TYPE ON ddname - where ddname is an allocated temporary file?

As I say, I can't test this so I don't know if it will do what I think it will - give it a go and let us know how you get on.

T

p.s. Regards to Mervyn if he's still there!

Thanks Tony, I gave that a try. It managed to write an output to the message hold file, but I still get the 'Transactions' message.
My code now looks like :

-* DEFINING HOLD FILE FOR MESSAGES

DEFINE FILE CAR
MESSHOLD/A100 = DECODE COUNTRY (
'ENGLAND' 'MESSAGE'
ELSE '0');
END

TABLE FILE CAR
SUM MESSHOLD
BY MESSHOLD NOPRINT
WHERE MESSHOLD NE '0';
ON TABLE HOLD AS HOLDMSG FORMAT ALPHA
END

-* CREATING HOLD FILE TO MAINTAIN

DEFINE FILE CAR
KEY/I2 = DECODE COUNTRY (
'ENGLAND' 1
'JAPAN' 2
'ITALY' 3
'W GERMANY' 4
'FRANCE' 5
ELSE 0) ;
VALUE/I2 = DECODE KEY (
1 10
2 15
3 20
4 25
5 30
ELSE 0) ;
END

TABLE FILE CAR
SUM VALUE BY KEY
ON TABLE HOLD AS HOLD1 FORMAT FOCUS
END


FILEDEF HOLDMSG DISK C:\IBI\DESKTOP436\CONF\EDATEMP\HOLDMSG.FTM

-RUN

MAINTAIN FILE HOLD1

FOR ALL NEXT HOLD1.KEY INTO STK
REPEAT STK.FOCCOUNT I/I5 = 1 ;

-* SUPPRESSING MESSAGE TO HOLD FILE
TYPE ON HOLDMSG "9"

IF (I GE 1) AND (I LT STK.FOCCOUNT) THEN BEGIN
COMPUTE VALHOLD/I2 = STK(I).VALUE ;
COMPUTE VALPLUS/I2 = VALHOLD + 1;
STK(I).VALUE = VALPLUS;
UPDATE HOLD1.VALUE FROM STK(I);
ENDBEGIN
ENDREPEAT I = I + 1;
END

-RUN

TABLE FILE HOLD1
PRINT *
END

TABLE FILE HOLDMSG
PRINT *
END

The last TABLE shows the output to the message hold file, which now contains five 9's.
Thanks for the suggestion, perhaps this would give us ammunition for a Webfocus upgrade.

I don't know any Mervyn personally, I take it you are an ex - Trostre /Ebbw Vale man yourself. Are you still with Corus or have you gone on to better things ?

Regards,
Trevor Wilson
Corus Packaging Plus, Trostre Works
UK

Nevermind, I just noticed you tried this already. Sorry.

Have you tried this?

SET MESSAGE = OFF

Hi Mickey,
Thanks for taking time to respond anyway. If anyone else has any ideas they would be very much appreciated, as I can't see us getting a Webfocus upgrade in the immediate future.

Regards,
Trevor Wilson
Corus Packaging Plus, Trostre Works
UK

SET EMGSRV=OFF

Deactivates all output messages including MAINTAIN statistics.

-* Deactivate output messages.
SET EMGSRV = OFF
-* MAINTAIN code.
MAINTAIN
...
END
-RUN
-* Reactivate output messages.
SET EMGSRV = ON

Regards,
Mikel

This message has been edited. Last edited by: Mikel,

Thanks Mikel, you did it again !. That did the job perfectly. I was sure that there had to be a simple answer to the problem.

Sincere thanks,

Trevor

Be careful, this set, EMGSRV=OFF, also deactivates all warning/error messages.

Regards,
Mikel