Hello, Is there a way to put the across result in the bottom of the table?
Thanks, Carlos DiasThis message has been edited. Last edited by: Carlos Dias,
WebFOCUS version: 7.6 Linux/Windows HTML, Excel
May 17, 2012, 02:36 PM
Kerry
Hi Carlos,
For our experts to better help you, can you please elaborate a bit more: what do you mean with "having across on the bottom"? If we do something like column total, is that what you want? A detailed example with any of our test files (CAR, EMPDATA) would be nice.
Cheers,
Kerry
Kerry Zhan Focal Point Moderator Information Builders, Inc.
May 23, 2012, 06:41 PM
Carlos Dias
Here is an example:
TABLE FILE CAR
SUM
CAR.SPECS.WIDTH AS ''
CAR.SPECS.HEIGHT AS ''
BY LOWEST CAR.BODY.DEALER_COST
ACROSS LOWEST CAR.BODY.SEATS
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
TYPE=ACROSSVALUE,
ACROSS=1,
BACKCOLOR='WHITE',
$
ENDSTYLE
END
What I would like to see is the ACROSS SEATS like a total.
Thanks, Carlos Dias
WebFOCUS version: 7.6 Linux/Windows HTML, Excel
May 24, 2012, 12:14 PM
Kerry
Hi Carlos,
From our technicals: is the following output truly what you want? If so, it will be challenging to do. Otherwise, please let us know how you would want the output to be.
Cheers, Kerry
Kerry Zhan Focal Point Moderator Information Builders, Inc.
-SET &ECHO=ALL;
-* File FOOT01.fex
TABLE FILE CAR
BY SEATS
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SAVE
END
-RUN
-SET &L=&LINES;
-SET &FOOT='" ';
-REPEAT #R FOR &I FROM 1 TO &L;
-READ SAVE,&S
-SET &FOOT=&FOOT | '<+0>' | &S ;
-#R
-SET &FOOT=&FOOT | '"';
-RUN
TABLE FILE CAR
SUM
CAR.SPECS.WIDTH AS ''
CAR.SPECS.HEIGHT AS ''
BY LOWEST CAR.BODY.DEALER_COST
ACROSS LOWEST CAR.BODY.SEATS NOPRINT
FOOTING
" <+0>SEATS "
&FOOT
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=FOOTING, HEADALIGN=BODY, $
TYPE=FOOTING, LINE=1, ITEM=2, COLSPAN=6, $
-REPEAT #FOOT FOR &I FROM 1 TO &L;
-SET &J=&I + 1;
TYPE=FOOTING, LINE=2, ITEM=&J, COLSPAN=2, $
-#FOOT
ENDSTYLE
END
This message has been edited. Last edited by: Danny-SRL,
Daniel In Focus since 1982 wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF
June 05, 2012, 06:16 PM
Carlos Dias
Danny-SRL, Thanks for the tip this solve my problem.