Is it true that we cannot use a "complex condition" in a WHEN statement in the style sheet, such as

TABLE FILE CAR
SUM DCOST RCOST MPG BY COUNTRY BY CAR BY MODEL
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=RCOST, COLOR=RED, WHEN = RCOST GT 12000 AND MPG LT 15,$
ENDSTYLE
END

How about using a DEFINEd field in the WHEN statement? I cannot get either of these to work, as follows:

DEFINE FILE CAR
BAD_CONDITION/A1 = IF RCOST GT 12000 AND MPG LT 15 THEN 'Y' ELSE 'N' ;
END
TABLE FILE CAR
SUM DCOST RCOST MPG BY COUNTRY BY CAR BY MODEL
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=RCOST, COLOR=RED, WHEN = BAD_CONDITION EQ 'Y',$
TYPE=REPORT, COLUMN=DCOST, COLOR=RED, WHEN = DCOST GT 9999,$
TYPE=REPORT, COLUMN=MPG, COLOR=RED, WHEN = MPG LT 15,$
ENDSTYLE
END

I thought I did this in the past.

This message has been edited. Last edited by: Doug,

You must include the defined column in the report:

DEFINE FILE CAR
BAD_CONDITION/A1 = IF RCOST GT 12000 AND MPG LT 15 THEN 'Y' ELSE 'N' ;
END
TABLE FILE CAR
SUM 
DCOST RCOST MPG 
BAD_CONDITION NOPRINT
BY COUNTRY 
BY CAR 
BY MODEL
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=RCOST, COLOR=RED  , WHEN = BAD_CONDITION EQ 'Y',$
TYPE=REPORT, COLUMN=DCOST, COLOR=BLUE , WHEN = DCOST GT 9999,$
TYPE=REPORT, COLUMN=MPG  , COLOR=GREEN, WHEN = MPG LT 15,$
ENDSTYLE
END

quote:

I thought I did this in the past.

Thanks Francis, That must have been the piece that I know back then which I left out this time.

How about a "multi-Conditional", like this?

TYPE=REPORT, COLUMN=DCOST, COLOR=RED, WHEN = DCOST GT 9999 AND MPG LT 15,$

I guess that would be covered using the DEFINE...

It's better to use COMPUTE instead of DEFINE - after all you're doing this for report rows, not input data.

Thanks Francis... Good point