Hi,
In webfocus 7.1,i am having two tables in one fex file.I want to get these two tables side by side in excel .using format exl2k ,i am getting the tables one after the other .is it possible to get the tables side by side?

This message has been edited. Last edited by: Kerry,

Check out this
http://techsupport.informationbuilders.com/sps/11682038.html

Hi Prarie,
With the help of techsupport site which you suggested ,I was able to get 2 different tables in excel side by side.Thanks a ton for your support.

Great!

Try this

TABLE FILE CAR
SUM SALES
BY COUNTRY
ON TABLE HOLD AS HLDFILE1 FORMAT HTMTABLE
ON TABLE NOTOTAL
END


TABLE FILE CAR
SUM SALES
BY MODEL
ON TABLE HOLD AS HLDFILE2 FORMAT HTMTABLE
ON TABLE NOTOTAL
END
SET HTMLFORMTYPE=XLS

-* Below code is not showing in the page properly
-* All you have to do is place the files in html table row side by side.



-HTMLFORM BEGIN
<TABLE>
<TR>
<TD>
!IBI.FIL.HLDFILE1;
</TD>
<TD>
!IBI.FIL.HLDFILE2;
</TD>
</TR>
</TABLE>
-HTMLFORM END

This message has been edited. Last edited by: <VenuPalvai>,

quote:

http://techsupport.informationbuilders.com/sps/11682038.html

this link doesn't work, is there a new link?

Hi Mikey,

There isn't a new link to this document. Here are the original contents:

Problem Section

Is there a way with COMPOUND EXL2K reports to allow two of the reports on
the same worksheet to be side-by-side instead of top-down? For example,
the first worksheet would consist of one report and the second worksheet
would have two reports by next to each other on the worksheet instead of
one after the other.

In this particular case, the two side-by-side reports are from the
same file. Only the selection on the same field is different for the
two reports.

Solution Section

The COMPOUND EXL2K option does not allow for side-by-side reports in the
output. However, you could combine the necessary data to a single file
and produce a single report that looks as if two separate reports were
created on the worksheet.

This technique demonstrates how to get the data into a format to be
side-by-side when you generate the COMPOUND EXL2K file.

 
DEFINE FILE CAR
BLANK/A1 WITH COUNTRY=' ';
END
MATCH FILE CAR
PRINT COUNTRY AS FCOUNTRY
      CAR AS FCAR
      MODEL AS FMODEL
      RCOST AS FRCOST
BY BLANK
IF COUNTRY EQ FRANCE
RUN
FILE CAR
PRINT COUNTRY AS ECOUNTRY
      CAR AS ECAR
      MODEL AS EMODEL
      RCOST AS ERCOST
BY BLANK
IF COUNTRY EQ ENGLAND
AFTER MATCH HOLD AS EFCAR OLD-OR-NEW
END
-RUN
TABLE FILE CAR
HEADING
"Report 1: W Germany"
PRINT DCOST BY COUNTRY BY CAR
IF COUNTRY EQ 'W GERMANY'
ON TABLE PCHOLD FORMAT EXL2K OPEN
ON TABLE SET STYLE *
type=report, color=red, $
type=data, backcolor=yellow, $
type=heading, color=blue, $
END
TABLE FILE EFCAR
HEADING
" "
" "
"Report 2: France and Report 3: England"
PRINT FCOUNTRY AS COUNTRY
      FCAR AS CAR
      FMODEL AS MODEL
      FRCOST AS RCOST
      BLANK AS ''
      BLANK AS ''
      ECOUNTRY AS COUNTRY
      ECAR AS CAR
      EMODEL AS MODEL
      ERCOST AS RCOST
ON TABLE PCHOLD FORMAT EXL2K CLOSE
ON TABLE SET STYLE *
type=report, color=lime, backcolor=fuschia, style=bold, $
type=title, color=black, style=bold+italic, $
type=heading, backcolor=black, $
END
 

Regards,

Kathryn

except that they're not side by side, there on 2 separate tabs
???

venu's solution works. nice!