Is there any way to get the SUBHEAD and SUBFOOT background colors to match the background color of the data row that they surround? The data rows have alternating colors and I want the SUBHEAD and SUBFOOT to use the same alternating colors.

This message has been edited. Last edited by: jbhurt@dst,

TABLE FILE CAR
PRINT
CAR
DEALER_COST
BY COUNTRY
ON COUNTRY SUBHEAD
"COUNTRY SUBHEAD"
ON COUNTRY SUBFOOT
"COUNTRY SUBFOOT"
ON COUNTRY SUBTOTAL AS '*TOTAL'
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
DEFMACRO=COND0001,
MACTYPE=RULE,
WHEN=N1 EQ 'ENGLAND',
$
DEFMACRO=COND0002,
MACTYPE=RULE,
WHEN=N1 EQ 'JAPAN',
$
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=10,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=DATA,
COLUMN=N3,
BACKCOLOR='OLIVE',
MACRO=COND0001,
$
TYPE=DATA,
COLUMN=N3,
BACKCOLOR='YELLOW',
MACRO=COND0002,
$
TYPE=DATA,
COLUMN=N1,
BACKCOLOR='OLIVE',
MACRO=COND0001,
$
TYPE=DATA,
COLUMN=N1,
BACKCOLOR='YELLOW',
MACRO=COND0002,
$
TYPE=DATA,
COLUMN=N2,
BACKCOLOR='OLIVE',
MACRO=COND0001,
$
TYPE=DATA,
COLUMN=N2,
BACKCOLOR='YELLOW',
MACRO=COND0002,
$
TYPE=SUBTOTAL,
BY=1,
BACKCOLOR='OLIVE',
MACRO=COND0001,
$
TYPE=SUBTOTAL,
BY=1,
BACKCOLOR='YELLOW',
MACRO=COND0002,
$
TYPE=SUBFOOT,
BY=1,
BACKCOLOR='OLIVE',
MACRO=COND0001,
$
TYPE=SUBFOOT,
BY=1,
BACKCOLOR='YELLOW',
MACRO=COND0002,
$
TYPE=SUBHEAD,
BY=1,
BACKCOLOR='OLIVE',
MACRO=COND0001,
$
TYPE=SUBHEAD,
BY=1,
BACKCOLOR='YELLOW',
MACRO=COND0002,
$
ENDSTYLE
END

Using the alternative row color in the data gives more visibility on it and the color change, from one to the other, is based on the number of detailed data to display.

I don't think that it's possible to have the same alternative color pattern for the SUBHEAD and SUBFOOT because their is always only one of them per BY level used for SUBHEAD and SUBFOOT.

But you can change their color as you probably already know but they will not match the same pattern as the data. The goal of the SUBHEAD and SUBFOOT is to have distinguished row from the data...

TABLE FILE CAR
PRINT CAR AS 'Car'
      MODEL AS 'Model'
      DEALER_COST AS 'Dealer,Cost'
BY COUNTRY NOPRINT
ON COUNTRY SUBHEAD "Subhead <COUNTRY"
ON COUNTRY SUBFOOT "Subfoot <COUNTRY"

ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     LEFTMARGIN=0.250000,
     RIGHTMARGIN=0.250000,
     TOPMARGIN=0.250000,
     BOTTOMMARGIN=0.250000,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
     PAGECOLOR='WHITE',
$
TYPE=REPORT,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=8,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
     RIGHTGAP=0.027778,
     LEFTGAP=0.027778,
     TOPGAP=0.027778,
     BOTTOMGAP=0.013889,
$
TYPE=DATA,
     BACKCOLOR=( RGB(230 230 230) 'WHITE' ),
$
TYPE=TITLE,
     COLOR='WHITE',
     BACKCOLOR=RGB(4 37 80),
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=SUBHEAD,
     STYLE=BOLD,
     COLOR='WHITE',
     BACKCOLOR='BLUE',
$
TYPE=SUBFOOT,
     STYLE=BOLD,
     COLOR='WHITE',
     BACKCOLOR='GREEN',
$
ENDSTYLE
END
-RUN

Thanks both of you for your input. Martin, you definitely understand the issue I'm having and its unfortunate that there isn't an exact fix. My table does have a one-to-one grouping of the subhead and subfoot to the data row and I'll be using your design idea to better break the data up.

Thanks again for your help.