I would like to achieve the 2 things mentioned below.

1)Title (CAR value - right now I am using Subhead to display that) to be on the same line with the Across Title.

2)Add a image next to the title (Next to Dealer Cost and Retail Cost).

Both not working in PDF format. Sample code is below.

TABLE FILE CAR
SUM DEALER_COST AS 'Dealer Cost' OVER
RETAIL_COST AS 'Retail Cost'
BY CAR NOPRINT
ACROSS COUNTRY AS ''
ON CAR PAGE-BREAK
ON CAR SUBHEAD
"ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT,FONT=ARIAL,SIZE=9,SQUEEZE=ON,ORIENTATION=LANDSCAPE,$
ENDSTYLE
END
-EXIT

Any thoughts or suggestions.

This message has been edited. Last edited by: <Kathryn Henning>,

8.2.06
Windows, All Formats

We will never get the column titles on the same line as the across column titles - we've been asking for that for 10 years or so.

You place an image in a report using WebFOCUS style-sheet syntax. The image must be in a app folder on the reporting server.

Francis,

Where you can't natively do what WFDev is asking about, you can use subheads with a nasty workaround to do it.

 SET ASNAMES = ON
DEFINE FILE CAR
BY_FIELD/A20V='Dealer Cost';
END

TABLE FILE CAR
SUM
DEALER_COST AS '' 
BY CAR 
BY BY_FIELD
ACROSS COUNTRY 
ON TABLE HOLD AS HOLD1 
END

TABLE FILE HOLD1
PRINT *
ON TABLE HOLD AS USE1 FORMAT FOCUS 
END

DEFINE FILE CAR
BY_FIELD/A20V='Retail Cost';
END

TABLE FILE CAR
SUM
RETAIL_COST AS '' 
BY CAR 
BY BY_FIELD
ACROSS COUNTRY 
ON TABLE HOLD AS HOLD2 
END

TABLE FILE HOLD2
PRINT *
ON TABLE HOLD AS USE2 FORMAT FOCUS
END

 USE USE1 AS USE1
 	 USE2 AS USE1
 END

TABLE FILE SYSCOLUM
PRINT NAME
WHERE TBNAME EQ 'USE1'
WHERE NOT NAME IN ('FOCLIST','CAR','BY_FIELD')
ON TABLE SAVE AS FIELDS
END

-SET &NUM_FLDS = &LINES;
-SET &CNTR=0;
-SET &ALL_FIELD='';
-REPEAT :FIELD_LOOP WHILE &CNTR LT &NUM_FLDS

-READ FIELDS NOCLOSE &FIELD_&CNTR.EVAL.A512
-SET &FIELD_&CNTR.EVAL =  TRUNCATE(&FIELD_&CNTR.EVAL);
-TYPE &FIELD_&CNTR.EVAL
-SET &ALL_FIELD = IF &CNTR + 1 EQ &NUM_FLDS THEN &ALL_FIELD.QUOTEDSTRING | &FIELD_&CNTR.EVAL ELSE &ALL_FIELD.QUOTEDSTRING | &FIELD_&CNTR.EVAL | '<+0>';
-TYPE &ALL_FIELD
-SET &CNTR=&CNTR+1;
-:FIELD_LOOP
-SET &CNTR=0;
TABLE FILE USE1
PRINT 
-REPEAT :BY_LOOP WHILE &CNTR LT &NUM_FLDS
 '&FIELD_&CNTR.EVAL' AS ''
-SET &CNTR=&CNTR+1;
-:BY_LOOP
BY CAR NOPRINT
BY BY_FIELD AS ''

ON CAR PAGE-BREAK
ON CAR SUBHEAD
"<CAR<+0>&ALL_FIELD.EVAL"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
	HEADALIGN=BODY,
$
TYPE=REPORT,FONT=ARIAL,SIZE=9,SQUEEZE=ON,ORIENTATION=LANDSCAPE,$
ENDSTYLE
END
 

Theres probably a better way. But this works.

Eric,

Your code works good for HTML but not for PDF. If it is HTML, we can get the Column and Across Title together by setting a ACROSSTITLE=SIDE.

Thanks

WFDev,

The code works for PDF too. I made a slight adjustment to the style sheet, but I get PDF output as I expect.

 TABLE FILE USE1
PRINT 
-REPEAT :BY_LOOP WHILE &CNTR LT &NUM_FLDS
 '&FIELD_&CNTR.EVAL' AS ''
-SET &CNTR=&CNTR+1;
-:BY_LOOP
BY CAR NOPRINT
BY BY_FIELD AS ''

ON CAR PAGE-BREAK
ON CAR SUBHEAD
"<CAR&ALL_FIELD.EVAL"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,FONT=ARIAL,SIZE=9,ORIENTATION=LANDSCAPE,$
TYPE = SUBHEAD,HEADALIGN=BODY,
ENDSTYLE
END