Hi All,
can any one help me how to display pie chart along with report side by side in excel format.I am using the 7.6.2version.

This message has been edited. Last edited by: Kerry,

Your best option is to use FORMAT EXL2K TEMPLATE
and use an Excel template to generate the graph

I am not able to find/recollect where I read about this technique, but here is what I vaugely remember.

- Step#1 - Save graph file output as GIF

- Step#2 - In a later TABLE FILE statement that creates the final Excel report, have a style-sheet line that embends an image. The syntax on this line includes the position parameters and you can position it wherever.

FOCUS-Nation, please correct me if I am wrong.

Sandeep Mamidenna

quote:

Originally posted by BlueZone:
I am not able to find/recollect where I read about this technique, but here is what I vaugely remember.

- Step#1 - Save graph file output as GIF

- Step#2 - In a later TABLE FILE statement that creates the final Excel report, have a style-sheet line that embends an image. The syntax on this line includes the position parameters and you can position it wherever.

FOCUS-Nation, please correct me if I am wrong.

Sandeep Mamidenna

Hello Sandeep,

Can you please provide a working example for this please. i specially want a reference (sample syntax/script) for the step 2 that you mentioned.

Regards,
Jagriti

The closest I can get for this requirement is a single Excel file with a Report Tab and a Chart Tab. The way I did it is by using a Document. Here's the code:

ENGINE INT CACHE SET ON
SET PAGE-NUM=NOLEAD
SET EMPTYREPORT=ON


COMPOUND LAYOUT PCHOLD FORMAT XLSX
SECTION=Section_1, LAYOUT=ON, PAGESIZE=LETTER, ORIENTATION=LANDSCAPE, SHOW_GLOBALFILTER=OFF, $
PAGELAYOUT=1, NAME='Page 1', TEXT='Page 1', LEFTMARGIN=0.25, RIGHTMARGIN=0.25, TOPMARGIN=0.25, BOTTOMMARGIN=0.25, $
COMPONENT=TableChart_1, COMPONENT-TYPE=REPORT, POSITION=(1.041666 1.041666), DIMENSION=(* *), ARREPORTSIZE=DIMENSION, METADATA='VERSION:1.0;WIDTH:4.0;HEIGHT:3.0;LEFT:1.041666;TOP:1.041666', $
COMPONENT=TableChart_2, COMPONENT-TYPE=GRAPH, POSITION=(4.635416 0.96875), DIMENSION=(5.0 3.5), ARREPORTSIZE=DIMENSION, METADATA='VERSION:1.0', $
END

SET COMPONENT=TableChart_1
-*component_type report
-DEFAULTH &WF_SUMMARY='Summary';
-DEFAULTH &WF_TITLE='WebFOCUS Report';
TABLE FILE ibisamp/car
SUM CAR.BODY.DEALER_COST
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR

ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE SET EMPTYREPORT ON
ON TABLE SET HTMLCSS ON
ON TABLE SET HTMLENCODE ON
ON TABLE SET CACHELINES 100
ON TABLE SET STYLE *
INCLUDE=IBFS:/FILE/IBI_HTML_DIR/ibi_themes/Warm.sty,$
TYPE=REPORT, TITLETEXT='Report1', SUMMARY=&WF_SUMMARY.QUOTEDSTRING, ORIENTATION=LANDSCAPE, $
ENDSTYLE
END

SET COMPONENT=TableChart_2
-*component_type graph
-DEFAULTH &WF_TITLE='WebFOCUS Report';
GRAPH FILE ibisamp/car
-* Created by Info Assist for Graph
SUM CAR.BODY.RETAIL_COST
BY CAR.BODY.BODYTYPE
ON GRAPH PCHOLD FORMAT PDF
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET ARGRAPHENGIN JSCHART
ON GRAPH SET EMBEDHEADING ON
ON GRAPH SET VZERO OFF
ON GRAPH SET HAXIS 5.0
ON GRAPH SET VAXIS 3.5
ON GRAPH SET UNITS INCHES
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 0
ON GRAPH SET GRLEGEND 1
ON GRAPH SET GRXAXIS 0
ON GRAPH SET LOOKGRAPH PIEMULTI
ON GRAPH SET STYLE *
*GRAPH_SCRIPT

setPieDepth(0);
setPieTilt(0);
setDepthRadius(0); 
setCurveFitEquationDisplay(false); 
setPlace(true); 
setPieFeelerTextDisplay(1); 

*END
INCLUDE=IBFS:/FILE/IBI_HTML_DIR/ibi_themes/Warm.sty,$
TYPE=REPORT, TITLETEXT='Chart1', ORIENTATION=LANDSCAPE, $
*GRAPH_SCRIPT

setReportParsingErrors(false);
setSelectionEnableMove(false);
*GRAPH_JS_FINAL
"pieProperties": {
    "holeSize": "0%"
},
"agnosticSettings": {
    "chartTypeFullName": "Pie_Multi"
}

*END
ENDSTYLE
END

COMPOUND END

If you search the documentation for "IMAGE EXCEL" then you will find some examples for including images (per Sandeep).

The documentation can be located here

T

Thank You For your response on this.

BabakNYC - Thank you for a working example.I have already managed to get this done (graph on one tab and report on the other) through compound layout as you mentioned. Now the requirement is to get a report and image (graph) on the same tab using the same compound layout concept. The report can be beneath the graph/image (not necessary side by side).

Tony - The entire document suggests to include an image in the excel format EXL07. However in my case the format of the report supported is EXL2K. Certain instances reflects that the same is not supported with the output/webfocus format I use (EXL2K). However this is a very useful link, it is of a great help.

I have somehow managed to get my intended output using the code provided below. This approach however is not a good programmer practice, but for now this serves my purpose. The idea is to generate as many blank lines as the height of the image could fit in, in the heading (in our case it is 24 no. of blank lines).
Any suggestion or enhancement for this is appreciated.

 
COMPOUND LAYOUT PCHOLD FORMAT EXL2K
SECTION=section1,LAYOUT=ON,ORIENTATION=PORTRAIT,PAGESIZE=Letter, $
PAGELAYOUT=1, $
COMPONENT = 'HOLD1',$
COMPONENT = 'HOLD2',$
END
 
SET COMPONENT='HOLD1'
 
GRAPH FILE CAR
SUM
SALES
BY COUNTRY
ON GRAPH HOLD AS GIF1 FORMAT GIF
ON GRAPH SET STYLE *
SQUEEZE=ON, ORIENTATION=PORTRAIT, $
TYPE=REPORT, GRID=OFF, FONT='TIMES NEW ROMAN', SIZE=10, $
ENDSTYLE
END
 
TABLE FILE CAR
HEADING
"</24 "
SUM
SALES 
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
-*XLSXPAGESETS=ON,TOPMARGIN=1,BOTTOMMARGIN=1,ORIENTATION=LANDSCAPE,PAGESIZE=LETTER,$
-*TYPE=REPORT,IMAGE=GIF1.GIF,POSITION=(.5 .5), SIZE=(.5 .5), $
-*TYPE=REPORT,STYLE=BOLD,$
-*TYPE=TABHEADING,IMAGE=GIF1.GIF,$
TYPE=REPORT,IMAGE=GIF1.GIF,$
-*TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=LEFT, IMAGE=GIF1.GIF,$
ENDSTYLE
END
 
SET COMPONENT='HOLD2'
 
GRAPH FILE CAR
SUM
SALES
BY CAR
ON GRAPH HOLD AS GIF2 FORMAT GIF
ON GRAPH SET STYLE *
SQUEEZE=ON, ORIENTATION=PORTRAIT, $
TYPE=HEADING, GRID=OFF, FONT='TIMES NEW ROMAN', SIZE=10, $
ENDSTYLE
END
 
 
 
TABLE FILE CAR
SUM
SALES 
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT,IMAGE=GIF2.GIF,$
ENDSTYLE
END
 
 
COMPOUND END 

Regards,
Jagriti

This message has been edited. Last edited by: Jagriti Kumari,