From a launch page a user can select a unit manager to see the most popular open cases for time period looking back in time (30, 45, or 90 days).

Here is a sample look at this page showing open work orders originated by customers or other means.

The subsequent report shows that the '223' work type was opened by customer 5 times in the last 30 days.

List of Open work Orders

WDC WORKDESC SWDC 
  
OPEN CUSTOMER ORDERS  
  
223 TURN OFF FOR REPAIRS	5 
230 INSPECT SUNKEN ROADWAY	4 
209 INSPECT FOR VALVE LEAK	3 
224 TURN ON			3 
119 INSPECT SURCHARGED SEWER	2 
041 AIR IN LINE			1 
108 INSPECT FOR SEWER LEAK	1 
405 REPLACE METER COVER		1 


OPEN WORK ORDERS  
  
301 LOCATE/ADJ CURB BOX TO GRADE	3 
017 MISC WATER MAINT			2 
200 SHUT DOWN/CHARGE WTR MAIN		2 
227 REPAIR FIRE HYDRANT LEAK		2 
258 LOCATE/ADJUST VALVE BOX		2 
303 CURB STOP INOPERABLE		2 
406 REPLACE METER F&C			2 
058 REINSPECT FOR SERVICE LEAK		1 
221 TURN OFF FOR LEAK			1 
289 REPAIR VALVE			1 
293 REPAIR FH LEAD VALVE LEAK		1 
425 VALVE WORK ON LARGE METER-01	1 

By clicking on the 223 value the user can run a
detail report for all '223' work orders.

I am trying to create a ALT tag to display a
specific drill link when the user hovers over a
work order in the 'open customer order' section, and a different link when the user hovers over a work order in the 'open work order' section.

So far, I have been testing this code:

DEFINE FILE ZXDB9
TXTORDST/A30 =
  IF ORDST EQ 'C' THEN 'OPEN CUSTOMER ORDERS'
                  ELSE 'OPEN WORK ORDERS';
END

TABLE FILE ZXDB9
SUM SWDC
BY TXTORDST NOPRINT
BY HIGHEST SWDC NOPRINT
BY ASSIGNEE NOPRINT
BY WDC
BY WORKDESC
-*BY ORDST
ON TXTORDST SKIP-LINE SUBHEAD
""
"<TXTORDST "
-*
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
LEFTMARGIN=0.000000,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT=ARIAL,
SIZE=9,
COLOR=BLACK,
STYLE=NORMAL,
$
TYPE=DATA, 
COLOR=BLACK,
SIZE=10,
STYLE=NORMAL,
$
TYPE=DATA, 
SIZE=10,
COLUMN=N4, 
COLOR=PURPLE,
STYLE=UNDERLINE,
WHEN=ORDST EQ 'C',
FOCEXEC=app/rpt11(ASGX=ASSIGNEE WDCX=WDC), 
TARGET='_self', 
ALT='Open Customer Orders', 
$
TYPE=DATA, 
SIZE=10,
COLUMN=N4,
COLOR=ORANGE,
STYLE=UNDERLINE,
WHEN=ORDST EQ 'O',
FOCEXEC=app/rpt01(ASGX=ASSIGNEE WDCX=WDC), 
ALT='Open Work Orders', 
$
TYPE=TITLE,
STYLE=BOLD,
COLOR=RED,
$
ENDSTYLE
END
-RUN

-EXIT

But I cannot get it to work. Has anyone tried to
do this with success?

Thanks!

This message has been edited. Last edited by: Tomsweb,

You need to include the column that is the subject of the WHEN phrase in your report request. Add

ORDST NOPRINT

or

BY ORDST NOPRINT

to the report.

Thanks Francis. It works!

BTW, do you prefer using the DRILLMENUITEM= syntax or ALT= syntax?

one is passive, one is active.
the passive one doesn't always show up, when repeatedly passing over the same link. by design.