Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Function argument not acceptable to V766 now

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] Function argument not acceptable to V766 now
 Login/Join
 
Adrian Wong
Gold member
posted
Hi,
I have some code here that works fine in v5.3.2 but when I test it in v7.6.6 it complains that an argument that we used is now not acceptable in v7.6.6 Here is the code:

SET EMPTYREPORT = ON
SET PRINTPLUS = ON
SET NODATA = ' '
-SET &ECHO=ALL;
-SET &REP_NAME = 'Card Production Centre Reconciliation Trend Report';
-SET &RUN_DATE = &DATEMtrDYY;
-SET &RUN_TIME = EDIT(HHMMSS('A8'),'99$:99$:99');
-SET &ORIENTATION = 'PORTRAIT';
-*------------------------------
-*-- DEFAULTS ----------------
-*------------------------------
-DEFAULT &AMONTH = 08;
-DEFAULT &AYEAR = 2007;
-DEFAULT &ACARD_TYPE_MEMBER = 'CT.DLCARD_V1';
-DEFAULT &OUTPUT = 'HTML';
-SET &CARD_HDG = IF &ACARD_TYPE_MEMBER = 'CT.DLCARD_V1' THEN 'Driver Licence Card' ELSE
- IF &ACARD_TYPE_MEMBER = 'CT.HCARD_V1' THEN 'Health Card' ELSE ' ';
-*------------------------------
-*-- MEMBER ARITHMETIC --------
-*------------------------------
-SET &AYM_STRING = &AYEAR | &AMONTH;
-SET &MTH_DESC = DECODE &AMONTH(01 'Jan' 02 'Feb' 03 'Mar' 04 'Apr' 05 'May' 06 'Jun' 07 'Jul' 08 'Aug' 09 'Sep' 10 'Oct' 11 'Nov' 12 'Dec');
-SET &PREV_MTH1 = &AYM_STRING;
-SET &PREV_MTH2 = AYM( &AYM_STRING, -1, 'YYM');
-SET &PREV_MTH3 = AYM( &AYM_STRING, -2, 'YYM');
-SET &PREV_MTH_MBR1 = 'OB[' || SUBSTR( 6, &PREV_MTH1, 1, 4, 4, 'A4' ) || '-' || SUBSTR( 6, &PREV_MTH1, 5, 6, 2, 'A2' ) || ']';
-SET &PREV_MTH_MBR2 = 'OB[' || SUBSTR( 6, &PREV_MTH2, 1, 4, 4, 'A4' ) || '-' || SUBSTR( 6, &PREV_MTH2, 5, 6, 2, 'A2' ) || ']';
-SET &PREV_MTH_MBR3 = 'OB[' || SUBSTR( 6, &PREV_MTH3, 1, 4, 4, 'A4' ) || '-' || SUBSTR( 6, &PREV_MTH3, 5, 6, 2, 'A2' ) || ']';
-*------------------------------
-*-- TABLE ---------
-*------------------------------
DEFINE FILE DLHCMR4_RELEASE4
Y_GB3/A4 = SUBSTR(11, GEN3_ORDER_BATCH, 4, 7, 4, Y_GB3);
M_GB3/A2= SUBSTR(11, GEN3_ORDER_BATCH, 9, 10, 2, M_GB3);
A6_GB3/A6 = Y_GB3 | M_GB3;
A6YYM_GB3/I6YYM = EDIT(A6_GB3);
YM_GB3/YYM = DATECVT(A6YYM_GB3, 'I6YYM', 'YYM');
YYM_GB3_SD/MtYY = YM_GB3;
END
-RUN
TABLE FILE DLHCMR4_RELEASE4
SUM ITEM_COUNT/I7C AS ''
ACROSS YYM_GB3_SD AS ''
FOR EVENTS_MEMBER
'ER.CPCBATCH_S' AS 'Orders Received By CPC' LABEL R1 OVER
'FPS_CARD_DAMAGED' OR 'FPS_DATA_QUALITY' OR 'FPS_SIGNATURE_QUALITY' OR 'FPS_IMAGE_QUALITY' OR 'FPS_INC_DATA' AS 'Final Production Failures *' LABEL R2 OVER
'ES.MAIL_S' OR 'ES.MAIL_P' AS 'Mailed' LABEL R3 OVER
'ER.REQ_CANCEL' AS 'Cancelled via Online Pull' LABEL R4 OVER
RECAP R5/I7C=R2+R3+R4; AS 'Total Orders Processed' OVER
RECAP R6/I7C=R1-R5; AS 'Outage **' OVER
'ES.QA_LVL_2_F' OR 'ES.QA_LVL_2_S' AS 'Sum Health Level 2 QA' LABEL R7 NOPRINT OVER
RECAP R8/D4.1%L=(R7/R1)*100; AS 'Health Level 2 QA %'
-* WHERE (GEN2_YEAR EQ '&AYEAR');
WHERE (CARD_TYPE_MEMBER EQ '&ACARD_TYPE_MEMBER');
WHERE (GEN3_ORDER_BATCH EQ '&PREV_MTH_MBR1' OR '&PREV_MTH_MBR2' OR '&PREV_MTH_MBR3' );
HEADING
"Ministry Of Transportation Of Ontario - DL Card and Health Card Contract Management"
"Card Production Centre Reconciliation Trend Report"
"Card Type: &CARD_HDG"
"For: &MTH_DESC.EVAL &AYEAR.EVAL"
" "
FOOTING
" "
"Notes:"
"* For DL - 3rd Attempt Failures Only."
"** Outage is the difference between Orders Received and Total Orders Processed."
" "
ON TABLE SUBFOOT
"Report ID: SR4 / Date: &RUN_DATE / Time: &RUN_TIME / Page ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT '&OUTPUT'
ON TABLE SET CSSURL '/approot/mtomis/report.css'
ON TABLE SET STYLE *
-*
-GOTO STY_&OUTPUT.EVAL
-*
-STY_HTML
-STY_EXL2K
-MRNOEDIT -INCLUDE STYLE011
-GOTO STY_END
-*
-STY_PDF
-MRNOEDIT -INCLUDE STYLE021
-*
-STY_EXCEL
-STY_END
ENDSTYLE
END
-RUN
-*
-IF &LINES GT 0 GOTO REPORT_END;
-*
-NO_DATA
-MRNOEDIT -INCLUDE MISI200
-*
-REPORT_END

The error mesaage is:
-SET &REP_NAME = 'Card Production Centre Reconciliation Trend Report';
-SET &RUN_DATE = January 19, 2009 ;
-SET &RUN_TIME = EDIT(HHMMSS('A8'),'99$:99$:99');
-SET &ORIENTATION = 'PORTRAIT';
-*------------------------------
-*-- DEFAULTS ----------------
-*------------------------------
-DEFAULT &AMONTH = 08;
-DEFAULT &AYEAR = 2007;
-DEFAULT &ACARD_TYPE_MEMBER = 'CT.DLCARD_V1';
-DEFAULT &OUTPUT = 'HTML';
-SET &CARD_HDG = IF CT.DLCARD_V1 = 'CT.DLCARD_V1' THEN 'Driver Licence Card' ELSE
- IF CT.DLCARD_V1 = 'CT.HCARD_V1' THEN 'Health Card' ELSE ' ';
-*------------------------------
-*-- MEMBER ARITHMETIC --------
-*------------------------------
-SET &AYM_STRING = 2007 | 08;
-SET &MTH_DESC = DECODE 08(01 'Jan' 02 'Feb' 03 'Mar' 04 'Apr' 05 'May' 06 'Jun' 07 'Jul' 08 'Aug' 09 'Sep' 10 'Oct' 11 'Nov' 12 'Dec');
-SET &PREV_MTH1 = 200708;
-SET &PREV_MTH2 = AYM( 200708, -1, 'YYM');
0 ERROR AT OR NEAR LINE 3 IN PROCEDURE sr4 FOCEXEC *
(FOC36355) INVALID TYPE OF ARGUMENT #3 FOR USER FUNCTION AYMI

I believe it is complaining about the argument 'YYM'. There is no such AYMI function in the code. There is only AYM function. I've run it again in Dev v5.3.2 and it works fine. The same code in Test v7.6.6 is not working.

Should I change to use a different function?

Thank you in advance for your suggestions.

This message has been edited. Last edited by: Kerry,


WF V7.7.03
Platform: AIX 6.1 64-bit, WinXP, IE 8.0
Output Formats: Html, Pdf, Excel
 
Posts: 71 | Registered: October 16, 2006Report This Post
GinnyJakes
Expert
posted Hide Post
The documentation states that for functions AYM and AYMD, the syntax for indate MUST be a legacy date format, i.e. I4, I4YM, I6, I6YYM, etc.

The code was tightened.


Ginny
---------------------------------
Prod: WF 7.7.01 Dev: WF 7.6.9-11
Admin, MRE,self-service; adapters: Teradata, DB2, Oracle, SQL Server, Essbase, ESRI, FlexEnable, Google
 
Posts: 2723 | Location: Ann Arbor, MI | Registered: April 05, 2006Report This Post
Francis Mariani
Expert
posted Hide Post
Try
-SET &PREV_MTH2 = AYM( 200708, -1, 'I6');

or 
-SET &PREV_MTH2 = AYM( 200708, -1, 'I6YYM');


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
Francis Mariani
Expert
posted Hide Post
From the 5.3.2 documentation:

quote:
Syntax: How to Add or Subtract Months to or From a Date
AYM(indate, months, outfield)where:

indate

I4, I4YM, I6, or I6YYM


Is the original date in year-month format, the name of a field that contains the date, or an expression that returns the date. If the date is not valid, the function returns a 0.


months

Integer


Is the number of months you are adding to or subtracting from the date. To subtract months, use a negative number.


outfield

I4YM or I6YYM


Is the name of the field that contains the result, or the format of the output value enclosed in single quotation marks.


In Dialogue Manager, you must specify the format. In Maintain, you must specify the name of the field.



Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
j.gross
Virtuoso
posted Hide Post
AYM and AYMI are entry points of the same function.
-- They really should tighten the error messages when they tighten the call requirements Wink


- Jack Gross
WF through 8.1.05
 
Posts: 1925 | Location: NYC | In FOCUS since 1983 | Registered: January 11, 2005Report This Post
Francis Mariani
Expert
posted Hide Post
The 5.3.2 documentation states that the output format for AYM must be I4YM or I6YYM. I'm sure that the 7.6 documentation states the same. Adrian was lucky that using YYM worked in v5.3.2. Code was tightened, error message makes sense, documentation is correct.

Cheers,


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
Adrian Wong
Gold member
posted Hide Post
Yes, I tried 'I6YYM' and it worked fine.
Thank you all for your suggestions especially you Francis for your helpful hints.
I'm moving on now to another problem in Essbase cube. Not sure yet why it is happening. Message indicates it is a connection failure but prelim test of connection indicates it is fine. Have to talk to other developers. Regards.


WF V7.7.03
Platform: AIX 6.1 64-bit, WinXP, IE 8.0
Output Formats: Html, Pdf, Excel
 
Posts: 71 | Registered: October 16, 2006Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Function argument not acceptable to V766 now

Copyright © 1996-2020 Information Builders