The column-value based color styling does not work in the following example - I do not get colours. v7.7.03 HF4. I don't think my syntax is wrong - am I missing something?

TABLE FILE CAR
SUM
COMPUTE FLG1/A1 = IF SALES LT 8000 THEN '1' ELSE IF SALES GT 8000 THEN '2';
SALES
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=SALES, COLOR=RED, WHEN= FLG1 EQ '1', $
TYPE=DATA, COLUMN=SALES, COLOR=GREEN, WHEN= FLG1 EQ '2', $
END

This message has been edited. Last edited by: Francis Mariani,

Maybe be a bug - seems to work if I remove the COMPUTE or move the COMPUTE below SALES after the SUM verb.

TABLE FILE CAR
 SUM
  SALES
  COMPUTE FLG1/A1 = IF SALES LT 8000 THEN '1' ELSE IF SALES GT 8000 THEN '2';
 BY COUNTRY
 BY CAR
 BY MODEL
 ON TABLE SET STYLE *
  TYPE=DATA, COLUMN=SALES, COLOR=RED, WHEN=SALES GT 8000, $
  TYPE=DATA, COLUMN=SALES, COLOR=BLUE, WHEN=SALES LT 8000, $
 ENDSTYLE
END

Francis, IF-THEN-ELSE logic, AND, put the COMPUTE after:

  
TABLE FILE CAR
SUM
SALES
COMPUTE FLG1/A1 = IF SALES LE 8000 THEN '1' ELSE '2';

BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=SALES, COLOR=RED, WHEN= FLG1 EQ '1', $
TYPE=DATA, COLUMN=SALES, COLOR=GREEN, WHEN= FLG1 EQ '2', $
END
-EXIT

This doesn't work:

TABLE FILE CAR
SUM
COMPUTE COL1/D1 = IF HEIGHT LT 8000 THEN 1 ELSE IF SALES GT HEIGHT THEN 2 ELSE 0;
COMPUTE COL2/D6 = LENGTH * HEIGHT * WIDTH;
SALES
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=SALES, COLOR=GREEN, WHEN= SALES GT 8000, $
TYPE=DATA, COLUMN=SALES, COLOR=RED, WHEN= SALES LT 8000, $
END

This does work:

TABLE FILE CAR
SUM
COMPUTE COL2/D6 = LENGTH * HEIGHT * WIDTH;
SALES
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=SALES, COLOR=GREEN, WHEN= SALES GT 8000, $
TYPE=DATA, COLUMN=SALES, COLOR=RED, WHEN= SALES LT 8000, $
END

SO does this:

TABLE FILE CAR
SUM
SALES
COMPUTE FLG1/A1 = IF SALES LT 8000 THEN '1' ELSE IF SALES GT 8000 THEN '2' ELSE '0';
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=SALES, COLOR=RED, WHEN= FLG1 EQ '1', $
TYPE=DATA, COLUMN=SALES, COLOR=GREEN, WHEN= FLG1 EQ '2', $
END

Mention of SALES in the COMPUTE is the problem. WF must be creating a new SALES column for the compute. This works by identifying the second SALES column for styling:

TABLE FILE CAR
SUM
COMPUTE COL1/D1 = IF HEIGHT LT 8000 THEN 1 ELSE IF SALES GT HEIGHT THEN 2 ELSE 0;
COMPUTE COL2/D6 = LENGTH * HEIGHT * WIDTH;
SALES
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=SALES(2), COLOR=GREEN, WHEN= SALES GT 8000, $
TYPE=DATA, COLUMN=SALES(2), COLOR=RED, WHEN= SALES LT 8000, $
END

Dan, that's it! Thanks.

Like you stated, since SALES is in the internal matrix twice, I should be using SALES(2). I'm putting on my "I should have known that" t-shirt...

Tom, thanks, yes I did try the COMPUTE after, which works.

I wear that T-shirt every day.

The other option is to use relative column numbers like Pn, Bn Cn, etc

TABLE FILE CAR
SUM
COMPUTE FLG1/A1 = IF SALES LT 8000 THEN '1' ELSE IF SALES GT 8000 THEN '2';
SALES
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=P5, COLOR=RED, WHEN= FLG1 EQ '1', $
TYPE=DATA, COLUMN=P5, COLOR=GREEN, WHEN= FLG1 EQ '2', $
END

Aha, so invisible fields in the internal matrix have impact on style definitions?!? That explains some curious problems I've had with styling, I wish I'd have known that before.

It makes me wonder though, why is that? That's like handing someone a shotgun with the barrel pointing straight down and not telling them it's loaded and the safety is off. Your report is going to look like your foot: messed up.

We've often switched to using numbered columns (like Waz suggests) after encountering issues like these, but numbered columns have the severe drawback that adding new columns or computations before existing ones (because you need the result in a next computation) breaks your styling - the column numbering changes.
It's even more of a pain with ACROSS-columns, which don't seem like they can be referenced by name at all.