Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] How to identify the first column of GRANDTOTAL

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] How to identify the first column of GRANDTOTAL
 Login/Join
 
JC Zhu
Member
posted
I need to create a drill down link from the first column in the column total row. See following example. I can only seem to identify the entire row as "TYPE=GRANDTOTAL". So now the drill down link is set for all columns of the table while I only want the first column in the grand total row to have the link. Can that be done? I tried "COLUMN=N1" and it doesn't work.

TABLE FILE CAR
SUM
SALES
BY LOWEST COUNTRY
ACROSS LOWEST SEATS
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
TYPE=REPORT,
GRAPHCOLOR='GREEN',
$
TYPE=ACROSSVALUE,
ACROSS=1,
BACKCOLOR='WHITE',
$
TYPE=GRANDTOTAL,
URL=http://test,
$
TYPE=REPORT,
OBJECT=MENU,
COLOR='WHITE',
HOVER-COLOR=RGB(66 70 73),
BACKCOLOR=RGB(102 102 102),
HOVER-BACKCOLOR=RGB(218 225 232),
BORDER-COLOR='WHITE',
$
TYPE=REPORT,
OBJECT=STATUS-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
TYPE=REPORT,
OBJECT=CURRENT-ROW,
HOVER-BACKCOLOR=RGB(218 225 232),
BACKCOLOR=RGB(200 200 200),
$
TYPE=REPORT,
OBJECT=CALC-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
ENDSTYLE
END

This message has been edited. Last edited by: <Kathryn Henning>,


WebFOCUS 7.7.3
Windows, All Outputs
 
Posts: 28 | Registered: January 19, 2012Report This Post
Severus.snape
Platinum Member
posted Hide Post
Hi,

Try
TYPE=GRANDTOTAL,
COLUMN=ROWTOTAL(1),
URL=http://test,
$

replace 1 with what ever column number you want.

thanks
Sashanka


WF 7.7.03/Windows/HTML,PDF,EXL
POC/local Dev Studio 7.7.03 & 7.6.11
 
Posts: 103 | Registered: June 12, 2009Report This Post
Severus.snape
Platinum Member
posted Hide Post
Never mind the above code ..it does not work..
but I tested out this one and it works:

 
TABLE FILE CAR
SUM 
SALES
BY LOWEST COUNTRY
ACROSS LOWEST SEATS
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
-*INCLUDE = endeflt,
$
TYPE=REPORT,
GRAPHCOLOR='GREEN',
$
TYPE=ACROSSVALUE,
ACROSS=1,
BACKCOLOR='WHITE',
$
TYPE=GRANDTOTAL,
COLUMN=C2,
URL=http://test,
$
TYPE=REPORT,
OBJECT=MENU,
COLOR='WHITE',
HOVER-COLOR=RGB(66 70 73),
BACKCOLOR=RGB(102 102 102),
HOVER-BACKCOLOR=RGB(218 225 232),
BORDER-COLOR='WHITE',
$
TYPE=REPORT,
OBJECT=STATUS-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
TYPE=REPORT,
OBJECT=CURRENT-ROW,
HOVER-BACKCOLOR=RGB(218 225 232),
BACKCOLOR=RGB(200 200 200),
$
TYPE=REPORT,
OBJECT=CALC-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
ENDSTYLE
END


WF 7.7.03/Windows/HTML,PDF,EXL
POC/local Dev Studio 7.7.03 & 7.6.11
 
Posts: 103 | Registered: June 12, 2009Report This Post
JC Zhu
Member
posted Hide Post
Thanks for the quick answer. Is there a way to have the link from the "Total" cell in the last row? That's what I meant by first column in my original post.


WebFOCUS 7.7.3
Windows, All Outputs
 
Posts: 28 | Registered: January 19, 2012Report This Post
Alex
Platinum Member
posted Hide Post
TYPE=GRANDTOTAL, COLUMN=C2, FOCEXEC=ibisamp/carinst,$


WF 7.7.04, WF 8.0.7, Win7, Win8, Linux, UNIX, Excel, PDF
 
Posts: 175 | Location: Pomona, NY | Registered: August 06, 2003Report This Post
Tom Flynn
Expert
posted Hide Post
  
SET ASNAMES = ON, NODATA = 0
TABLE FILE CAR
SUM 
   SALES
  BY COUNTRY
  BY SEATS
 ON TABLE HOLD AS HOLD1
END
-RUN
DEFINE FILE HOLD1
  XCOUNTRY/A10 = 'Total';
END
TABLE FILE HOLD1
SUM 
   SALES
  BY XCOUNTRY AS 'COUNTRY'
  BY SEATS
 ON TABLE HOLD AS HOLD2
END
-RUN
TABLE FILE HOLD1
PRINT 
   SALES
  BY COUNTRY
  BY SEATS
 ON TABLE HOLD AS HOLD3
MORE 
FILE HOLD2
END
-RUN
DEFINE FILE HOLD3
 XSORT/I2 = DECODE COUNTRY('Total' 99 ELSE 1);
END   
TABLE FILE HOLD3
SUM 
SALES
BY XSORT NOPRINT
BY COUNTRY
ACROSS SEATS
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
TYPE=REPORT,GRAPHCOLOR='GREEN',$
TYPE=ACROSSVALUE,ACROSS=1,BACKCOLOR='WHITE',$
TYPE=DATA, COLUMN=N2, FOCEXEC=PROGRAM_NAME, STYLE=BOLD, COLOR=BLUE, WHEN=COUNTRY EQ 'Total',$
ENDSTYLE
END
-EXIT


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe
 
Posts: 1972 | Location: Centennial, CO | Registered: January 31, 2006Report This Post
JC Zhu
Member
posted Hide Post
Tom, thanks for the solution. It works. I was hoping there is a way to identify that total column by using "type=GRANDTOTAL", but it looks like WebFocus does not really support that.


WebFOCUS 7.7.3
Windows, All Outputs
 
Posts: 28 | Registered: January 19, 2012Report This Post
Severus.snape
Platinum Member
posted Hide Post
This feature --identifying the TOTAL tags in the style sheet is available now on the RS version 7.7.05..along with some other cool things.

thanks
Sashanka


WF 7.7.03/Windows/HTML,PDF,EXL
POC/local Dev Studio 7.7.03 & 7.6.11
 
Posts: 103 | Registered: June 12, 2009Report This Post
Francis Mariani
Expert
posted Hide Post
quote:
identifying the TOTAL tags in the style sheet is available now on the RS version 7.7.05..along with some other cool things
I wonder where this is documented, can't seem to find anything...


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
Francis Mariani
Expert
posted Hide Post
It appears to be documented ONLY in the New Features doc:

WebFOCUS New Features Version 7 Release 7.05 > Reporting Language Enhancements > Styling Tags for SUBTOTAL and GRANDTOTAL Lines

How to Style Subtotal and Grand Total Tags 

TYPE={SUBTOTAL|GRANDTOTAL}, OBJECT=TAG,
  [FONT=font], [SIZE=size], [STYLE=style],
  [COLOR={color|RGB({r g b|#hexcolor})],
  [drilltype=drillparms], $
OBJECT=TAG is the key.


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
Francis Mariani
Expert
posted Hide Post
TABLE FILE CAR
SUM
LENGTH
BY COUNTRY
ACROSS BODYTYPE AS ''
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'

ON TABLE SET PAGE NOLEAD
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='ARIAL', SIZE=9, BORDER=1, BORDER-COLOR=SILVER, $

TYPE=TITLE, COLOR=BLUE, STYLE=BOLD, $
TYPE=ACROSSVALUE, COLOR=BLUE, STYLE=BOLD, $
TYPE=GRANDTOTAL, STYLE=BOLD, $

TYPE=GRANDTOTAL, OBJECT=TAG, COLOR=GREEN, FOCEXEC=NONE, $

TYPE=GRANDTOTAL, 
FOCEXEC=APP/CHG_MGMT_AGING_DETAIL(BODYTYPE=A1), $

ENDSTYLE
END


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] How to identify the first column of GRANDTOTAL

Copyright © 1996-2020 Information Builders