-* File rartest1.fex

SET PAGE      = NOLEAD
SET STYLEMODE = FIXED
SET PANEL     = 200
-RUN

FILEDEF RARFILE1 DISK rarfile1.txt
-RUN

-WRITE RARFILE1 NAX01A N NAX 23685895.35 24684053.56 24584281.18 21986382.76
-WRITE RARFILE1 NAX01B N NAX 27141462.90 28219119.02 27991396.95 24804236.62
-WRITE RARFILE1 NAX01C N NAX 22814271.58 23223617.55 23347572.29 20584141.55
-WRITE RARFILE1 NAX01D N NAX   159373.15   168432.05   202199.81   169849.26
-WRITE RARFILE1 NAX01E N NAX      989.77     3688.19    12359.59     2872.22
-WRITE RARFILE1 NAX04H N NAX  1553106.40  1604704.88  1597666.69  1460675.89

FILEDEF MASTER DISK rarfile1.mas
-RUN

-WRITE MASTER FILENAME=RARFILE1, SUFFIX=FIX, $
-WRITE MASTER SEGNAME=RARFILE1, $
-WRITE MASTER FIELDNAME=RARCODE    , FORMAT=A06    , ACTUAL=A06, $
-WRITE MASTER FIELDNAME=FILL1      , FORMAT=A01    , ACTUAL=A01, $
-WRITE MASTER FIELDNAME=RARPREF1   , FORMAT=A01    , ACTUAL=A01, $
-WRITE MASTER FIELDNAME=FILL1      , FORMAT=A01    , ACTUAL=A01, $
-WRITE MASTER FIELDNAME=RARPREF3   , FORMAT=A03    , ACTUAL=A03, $
-WRITE MASTER FIELDNAME=REV201011  , FORMAT=P17.2BC, ACTUAL=A12, $
-WRITE MASTER FIELDNAME=REV201012  , FORMAT=P17.2BC, ACTUAL=A12, $
-WRITE MASTER FIELDNAME=REV201101  , FORMAT=P17.2BC, ACTUAL=A12, $
-WRITE MASTER FIELDNAME=REV201102  , FORMAT=P17.2BC, ACTUAL=A12, $
-RUN

TABLE FILE RARFILE1
SUM
REV201011/P14.2C AS '201011'
REV201012/P14.2C AS '201012'
REV201101/P14.2C AS '201101'
REV201102/P14.2C AS '201102'

COMPUTE DIFF2/P14.2C = REV201102 - REV201101;       AS 'B/(W),$'
COMPUTE PERC2/D6.1  = DIFF2 / ABS(REV201101) * 100; AS 'B/(W),%'

FOR RARCODE
"A) NET INTEREST EARNINGS (NAX) - CORE" OVER
"1. PERSONAL DEPOSITS" OVER
NAX01A AS '    a) Primary Chequing Accounts'      LABEL NAX01A      OVER
NAX01B AS '    b) Interest Chequing Accounts'     LABEL NAX01B      OVER
RECAP NAX01HIGH/P14.2C = NAX01A + NAX01B;
AS 'SUBTOTAL: High Spread Deposits'               LABEL NAX01HIGH   OVER
NAX01C AS '    c) Premium Rate Savings and SSA'   LABEL NAX01C      OVER
NAX01D AS '    d) Tax Free Savings Accounts'      LABEL NAX01D      OVER
NAX04H AS '    e) Accounts in Overdraft'          LABEL NAX04H      OVER
NAX01E AS '    f) Other Personal Deposit / Recon. Amt' LABEL NAX01E OVER
BAR OVER
RECAP NAX01PD/P14.2C = (NAX01A + NAX01B) + NAX01C + NAX01D + NAX01E + NAX04H;
AS 'TOTAL: PERSONAL DEPOSITS (1)'                 LABEL NAX01PD     OVER
" "
END
-RUN

                                                                                                                                     B/(W)    B/(W)
                                                        201011             201012             201101             201102              $        %
                                                        ------             ------             ------             ------              -----    -----
 A) NET INTEREST EARNINGS (NAX) - CORE
 1. PERSONAL DEPOSITS
     a) Primary Chequing Accounts                23,685,895.35      24,684,053.56      24,584,281.18      21,986,382.76      -2,597,898.42    -10.6
     b) Interest Chequing Accounts               27,141,462.90      28,219,119.02      27,991,396.95      24,804,236.62      -3,187,160.33    -11.4
 SUBTOTAL: High Spread Deposits                  50,827,358.25      52,903,172.58      52,575,678.13      46,790,619.38      -5,785,058.75   -21.95
     c) Premium Rate Savings and SSA             22,814,271.58      23,223,617.55      23,347,572.29      20,584,141.55      -2,763,430.74    -11.8
     d) Tax Free Savings Accounts                   159,373.15         168,432.05         202,199.81         169,849.26         -32,350.55    -16.0
     e) Accounts in Overdraft                     1,553,106.40       1,604,704.88       1,597,666.69       1,460,675.89        -136,990.80     -8.6
     f) Other Personal Deposit / Recon. Amt             989.77           3,688.19          12,359.59           2,872.22          -9,487.37    -76.8
                                             -----------------  -----------------  -----------------  -----------------  -----------------  -------
 TOTAL: PERSONAL DEPOSITS (1)                    75,355,099.15      77,903,615.25      77,735,476.51      69,008,158.30      -8,727,318.21  -135.12
  

Francis

Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server

RECAP R_TOTAL1(3,*,3) = (R_TOTAL1(*-1) - R_TOTAL1(*-2) ) / R_TOTAL1(*-2) * 100; OVER

Francis

Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server

quote:

A calculation can use a specific column as a base, and refer to all other columns by their displacement from that column. The column to the left of the base column has a displacement of -1 relative to the base column. The column to the right has a displacement of +1. For example,

COMP=FIX(*)-FIX(*-1);
can refer to the change in fixed assets from one period to the next. The reference to COMP=FIX(*) is equivalent to COMP=FIX.

When referring to a prior column, the column must already have been retrieved, or its value is zero.

Francis

Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server