One of my customers had the following request which I will state using the CAR file.

A report shows SALES BY COUNTRY:


When clicking on COUNTRY a new report is to be shown in the same window showing SALES BY COUNTRY BY CAR but only display the CARs for the clicked COUNTRY:


This is the solution I came up with:

  
-* File recursive.fex

-DEFAULTH &COUNTRY=' ';
-SET &XCAR=IF &COUNTRY EQ ' ' THEN '' ELSE 'CAR';

DEFINE FILE CAR
 XCAR/A16=IF COUNTRY EQ '&COUNTRY' THEN CAR ELSE ' ';
END

TABLE FILE CAR
SUM CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY
BY XCAR AS '&XCAR'
ON TABLE PCHOLD FORMAT HTML
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE SET EMPTYREPORT ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
 INCLUDE=endeflt,$
TYPE=DATA, COLUMN=N1, TARGET='_self', FOCEXEC=recursive(COUNTRY=CAR.ORIGIN.COUNTRY), $
ENDSTYLE
END

This message has been edited. Last edited by: Danny-SRL,

I don't know if there is a question in your post...

But here's another one:

DEFINE FILE CAR
	XCAR/A16 = IF COUNTRY EQ &COUNTRY THEN CAR ELSE '';
END

TABLE FILE CAR
	SUM	SALES
	BY	COUNTRY
	BY	XCAR
ON TABLE PCHOLD FORMAT HTML
END

...and another one...

TABLE FILE CAR
	SUM	SALES
	BY	COUNTRY
ON TABLE SET ASNAMES ON
ON TABLE HOLD AS H_COUNTRY
END

TABLE FILE CAR
	SUM	SALES
	BY	COUNTRY
	BY	CAR
WHERE COUNTRY EQ &COUNTRY
ON TABLE SET ASNAMES ON
ON TABLE HOLD AS H_CAR
END

MATCH FILE H_COUNTRY
	SUM	SALES AS 'CNTRY_SALES'
	BY	COUNTRY
RUN
FILE H_CAR
	SUM	ALL.SALES AS 'CAR_SALES'
	BY	COUNTRY
	BY	CAR
ON TABLE HOLD AS X OLD-OR-NEW
END

TABLE FILE X
	SUM COMPUTE SALES/D20 = IF FST.COUNTRY EQ &COUNTRY THEN CAR_SALES ELSE CNTRY_SALES;
	BY	COUNTRY
	BY	CAR
END

WebFocus : Inifite ways to skin a car

"skin a car"
ROFL

@susannah

It was actually a typo.. the R is next to the T. And 'we' type CAR alot more then CAT. :-) Just decided to leave it like that

Dave,
There was no question, I was just sharing and maybe hoped for a more elegant solution.
As for what you suggest, I don't see the recursivity.

Looks pretty elegant to me.

Thanks Waz.

@Danny

I thought you were looking for another way to create the output...

...the recursivity needed no enhancements. :-)