In the sample code below, the bottom border formatting on the dealer_cost and retail_cost columns doesn't work. If you comment out the free text "Europe", it does. Or if you use, TYPE=TITLE, BORDER-BOTTOM=LIGHT, $ instead of the column specific bottom border formats, you get a bottom border under all of the columns. I, however, only want the bottom border under the dealer_cost and retail_cost columns. Any ideas on how to get that to work?
TABLE FILE CAR
SUM
DEALER_COST
RETAIL_COST
FOR COUNTRY
"EUROPE" OVER
ENGLAND AS 'ENGLAND' LABEL ENG OVER
ITALY AS 'ITALY' LABEL ITL OVER
BAR OVER
RECAP TOTEUR = ENG + ITL; AS 'TOTAL EUROPE' OVER
"ASIA" OVER
JAPAN AS 'JAPAN' LABEL JAP OVER
BAR OVER
RECAP TOT = TOTEUR + JAP; AS 'TOTAL' OVER
BAR AS '='
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
LEFTMARGIN=0.5,
RIGHTMARGIN=0.0,
TOPGAP=.025,
BOTTOMGAP=.025,
RIGHTGAP=.15,
LEFTGAP=.15,
TOPMARGIN=0.5,
BOTTOMMARGIN=0.0,
ORIENTATION=LANDSCAPE,
SQUEEZE=ON,
$
TYPE=REPORT,
FONT='TIMES NEW ROMAN',
SIZE=8,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=TITLE, COLUMN=DEALER_COST, BORDER-BOTTOM=LIGHT, $
TYPE=TITLE, COLUMN=RETAIL_COST, BORDER-BOTTOM=LIGHT, $
END
Bethany
Server Environment: Win2K3 Server WebFOCUS 7.13 Apache Tomcat standalone application server
September 23, 2008, 04:20 PM
Darin Lee
I would open a case with techsupport on this one. I played with it for a minute and found the following. Any text other than blanks in ANY line before the first FOR field causes the underlines on column title to disappear. If you add " " OVER as the first line, you get column titles underlined, but they are moved down a line. If you put 'FRANCE' OVER as the very first line under the FOR, you get correct underlines. You can use TYPE=TITLE, COLUMN=DEALER_COST, STYLE=UNDERLINE,$ in the stylesheet, but when I run your code with this, I get double underlines under the column titles.
Seems like there are several things going on with this that should not.
Regards,
Darin
In FOCUS since 1991 WF Server: 7.7.04 on Linux and Z/OS, ReportCaster, Self-Service, MRE, Java, Flex Data: DB2/UDB, Adabas, SQL Server Output: HTML,PDF,EXL2K/07, PS, AHTML, Flex WF Client: 77 on Linux w/Tomcat
September 23, 2008, 04:23 PM
LEX-IA
Hi,
I had a similar problem
Here is a workaround:
TABLE FILE CAR
SUM
DEALER_COST
RETAIL_COST
FOR COUNTRY
"EUROPE" LABEL TU OVER
ENGLAND AS 'ENGLAND' LABEL ENG OVER
ITALY AS 'ITALY' LABEL ITL OVER
BAR OVER
RECAP TOTEUR = ENG + ITL; AS 'TOTAL EUROPE' OVER
"ASIA" OVER
JAPAN AS 'JAPAN' LABEL JAP OVER
BAR OVER
RECAP TOT = TOTEUR + JAP; AS 'TOTAL' OVER
BAR AS '='
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
LEFTMARGIN=0.5,
RIGHTMARGIN=0.0,
TOPGAP=.025,
BOTTOMGAP=.025,
RIGHTGAP=.15,
LEFTGAP=.15,
TOPMARGIN=0.5,
BOTTOMMARGIN=0.0,
ORIENTATION=LANDSCAPE,
SQUEEZE=ON,
$
TYPE=REPORT,
FONT='TIMES NEW ROMAN',
SIZE=8,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
GRID=OFF,
$
TYPE=TITLE, COLUMN=DEALER_COST,LABEL=TU, BORDER-TOP=LIGHT,$
TYPE=TITLE, COLUMN=RETAIL_COST,LABEL=TU, BORDER-TOP=LIGHT, $
END
Hope this helpsThis message has been edited. Last edited by: LEX-IA,
PROD: WebFOCUS 7.1.0 on Linux/Tomcat 5.5.12 (standalone)/Informix on AIX TEST: WebFOCUS 7.1.3 on Linux/Tomcat 5.5.16 (standalone)/Informix on AIX
September 23, 2008, 04:26 PM
Bethany
Thanks for looking. I'll give tech support a call on this one.
Server Environment: Win2K3 Server WebFOCUS 7.13 Apache Tomcat standalone application server
September 23, 2008, 04:34 PM
Bethany
Thanks LEX-IA! That should do the trick!
Server Environment: Win2K3 Server WebFOCUS 7.13 Apache Tomcat standalone application server
September 23, 2008, 04:34 PM
LEX-IA
Did the tweak I made to your example help? I used label and border-top instead of border-bottom?
PROD: WebFOCUS 7.1.0 on Linux/Tomcat 5.5.12 (standalone)/Informix on AIX TEST: WebFOCUS 7.1.3 on Linux/Tomcat 5.5.16 (standalone)/Informix on AIX
September 23, 2008, 04:35 PM
LEX-IA
Cool!
PROD: WebFOCUS 7.1.0 on Linux/Tomcat 5.5.12 (standalone)/Informix on AIX TEST: WebFOCUS 7.1.3 on Linux/Tomcat 5.5.16 (standalone)/Informix on AIX