Can someone please point me in the right direction?? I have a report that has a subfoot within it. I am trying to drill to another report thru the subfoot data.

 TYPE=SUBFOOT,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     TARGET='_blank',
     FOCEXEC=app/MyFex( \
     INV_L=N10 \
     ),
$ 

The report is HTML output. This doesn't seem to be working for the SUBFOOT it does work if I drill thru on the data above the SUBFOOT output. Any ideas on how to create this drill thru to another fex from the subfoot?

This message has been edited. Last edited by: ERINP,

Passing columnar notation to a drill in a subfoot doesn't seem logical to me as there are no columns. Maybe you could reproduce what you want with the CAR file and we can attempt a solution for you. What kind of data is the child program looking for?

Seems to work for me, the hyperlink appears on the field value of the second By statement's subfoot:

TABLE FILE CAR
SUM
SALES

BY COUNTRY SUBFOOT
"SUBFOOT1 LINE 1COUNTRY <COUNTRY"

BY CAR SUBFOOT
"SUBFOOT2 LINE 1 CAR <CAR"
"SUBFOOT2 LINE 2 COUNTRY <COUNTRY"

BY MODEL SUBFOOT
"SUBFOOT3 LINE 1 MODEL <MODEL"
"SUBFOOT3 LINE 2 CAR <CAR"
"SUBFOOT3 LINE 3 COUNTRY <COUNTRY"

ON TABLE SET STYLE *
TYPE=SUBFOOT, 
     BY=2, 
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     TARGET='_BLANK',
     FOCEXEC=APP/MYFEX( \
     CAR=CAR \
     COUNTRY=COUNTRY \
     ),
$ 
ENDSTYLE
END

Ginny,
The reason for the drill down on the subfoot is the result of an end-user request to format the TOTAL for a column of data different than the data in the column. The end-user would like comma seperated 2 decimal place data, but the TOTAL needs to have dollar signs, commas, and 2 decimal places. In order to accomodate this request I have created a SUBFOOT with the TOTAL for the column of data and reformatted it with the Dollar Sign. The CAR file example below is more in line with what I am 'attempting' to do.

 
TABLE FILE CAR
SUM
     'CAR.BODY.BODYTYPE'
     'CAR.SPECS.MPG'
     'CAR.BODY.SEATS'
     'CAR.BODY.SALES/P11.2C'
     COMPUTE TOT_SALES/P11.2CM = TOT.SALES; NOPRINT
   
BY 'CAR.ORIGIN.COUNTRY'
BY 'CAR.CARREC.MODEL'
WHERE COUNTRY = 'ENGLAND';
ON CAR.ORIGIN.COUNTRY SUBFOOT
" <+0> <+0> <+0>SUBFOOT1 LINE1 COUNTRY <+0> <TOT_SALES"
ON TABLE NOTOTAL
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
TYPE=SUBFOOT,
     STYLE=BOLD,
     JUSTIFY=RIGHT,
     HEADALIGN=BODY,
$
TYPE=SUBFOOT,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     TARGET='_BLANK',
     FOCEXEC=APP/MYFEX( \
     CAR=CAR.COMP.CAR \
     COUNTRY=CAR.ORIGIN.COUNTRY \
     ),
$
ENDSTYLE
END
 

I noticed that Francis' post had the BY=2 in it like my original example. When I saw this I realized the code was wrong for what I am trying to do. I have 2 BY fields, but I am using ON FIELDNAME SUBFOOT for only one of the two BY fields. In this example a click of the TOTAL for sales would pass the value of 'ENGLAND' to the app/MYFEX. I'm not sure I can make the association between a click on TOT_SALES and Pass the Country. In my actual code 'ENGLAND' would be an amper variable for this drill down. I can't get the TOT_SALES to show up as a hyperlink in my actual code even if I use a URL for the drill down (it works fine with the CAR file). Any other ideas would be greatly appreciated. Francis the code you supplied worked on my end just fine. I may need to try a watered down version of my code to see if I can get it to work.
Thanks,
Erin

I have figured out my issue with the drill down. In my first attempt I had added some styling for the different subfoot totals:

 TYPE=SUBFOOT,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     TARGET='_BLANK',
     FOCEXEC=APP/MYFEX( \
     CAR=CAR.COMP.CAR \
     COUNTRY=CAR.ORIGIN.COUNTRY \
     ),
$
TYPE=SUBFOOT,
     ITEM=8,
     COLSPAN=1,
$
TYPE=SUBFOOT,
     ITEM=9,
     COLSPAN=1,
$
TYPE=SUBFOOT,
     ITEM=10,
     COLSPAN=1,
$
TYPE=SUBFOOT,
     ITEM=11,
     COLSPAN=1,
$
 

When I removed the styling for ITEMs 8, 9, 10, and 11 the drill down works just fine. I think the styling was 'over riding' the drill down code for the subfoot total.
Without the example from Francis i would still be beating my head against my monitor. Thanks Francis.

Erin