I tried doing a search on this but I did not find what I was looking for.
I have a PDF format report which has a drilldown on region. Only the last region is showing an underline but I want all of the regions to show an underline to indicate a link. I tried Style = Underline but that doesn't work either. Any suggestions?

GG

If you post your code I will take a look.

Post it between [ CODE ] [ /CODE ] (Without the spaces)

Sometimes the links are hidden if the font size of the report is small. Are the links still missing if you increase the size of the report display?

Sean

DEFINE FILE ALLEXPENSES
JREGION/A50 = IF EXPENSEREGION EQ 'John Boeckh' THEN 'ZZZZZ' ELSE EXPENSEREGION;
END

TABLE FILE ALLEXPENSES
SUM
TOTAL/C AS 'Actual'
MAX.BUDGET/C AS 'Budget'
MAX.VARIANCE/C AS 'Variance'
BY JREGION NOPRINT
BY EXPENSEREGION AS 'Region'
ACROSS EXPDATE_MMYY AS ' ' ROW-TOTAL AS 'FYTD Total'
WHERE EXPENSEREGION NE ' ';
HEADING
"Expense Report"
ON TABLE COLUMN-TOTAL
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
UNITS = IN, PAGESIZE = LEGAL, ORIENTATION = LANDSCAPE, GRID = OFF, SQUEEZE = ON,
LEFTMARGIN = 0.5, TOPMARGIN = 0.25, RIGHTMARGIN = 0.025, BOTTOMMARGIN = 0.025, LEFTGAP = 0.15, RIGHTGAP = 0.15, $
TYPE = REPORT, FONT = 'Arial', SIZE = 12, $
TYPE = HEADING, SIZE = 12, STYLE = BOLD, $
TYPE = TITLE, SIZE = 12, STYLE = BOLD, $
TYPE = DATA, SIZE = 11, JUSTIFY = LEFT, COLUMN = EXPENSEREGION, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = DATA, COLUMN = EXPENSEREGION, FOCEXEC = EXPBMOTY(RGN = EXPENSEREGION), STYLE = UNDERLINE, $
TYPE = DATA, SIZE = 11, JUSTIFY = RIGHT, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = ACROSS, FONT = 'ARIAL', SIZE = 12, STYLE = BOLD, JUSTIFY = CENTER, $
TYPE = GRANDTOTAL, FONT = 'ARIAL', SIZE = 11, STYLE = BOLD, $
TYPE = TITLE, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
TYPE = TITLE, COLUMN = ROWTOTAL(2), STYLE = BOLD, $
TYPE = TITLE, COLUMN = ROWTOTAL(3), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(2), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(3), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(1), BORDER-LEFT = MEDIUM, BORDER-LEFT-STYLE = SOLID, BORDER-LEFT-COLOR = BLACK, $
TYPE = ACROSSVALUE, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
ENDSTYLE
END

I would try to change the sequenze of these lines
And IMO the style=underline is not needed, since this is an hyperlink

TYPE = DATA, SIZE = 11, JUSTIFY = RIGHT, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
-* remove this line: TYPE = DATA, SIZE = 11, JUSTIFY = LEFT, COLUMN = EXPENSEREGION, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = DATA, COLUMN = EXPENSEREGION, FOCEXEC = EXPBMOTY(RGN = EXPENSEREGION), TARGET =_blank , $

does it work in HTML?

Yea it works in HTML.
It shows the regions in blue. There's no underline.

If my memory has not gone ....
Were drilldowns from PDF supported in 5.3.2?

I was told that it doesn't work but my drilldown works properly. The only problem is the underline that's showing on the last region.

GG

If you try to build this report on the CAR database is the reslt then the same? (no underline?)

Drill-downs work for PDF reports in 5.3.2.

There appears to be a bug in WebFOCUS that is still around up to at least version 7.1.1.

DrillDown column - underline does not appear on all values

By the way, it helps to post code that can be run by anyone on the forum - using the CAR file or the Gotham Grinds demo files.

e.g.

TABLE FILE CAR
SUM
SALES
BY COUNTRY
ACROSS SEATS
ON TABLE SET PAGE NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS = IN, PAGESIZE = LEGAL, ORIENTATION = LANDSCAPE, GRID = OFF, SQUEEZE = ON,
LEFTMARGIN = 0.5, TOPMARGIN = 0.25, RIGHTMARGIN = 0.025, BOTTOMMARGIN = 0.025, LEFTGAP = 0.15, RIGHTGAP = 0.15, $
TYPE = REPORT, FONT = 'Arial', SIZE = 12, $
TYPE = HEADING, SIZE = 12, STYLE = BOLD, $
TYPE = TITLE, SIZE = 12, STYLE = BOLD, $
TYPE = DATA, SIZE = 11, JUSTIFY = LEFT, COLUMN = COUNTRY, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = DATA, COLUMN = COUNTRY, FOCEXEC = EXPBMOTY(COUNTRY = COUNTRY), STYLE = UNDERLINE, $
TYPE = DATA, SIZE = 11, JUSTIFY = RIGHT, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = ACROSS, FONT = 'ARIAL', SIZE = 12, STYLE = BOLD, JUSTIFY = CENTER, $
TYPE = GRANDTOTAL, FONT = 'ARIAL', SIZE = 11, STYLE = BOLD, $
TYPE = TITLE, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
TYPE = TITLE, COLUMN = ROWTOTAL(2), STYLE = BOLD, $
TYPE = TITLE, COLUMN = ROWTOTAL(3), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(2), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(3), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(1), BORDER-LEFT = MEDIUM, BORDER-LEFT-STYLE = SOLID, BORDER-LEFT-COLOR = BLACK, $
TYPE = ACROSSVALUE, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
ENDSTYLE
END
-RUN

I clicked on "Advanced Search on Technical Support" in the FocalPoint banner, logged in using my InfoResponse User ID and Password and searched for "drilldown underline pdf".

May I recommend "rationalizing" the style-sheet?

If you're using one font in the report, you can declare it once. If most of the components are one size, declare that once. Then declare the exceptions...

After "rationalizing" the style-sheet, the hyper-links become blue, so, even if they are not underlined, the blue suggests there is a hyper-link.

TABLE FILE CAR
SUM
SALES
BY COUNTRY
ACROSS SEATS
ON TABLE SET PAGE NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS = IN, PAGESIZE = LEGAL, ORIENTATION = LANDSCAPE, GRID = OFF, SQUEEZE = ON,
LEFTMARGIN = 0.5, TOPMARGIN = 0.25, RIGHTMARGIN = 0.025, BOTTOMMARGIN = 0.025, LEFTGAP = 0.15, RIGHTGAP = 0.15, $
TYPE = REPORT, FONT = 'Arial', SIZE = 11, $
TYPE = HEADING, SIZE = 12, STYLE = BOLD, $
TYPE = TITLE, SIZE = 12, STYLE = BOLD, $
TYPE = GRANDTOTAL, STYLE = BOLD, $
TYPE = ACROSS, SIZE = 12, STYLE = BOLD, JUSTIFY = CENTER, $
TYPE = ACROSSVALUE, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
TYPE = DATA, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = DATA, COLUMN = COUNTRY, FOCEXEC = EXPBMOTY(COUNTRY = COUNTRY), STYLE = UNDERLINE, $
TYPE = DATA, COLUMN = ROWTOTAL(1), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(2), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(3), STYLE = BOLD, $
TYPE = DATA, COLUMN = ROWTOTAL(1), BORDER-LEFT = MEDIUM, BORDER-LEFT-STYLE = SOLID, BORDER-LEFT-COLOR = BLACK, $
ENDSTYLE
END
-RUN

Yea I already managed to get the hyper-links blue. However, it still shows the underline on the last region/country.

Please read my posting about the WebFOCUS bug and follow the link to the Tech Support site.

There appears to be no workaround, UNLESS you remove the alternating colours from the DATA rows - then the under-lines work. So you'll have to decide which you or the users prefer, until you upgrade to a version past 7.1.1.

Yea sorry Francis, I forgot to respond to that post. I did read that and the tech support. I figured it had something to do with the version.

I'll see what the users want.
Thanks.