Focal Point
[CASE-OPENED]Tabfooting Row Color Formatting

This topic can be found at:
https://forums.informationbuilders.com/eve/forums/a/tpc/f/7971057331/m/7327019286

June 28, 2016, 11:49 AM
Maggie McBride
[CASE-OPENED]Tabfooting Row Color Formatting
I would like to have the color for the first three rows of the tabfooting to be rgb(44 189 156). I have set the backcolor to the proper rgb, however the last row needs to be 154 220 206, of which I have accomplished. There seems to be some sort of border on the right side of my first three rows and I can not figure out what is causing it. 


 

TABLE FILE CAR

SUM
  COMPUTE HEADER/A20 = ('Sales'); AS '' OVER
  COMPUTE BLNKRW/A20 = ('      '); AS '' OVER
  SALES/D8 AS '' OVER
  COMPUTE LINE/A20 = ('_________________'); AS ''


  COMPUTE SLSQTRPNT/P4 =
                          IF (SALES LE 0)                       THEN 0.00
					ELSE  IF (SALES GT 0 AND SALES LE 25)  THEN 6.00
					ELSE  IF (SALES GT 25 AND SALES LE 50) THEN 12.00
					ELSE  IF (SALES GT 50 AND SALES LE 75) THEN 18.00
					ELSE  IF (SALES GT 75)                      THEN 24.00
					ELSE 0 ;  AS '' NOPRINT

  COMPUTE SLSQTRGRD/A2 =
                         IF (SALES LE 25)                       THEN 'D'
                    ELSE  IF (SALES GT 25 AND SALES LE 50) THEN 'C'
					ELSE IF (SALES GT 50 AND SALES LE 75)  THEN 'B'
					ELSE IF (SALES GT 75)                       THEN 'A';
						  AS '' NOPRINT

ON TABLE SUBFOOT
"GRADE"
"<SLSQTRGRD"
" "
"<SLSQTRPNT  x  Weight 24%"
ON TABLE SET PAGE NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

INCLUDE = IBFS:/FILE/IBI_HTML_DIR/javaassist/intl/EN/combine_templates/ENFlat.sty,

$
     LEFTMARGIN=0.000000, RIGHTMARGIN=0.0000, TOPMARGIN=0.000000, BOTTOMMARGIN=0.000000, SQUEEZE=OFF,


$
TYPE=DATA,
     COLUMN=HEADER,
   	 FONT='CALIBRI',
     SIZE=18,
     STYLE=BOLD,
	 BORDER-BOTTOM=OFF,
	 BORDER-BOTTOM-COLOR='WHITE',
     JUSTIFY=CENTER,
     BACKCOLOR= RGB (44 189 156),
	 COLOR= 'WHITE',
 	 SQUEEZE=2,

$
TYPE=DATA,
     COLUMN=BLNKRW,
   	 FONT='CALIBRI',
     SIZE=1,
     STYLE=BOLD,
	 BORDER-BOTTOM=OFF,
	 BORDER-BOTTOM-COLOR='WHITE',
     JUSTIFY=CENTER,
     BACKCOLOR= RGB (44 189 156),
	 COLOR= 'WHITE',
$
TYPE=DATA,
     COLUMN=SALES,
   	 FONT='CALIBRI',
     SIZE=32,
     STYLE=BOLD,
	 BORDER-BOTTOM=OFF,
	 BORDER-BOTTOM-COLOR='WHITE',
     JUSTIFY=CENTER,
     BACKCOLOR= RGB (44 189 156),
	 COLOR= 'WHITE',
$
TYPE=DATA,
     COLUMN=EQUAL,
   	 FONT='CALIBRI',
     SIZE=1,
     STYLE=BOLD,
	 BORDER-BOTTOM=OFF,
	 BORDER-BOTTOM-COLOR='WHITE',
     JUSTIFY=CENTER,
     BACKCOLOR= RGB (44 189 156),
	 COLOR= 'WHITE',
$
TYPE=DATA,
     COLUMN=LINE,
   	 FONT='CALIBRI',
     SIZE=12,
     STYLE=BOLD,
	 BORDER-BOTTOM=OFF,
	 BORDER-BOTTOM-COLOR='WHITE',
     JUSTIFY=CENTER,
     BACKCOLOR= RGB (44 189 156),
	 COLOR= 'GREY',
	 BOTTOMGAP=-2,
$
TYPE=TITLE,
     FONT='CALIBRI',
     SIZE=20,
     STYLE=BOLD,
     JUSTIFY=CENTER,
	 BACKCOLOR= RGB (44 189 156),
	 COLOR= 'WHITE',
$
TYPE=TABHEADING,
     BORDER-BOTTOM=OFF,
     STYLE=BOLD,
	 SIZE=20,
	 FONT='CALIBRI',
	 COLOR= 'WHITE',
	 JUSTIFY=CENTER,
	 BACKCOLOR= RGB (44 189 156),
$
TYPE=REPORT,
     BORDER-TOP=OFF,
	 BORDER-BOTTOM=OFF,
     STYLE=BOLD,
	 SIZE=20,
	 FONT='CALIBRI',
	 JUSTIFY=CENTER,
	 COLOR='WHITE',
	 BACKCOLOR= RGB (44 189 156),
$

TYPE=TABFOOTING, FONT=ARIAL, SIZE=1, BORDER-TOP=OFF, BORDER-BOTTOM=OFF, STYLE=BOLD, BOTTOMGAP=-.1, BACKCOLOR= RGB (154 220 206), JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=1, ITEM=1, BORDER-TOP = OFF, SIZE=10, COLOR= 'WHITE',BACKCOLOR= RGB (44 189 156), JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=2, ITEM=1, BORDER-TOP = OFF, SIZE=32, COLOR= 'WHITE',BACKCOLOR= RGB (44 189 156), JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=2, ITEM=2, BORDER-TOP = OFF, SIZE=1, COLOR= 'WHITE',BACKCOLOR= RGB (44 189 156), JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=3, ITEM=1, BORDER-TOP = OFF, SIZE=1, COLOR= 'WHITE',BACKCOLOR= RGB (44 189 156), JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=4, ITEM=1, BORDER-TOP = OFF, SIZE=12, COLOR= 'WHITE', BACKCOLOR= RGB (154 220 206),  JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=4, ITEM=2, BORDER-TOP = OFF, SIZE=12, COLOR= 'WHITE', BACKCOLOR= RGB (154 220 206),  JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=4, ITEM=3, BORDER-TOP = OFF, SIZE=12, COLOR= 'WHITE', BACKCOLOR= RGB (154 220 206),  JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=4, ITEM=4, BORDER-TOP = OFF, SIZE=12, COLOR= 'WHITE', BACKCOLOR= RGB (154 220 206),  JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=4, ITEM=5, BORDER-TOP = OFF, SIZE=12, COLOR= 'WHITE', BACKCOLOR= RGB (154 220 206), JUSTIFY=CENTER, $

ENDSTYLE

END

This message has been edited. Last edited by: <Emily McAllister>,


WebFOCUS 8.1.04
Windows, All Outputs
June 28, 2016, 01:42 PM
Francis Mariani
Maggie, it appears the styling may have been created by one of the App Studio/Dev Studio GUI tools - these tools seem to generate a lot of repetition. I've cleaned up the styling a bit and it is now closer to what you're looking for but not quite there (I'm still looking into it).

TABLE FILE CAR

SUM
  COMPUTE HEADER/A20 = ('Sales'); AS '' OVER
  COMPUTE BLNKRW/A20 = ('     '); AS '' OVER
  SALES/D8 AS '' OVER
  COMPUTE LINE/A20 = ('_________________'); AS ''


  COMPUTE SLSQTRPNT/P4 =
                     IF (SALES LE 0)                   THEN 0.00
                ELSE  IF (SALES GT 0 AND SALES LE 25)  THEN 6.00
                ELSE  IF (SALES GT 25 AND SALES LE 50) THEN 12.00
                ELSE  IF (SALES GT 50 AND SALES LE 75) THEN 18.00
                ELSE  IF (SALES GT 75)                  THEN 24.00
                ELSE 0 ;  AS '' NOPRINT

  COMPUTE SLSQTRGRD/A2 =
                    IF (SALES LE 25)                   THEN 'D'
                ELSE  IF (SALES GT 25 AND SALES LE 50) THEN 'C'
                ELSE IF (SALES GT 50 AND SALES LE 75)  THEN 'B'
                ELSE IF (SALES GT 75)                   THEN 'A';
                     AS '' NOPRINT

ON TABLE SUBFOOT
"GRADE"
"<SLSQTRGRD"
" "
"<SLSQTRPNT  x  Weight 24%"
ON TABLE SET PAGE NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

INCLUDE = IBFS:/FILE/IBI_HTML_DIR/javaassist/intl/EN/combine_templates/ENgray_theme.sty, $
TYPE=REPORT, LEFTMARGIN=0.000000, RIGHTMARGIN=0.0000, TOPMARGIN=0.000000, BOTTOMMARGIN=0.000000, SQUEEZE=OFF,$

TYPE=REPORT,
    BORDER=OFF,
    BACKCOLOR= RGB (44 189 156),
    FONT='CALIBRI',
    SIZE=20,
    STYLE=BOLD,
    COLOR='WHITE',
    JUSTIFY=CENTER,
$

TYPE=DATA,
    BORDER-BOTTOM=OFF,
    BACKCOLOR= RGB (44 189 156),
    COLOR= 'WHITE',
    STYLE=BOLD,
    JUSTIFY=CENTER,
$
TYPE=DATA,
    COLUMN=HEADER,
    SIZE=18,
    BORDER-BOTTOM-COLOR='WHITE',
    SQUEEZE=2,

$
TYPE=DATA,
    COLUMN=BLNKRW,
    SIZE=1,
$
TYPE=DATA,
    COLUMN=SALES,
    SIZE=32,
    BORDER-BOTTOM-COLOR='WHITE',
$
TYPE=DATA,
    COLUMN=EQUAL,
    SIZE=1,
    BORDER-BOTTOM-COLOR='WHITE',
$
TYPE=DATA,
    COLUMN=LINE,
    SIZE=12,
    BORDER-BOTTOM-COLOR='WHITE',
    COLOR= 'GREY',
    BOTTOMGAP=-2,
$
TYPE=TITLE,
    SIZE=20,
$
TYPE=TABHEADING,
    SIZE=20,
$
TYPE=TABFOOTING, BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BOTTOMGAP=-.1, FONT=ARIAL, SIZE=1, COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, $

TYPE=TABFOOTING, LINE=1, SIZE=10, $
TYPE=TABFOOTING, LINE=2, SIZE=32, $

TYPE=TABFOOTING, LINE=4, BACKCOLOR= RGB (154 220 206), SIZE=12, $

ENDSTYLE

END





Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
June 28, 2016, 01:52 PM
susannah
hmmm
I can get rid of that; but I don't see why the tabfooting is always a wee bit narrower than the tabheading. puzzle. maybe that's just the way it is.
I also took out the reference to the internal style sheet. ick.
TYPE=TABFOOTING,   FONT=ARIAL, SIZE=1, BORDER-TOP=OFF, BORDER-BOTTOM=OFF, STYLE=BOLD, BOTTOMGAP=-.1, 
  	BACKCOLOR= WHITE, 
 	JUSTIFY=CENTER,
	COLOR= 'WHITE', $
TYPE=TABFOOTING,LINE=1, BACKCOLOR= RGB (44 189 156),$
TYPE=TABFOOTING,LINE=2, BACKCOLOR= RGB (44 189 156), $
TYPE=TABFOOTING,LINE=3, BACKCOLOR= RGB (44 189 156), $
TYPE=TABFOOTING, LINE=1, ITEM=1,   SIZE=10,   $
TYPE=TABFOOTING, LINE=2, ITEM=1,   SIZE=32,      $
TYPE=TABFOOTING, LINE=2, ITEM=2,   SIZE=1,      $
TYPE=TABFOOTING, LINE=3, ITEM=1,   SIZE=1,     $
TYPE=TABFOOTING, LINE=4,   BACKCOLOR=RGB(154 220 206),SIZE=12,   $




In Focus since 1979///7706m/5 ;wintel 2008/64;OAM security; Oracle db, ///MRE/BID
June 28, 2016, 01:54 PM
susannah
ah. I see Francesco and I are of the same mind. my stylesheet bit also cleans it up and puts all the generic items together, leaving the individual ITEM= lines for the specific differences between items.



In Focus since 1979///7706m/5 ;wintel 2008/64;OAM security; Oracle db, ///MRE/BID
June 28, 2016, 02:40 PM
Francis Mariani
Susannah's code got rid of the unwanted background colour, but now it appears narrower.

This would be a great case to open with IBI. We need an explanation why this happens.




Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
June 28, 2016, 03:05 PM
Francis Mariani
I will assume there's a bug in the system and it has something to do with RIGHTGAP, which is supposed to be valid only for PDF or PS:

quote:
LEFTGAP
Indicates how much space to add to the left of a report column.

RIGHTGAP
Indicates how much space to add to the right of a report column.


Adding RIGHTGAP=0 to the REPORT styling (which is the only place it can be) removes that right area of the TABFOOTING, but, alas, things don't look centered.

-*TABLE FILE CAR
-*SUM
-*COMPUTE HEADER/A20 = 'Sales'; AS '' OVER
-*COMPUTE BLNKRW/A20 = ''; AS '' OVER
-*SALES/D10  AS '' OVER
-*COMPUTE LINE/A20 = '_________________'; AS ''
-*ON TABLE SUBFOOT
-*"A"
-*"<HEIGHT"
-*" "
-*"<LENGTH"
-*
-*ON TABLE SET PAGE NOLEAD
-*ON TABLE SET ASNAMES ON
-*ON TABLE SET BYDISPLAY ON
-*ON TABLE NOTOTAL
-*ON TABLE PCHOLD FORMAT HTML
-*ON TABLE SET DROPBLNKLINE ALL
-*ON TABLE SET HTMLCSS ON
-*
-*ON TABLE SET STYLE *
-*TYPE=REPORT, LEFTMARGIN=0.000000, RIGHTMARGIN=0.0000, TOPMARGIN=0.000000, BOTTOMMARGIN=0.000000, SQUEEZE=OFF, $
-*
-*TYPE=REPORT,
-*    BORDER=OFF,
-*    BACKCOLOR= RGB (44 189 156),
-*    FONT='CALIBRI',
-*    SIZE=20,
-*    STYLE=BOLD,
-*    COLOR='WHITE',
-*    JUSTIFY=CENTER,
-*$
-*
-*TYPE=TABFOOTING, BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BOTTOMGAP=-.1, FONT=ARIAL, SIZE=1, COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, $
-*
-*TYPE=TABFOOTING, LINE=1, SIZE=10, $
-*TYPE=TABFOOTING, LINE=2, SIZE=32, $
-*
-*TYPE=TABFOOTING, LINE=4, BACKCOLOR= RGB (154 220 206), SIZE=12, $
-*ENDSTYLE
-*END

TABLE FILE CAR

SUM
  COMPUTE HEADER/A20 = ('Sales'); AS '' OVER
  COMPUTE BLNKRW/A20 = ('     '); AS '' OVER
  SALES/D8 AS '' OVER
  COMPUTE LINE/A20 = ('_________________'); AS ''


  COMPUTE SLSQTRPNT/P4 =
                     IF (SALES LE 0)                   THEN 0.00
                ELSE  IF (SALES GT 0 AND SALES LE 25)  THEN 6.00
                ELSE  IF (SALES GT 25 AND SALES LE 50) THEN 12.00
                ELSE  IF (SALES GT 50 AND SALES LE 75) THEN 18.00
                ELSE  IF (SALES GT 75)                  THEN 24.00
                ELSE 0 ;  AS '' NOPRINT

  COMPUTE SLSQTRGRD/A2 =
                    IF (SALES LE 25)                   THEN 'D'
                ELSE  IF (SALES GT 25 AND SALES LE 50) THEN 'C'
                ELSE IF (SALES GT 50 AND SALES LE 75)  THEN 'B'
                ELSE IF (SALES GT 75)                   THEN 'A';
                     AS '' NOPRINT

ON TABLE SUBFOOT
"GRADE"
"<SLSQTRGRD"
" "
"<SLSQTRPNT  x  Weight 24%"
ON TABLE SET PAGE NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

TYPE=REPORT,
    BORDER=OFF,
    BACKCOLOR= RGB (44 189 156),
    FONT='Calibri',
    SIZE=20,
    STYLE=BOLD,
    COLOR='WHITE',
    JUSTIFY=CENTER,
    RIGHTGAP=0,
$

TYPE=DATA,
    BORDER-BOTTOM=OFF,
    BACKCOLOR= RGB (44 189 156),
    COLOR= 'WHITE',
    STYLE=BOLD,
    JUSTIFY=CENTER,
$
TYPE=DATA,
    COLUMN=HEADER,
    SIZE=18,
    BORDER-BOTTOM-COLOR='WHITE',
    SQUEEZE=2,

$
TYPE=DATA,
    COLUMN=BLNKRW,
    SIZE=1,
$
TYPE=DATA,
    COLUMN=SALES,
    SIZE=32,
    BORDER-BOTTOM-COLOR='WHITE',
$
TYPE=DATA,
    COLUMN=EQUAL,
    SIZE=1,
    BORDER-BOTTOM-COLOR='WHITE',
$
TYPE=DATA,
    COLUMN=LINE,
    SIZE=12,
    BORDER-BOTTOM-COLOR='WHITE',
    COLOR= 'GREY',
    BOTTOMGAP=-2,
$
TYPE=TITLE,
    SIZE=20,
$
TYPE=TABHEADING,
    SIZE=20,
$
TYPE=TABFOOTING, BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BOTTOMGAP=-.1, FONT=ARIAL, SIZE=1, COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, $

TYPE=TABFOOTING, LINE=1, SIZE=10, $
TYPE=TABFOOTING, LINE=2, SIZE=32, $

TYPE=TABFOOTING, LINE=4, BACKCOLOR= RGB (154 220 206), SIZE=12, $

ENDSTYLE

END





Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
June 29, 2016, 08:03 AM
Maggie McBride
Thank you Francis and Susannah! I am a beginner with this so I did start in GUI then modified in the code. This is much better than what I started with. I did put a lot of the unnecessary code in to see if it would affect the appearance. I will be sure to open a case with IBI.

Maggie


WebFOCUS 8.1.04
Windows, All Outputs
July 12, 2016, 04:23 PM
mmoody
Hi Maggie,

Thank you for opening a case with Customer Support.

I believe the code you are looking for is
GAPINTERNAL=ON

This should help you center the columns as desired. See below for your modified code:



TABLE FILE CAR

SUM
COMPUTE HEADER/A20 = ('Sales'); AS '' OVER
COMPUTE BLNKRW/A20 = (' '); AS '' OVER
SALES/D8 AS '' OVER
COMPUTE LINE/A20 = ('_________________'); AS ''

COMPUTE SLSQTRPNT/P4 =
IF (SALES LE 0) THEN 0.00
ELSE IF (SALES GT 0 AND SALES LE 25) THEN 6.00
ELSE IF (SALES GT 25 AND SALES LE 50) THEN 12.00
ELSE IF (SALES GT 50 AND SALES LE 75) THEN 18.00
ELSE IF (SALES GT 75) THEN 24.00
ELSE 0 ; AS '' NOPRINT

COMPUTE SLSQTRGRD/A2 =
IF (SALES LE 25) THEN 'D'
ELSE IF (SALES GT 25 AND SALES LE 50) THEN 'C'
ELSE IF (SALES GT 50 AND SALES LE 75) THEN 'B'
ELSE IF (SALES GT 75) THEN 'A';
AS '' NOPRINT

ON TABLE SUBFOOT
"GRADE"
"" "
"ON TABLE SET PAGE NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

TYPE=REPORT,
BORDER=OFF,
GAPINTERNAL=ON,
BACKCOLOR= RGB (44 189 156),
FONT='Calibri',
SIZE=20,
STYLE=BOLD,
COLOR='WHITE',
JUSTIFY=CENTER,
-* RIGHTGAP=0,
$

TYPE=DATA,
BORDER-BOTTOM=OFF,
BACKCOLOR= RGB (44 189 156),
COLOR= 'WHITE',
STYLE=BOLD,
JUSTIFY=CENTER,
$
TYPE=DATA,
COLUMN=HEADER,
SIZE=18,
BORDER-BOTTOM-COLOR='WHITE',
SQUEEZE=2,

$
TYPE=DATA,
COLUMN=BLNKRW,
SIZE=1,
$
TYPE=DATA,
COLUMN=SALES,
SIZE=32,
BORDER-BOTTOM-COLOR='WHITE',
$
TYPE=DATA,
COLUMN=EQUAL,
SIZE=1,
BORDER-BOTTOM-COLOR='WHITE',
$
TYPE=DATA,
COLUMN=LINE,
SIZE=12,
BORDER-BOTTOM-COLOR='WHITE',
COLOR= 'GREY',
BOTTOMGAP=-2,
$
TYPE=TITLE,
SIZE=20,
$
TYPE=TABHEADING,
SIZE=20,
$
TYPE=TABFOOTING, BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BOTTOMGAP=-.1, FONT=ARIAL, SIZE=1, COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, $

TYPE=TABFOOTING, LINE=1, SIZE=10, $
TYPE=TABFOOTING, LINE=2, SIZE=32, $

TYPE=TABFOOTING, LINE=4, BACKCOLOR= RGB (154 220 206), SIZE=12, $

ENDSTYLE

END



Kind Regards,
Michelle
July 13, 2016, 01:06 PM
Francis Mariani
Michelle, please place your code between code tags (the sub-footing is mangled in your code):

[code]
YOUR CODE HERE
[/code]


Meanwhile, I don't see how using GAPINTERNAL has helped - there is still a green border on the right of the light green band - wouldn't be nice to have a light green band right across the report?

Also, GAPINTERNAL (like LEFTGAP and RIGHTGAP) is supposed to be for PDF only, so why are we playing with this in an HTML report?

quote:
Using the GAPINTERNAL=ON StyleSheet attribute, you can have the gaps placed within the column boundaries for PDF report output. This feature makes it much easier to align fields and headings in reports that use the OVER phrase to create multiple lines.


And by the way, setting it to ON or OFF or removing the setting completely makes no difference in my WF 8.0.08 installation.


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
July 13, 2016, 03:59 PM
Francis Mariani
Maggie,

You may wish to "roll your own" HTML, as some others on FocalPoint have described generating your own HTML. Here's an example of your report, where HTML is computed, and CSS is used to style the rows.

It may be helpful - you have much more control over styling when generating your own HTML.

-SET &ECHO=ALL;

SET PAGE=NOLEAD
SET HOLDLIST=PRINTONLY
-RUN

TABLE FILE CAR

SUM

COMPUTE HTML_HEADER/A100        = '<tr><td class="HEADER">Sales</td></tr>';
COMPUTE HTML_SALES/A100         = '<tr><td class="SALES">' || FPRINT(SALES, 'D8', 'A10') || '</td></tr>';
COMPUTE HTML_LINE/A100          = '<tr><td class="LINES">_________________</td></tr>';
COMPUTE HTML_BLNKRW1/A100       = '<tr><td class="BLNKRW1">&|nbsp;</td></tr>';

COMPUTE SLSQTRPNT/P4 =
     IF (SALES LE  0)                 THEN 0.00
ELSE IF (SALES GT  0 AND SALES LE 25) THEN 6.00
ELSE IF (SALES GT 25 AND SALES LE 50) THEN 12.00
ELSE IF (SALES GT 50 AND SALES LE 75) THEN 18.00
ELSE IF (SALES GT 75)                 THEN 24.00
ELSE 0 ; NOPRINT

COMPUTE SLSQTRGRD/A2 =
     IF (SALES LE 25)                 THEN 'D'
ELSE IF (SALES GT 25 AND SALES LE 50) THEN 'C'
ELSE IF (SALES GT 50 AND SALES LE 75) THEN 'B'
ELSE IF (SALES GT 75)                 THEN 'A'
ELSE ''; NOPRINT

COMPUTE HTML_SUBFOOT/A100       = '<tr><td class="subfootLine1">GRADE</td></tr>';
COMPUTE HTML_SLSQTRGRD/A100     = '<tr><td class="subfootLine2">' || SLSQTRGRD || '</td></tr>';
COMPUTE HTML_SLSQTRPNT/A100     = '<tr><td class="subfootLine3">' || FPRINT(SLSQTRPNT, 'P4', 'A5') || '  x  Weight 24%</td></tr>';
COMPUTE HTML_BLNKRW2/A100       = '<tr><td class="subfootLine4">&|nbsp;</td></tr>';

ON TABLE HOLD AS HSALES1 FORMAT ALPHA
END
-RUN

-HTMLFORM BEGIN
<html>
<head>
    <title>WebFOCUS Report</title>
    <style>
        table {
            font-family: Calibri; color: white; font-size: 20pt; font-weight: bold; text-align: center;
            background-color: rgb(44,189,156); border-collapse: collapse;
        }

        td { padding-left: 6pt; padding-right: 6pt; }

        .HEADER { font-size: 18pt; }
        .SALES { font-size: 32pt; }
        .BLNKRW { font-size: 20pt; }
        .LINES { font-size: 12pt; color: #808080; }
        .subfootLine1 { font-family: Arial; font-size: 10pt; }
        .subfootLine2 { font-family: Arial; font-size: 32pt; }
        .subfootLine3 { font-family: Arial; font-size: 12pt; background-color: rgb(154,220,206); }
        .subfootLine4 { font-size: 18pt; }
    </style>
</head>

<body>

<table>
!IBI.FIL.HSALES1;
</table>

</body>
</html>
-HTMLFORM END




Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
July 28, 2016, 08:22 AM
Maggie McBride
Thanks so much Francis! Sorry for the delayed response; I was on vacation. I guess I am going to have to learn HTML too!


WebFOCUS 8.1.04
Windows, All Outputs
July 28, 2016, 09:45 AM
Francis Mariani
quote:
I guess I am going to have to learn HTML too!

As far as I can tell, the current mantra is "I don't have to learn anything, because the GUI can do it for me"!


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server