One of our customers asked for the possibility to convert a decimal number to hexadecimal. both in Dialog Manager and as a WebFOCUS function.
Here is what we came up with.

Dialog Manager:

  
-SET &ECHO=ALL;
-* File dec2hex.fex
-DEFAULT &DEC=123456789;
-SET &HEX=' ';
-SET &H0=&DEC;
-#NXTHEX
-SET &H1=&H0/16;
-SET &HN=&H0 - &H1 * 16;
-SET &HX=DECODE &HN(0 '0' 1 '1' 2 '2' 3 '3' 4 '4' 5 '5' 6 '6' 7 '7' 8 '8' 9 '9' 10 'A' 11 'B' 12 'C' 13 'D' 14 'E' 15 'F');
-SET &HEX = &HX | &HEX;
-IF &H0 LE 15 GOTO #DONE;
-SET &H0 = &H1;
-GOTO #NXTHEX
-#DONE
-TYPE &DEC = &HEX

WebFOCUS Function

  
-SET &ECHO=ALL;
-* File f_dec2hex.fex
DEFINE FUNCTION DEC2HEX (DEC/I9)
H0/I9=DEC;
HEX/A9=' ';
-REPEAT #HLOOP FOR &I FROM 1 TO 9;
-SET &J=&I-1;
H&I/I9=H&J / 16;
HN/I9=H&J - H&I * 16;
HX/A1=DECODE HN(0 '0' 1 '1' 2 '2' 3 '3' 4 '4' 5 '5' 6 '6' 7 '7' 8 '8' 9 '9' 10 'A' 11 'B' 12 'C' 13 'D' 14 'E' 15 'F');
HEX/A9=HX | SUBSTR(9, HEX, 1, 8, 8, 'A8');
-#HLOOP
DEC2HEX/A9=TRIM('L',HEX,9,'0',1,'A9') ;
END
-RUN
TABLE FILE CAR
SUM SALES 
COMPUTE HSALES/A9=DEC2HEX(SALES);
BY COUNTRY
END

That's great Danny, but what if the server has DMPRECISION set to anything other than the default 0? Might be worthwhile using INT function in the DM solution? As in -SET &H1=INT(&H0/16);

Now, where's that like button?

T

Actually, you can convert entire Bytes (0-255) to HEX at once using HEXBYT and UFMT.
I wrote this once, but ISTR that this function became deprecated - but by what I don't remember...

-SET &_INTEGER = &INTEGER;

-SET &HEX = '';
-REPEAT :HXLOOP WHILE &_INTEGER GT 0;
-SET &BYTE = DMOD(&_INTEGER, 256, 'I3');
-SET &_INTEGER = (&_INTEGER - &BYTE) / 256;
-SET &HEX = UFMT(HEXBYT(&BYTE, 'A1'), 3, 'A2') || &HEX;
-:HXLOOP

More likes, plus the memory that you could call the function from DM anyway Danny

T

Tony,
Oh so true!