Hello

Below is a graph with CAR file.

I have similar graph and I am working to get a legend like this.
It should show 3 colors with text like "ITALY Amount", "JAPAN Amount", "W GERMANY Amount" beside each color.
Please suggest.

-SET &SEL1 = 'ITALY';
-SET &SEL2 = 'JAPAN';
-SET &SEL3 = 'W GERMANY';

GRAPH FILE CAR
SUM
SALES
BY COUNTRY AS '' NOPRINT
BY CAR AS ''
WHERE SALES GT 0;
WHERE COUNTRY EQ '&SEL1' OR '&SEL2' OR '&SEL3';
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET LOOKGRAPH VBAR2AX
ON GRAPH SET GRMERGE ON
ON GRAPH SET GRAPHSTYLE *
setTemplateFile("/images/tdg/template/IBISouthWestern.txt");
setLegendDisplay(true);
ENDSTYLE
ON GRAPH SET STYLE *
PAGESIZE='Letter',$
DEFMACRO=COND0001,MACTYPE=RULE,WHEN=COUNTRY EQ '&SEL1',$
DEFMACRO=COND0002,MACTYPE=RULE,WHEN=COUNTRY EQ '&SEL2',$
DEFMACRO=COND0003,MACTYPE=RULE,WHEN=COUNTRY EQ '&SEL3',$
TYPE=DATA,COLOR='RED',MACRO=COND0001,$
TYPE=DATA,COLOR='GREEN',MACRO=COND0002,$
TYPE=DATA,COLOR='YELLOW',MACRO=COND0003,$
ENDSTYLE
END

This message has been edited. Last edited by: <Kathryn Henning>,

You may need to use ANNOTATIONS to get this.

I never used ANNOTATIONS. Can you provide any example? I will search in forum as well.

Its not just text I am trying to display. It should be like legend with colored box beside each text.

quote:

Originally posted by Ram Prasad E:
You may need to use ANNOTATIONS to get this.

This message has been edited. Last edited by: Enigma006,

Hi,
You could try something like this:

DEFINE FILE CAR
 MYCOUNTRY/A50=IF COUNTRY EQ 'ITALY' THEN 'ITALY Amount' ELSE IF COUNTRY EQ 'JAPAN' THEN 'JAPAN Amount' ELSE IF COUNTRY EQ 'W GERMANY' THEN 'W GERMANY Amount';
END
GRAPH FILE CAR
SUM CAR.BODY.SALES
BY MYCOUNTRY
ACROSS CAR.COMP.CAR
WHERE COUNTRY EQ 'ITALY' OR 'JAPAN' OR 'W GERMANY';
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET ARGRAPHENGIN JSCHART
ON GRAPH SET VZERO OFF
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 0
ON GRAPH SET GRLEGEND 1
ON GRAPH SET GRXAXIS 1
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET STYLE *
*GRAPH_SCRIPT

setPieDepth(0);
setPieTilt(0);
setDepthRadius(0); 
setCurveFitEquationDisplay(false); 
setPlace(true); 

*END
*GRAPH_SCRIPT
setReportParsingErrors(false);
setSelectionEnableMove(false);
setFillColor(getSeries(0), new Color(255,0,0));
setFillColor(getSeries(1), new Color(0,255,0));
setFillColor(getSeries(2), new Color(255,255,0));

*END
ENDSTYLE
END

-RUN

  

Thanks.

quote:

Originally posted by nick z:
Hi,
You could try something like this:

DEFINE FILE CAR
 MYCOUNTRY/A50=IF COUNTRY EQ 'ITALY' THEN 'ITALY Amount' ELSE IF COUNTRY EQ 'JAPAN' THEN 'JAPAN Amount' ELSE IF COUNTRY EQ 'W GERMANY' THEN 'W GERMANY Amount';
END
GRAPH FILE CAR
SUM CAR.BODY.SALES
BY MYCOUNTRY
ACROSS CAR.COMP.CAR
WHERE COUNTRY EQ 'ITALY' OR 'JAPAN' OR 'W GERMANY';
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET ARGRAPHENGIN JSCHART
ON GRAPH SET VZERO OFF
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 0
ON GRAPH SET GRLEGEND 1
ON GRAPH SET GRXAXIS 1
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET STYLE *
*GRAPH_SCRIPT

setPieDepth(0);
setPieTilt(0);
setDepthRadius(0); 
setCurveFitEquationDisplay(false); 
setPlace(true); 

*END
*GRAPH_SCRIPT
setReportParsingErrors(false);
setSelectionEnableMove(false);
setFillColor(getSeries(0), new Color(255,0,0));
setFillColor(getSeries(1), new Color(0,255,0));
setFillColor(getSeries(2), new Color(255,255,0));

*END
ENDSTYLE
END

-RUN

  

Thanks.

thanks nick...this worked..
meanwhile I got it to work using compound pdf and displaying that legend using a dummy report but this is efficient.