Hi,

We got a problem: when we use the field W_POPUP in combination with HFREEZE all the fields next of W_POPUP disappears.

We use WF 8

 
-* File popup.fex 

-SET &ECHO=ALL 

DEFINE FILE CAR 
W_POPUP/A100='<div title=''' | CAR | ' ' | MODEL | '''>' | 'A'  | '</div>'; 
END 

TABLE FILE CAR 
PRINT 
     COUNTRY 
     W_POPUP 
     CAR 
     MODEL NOPRINT 
     DEALER_COST 
     RETAIL_COST 
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE * 
     INCLUDE = endeflt, 
$ 
TYPE=REPORT, 
     HFREEZE=ON, 
$ 
ENDSTYLE 
END 

 

This message has been edited. Last edited by: <Kathryn Henning>,

Your problem stems from the fact that you have the div within your field output. This adds length to the scrolling content which is not reflected within the "frozen" headings such that the rest of the fields are pushed out of view to the right.

To show this, run in IE and hit F12. Leaving the tab on HTML, click the arrow and then click on the first entry on the Country column. This will show the styling on this column in the right hand pane of the IE tools window.

Now click on the "div" row just above in the left hand pane. Notice that the style on the right now reflects that for the selected element.

Uncheck the last attribute under "inline style" this should be something like Width 444px.

Now move back to your report and you will notice that the fields have appeared - to the right of where the table width forced a finish.

I guess that you are just attempting to add a tooltip for a particular column?

I would suggest moving the W_POPUP to the last position so that you allow the "overlapped" portion of the report to be the excess length caused by the div element but would this work for you?

T

Tony,

Thanks for your reply. I put it in the front because the fields in the tooltip ar position there. (see Model)
if I'm not mistaken it work in older versions of WebFOCUS???

Mark

Hi Mark,

Unfortunately I do not have pre 8.0.0.6 available at the moment so I couldn't confirm that it worked. If someone has an earlier release perhaps we could ask that they check it and advise?

As regards the tooltip, the ideal method would be to be able to add field(s) to the ALT attribute in the WF style sheet syntax -

 TYPE=DATA, COLUMN=COUNTRY,JAVASCRIPT=fx(COUNTRY), ALT='tooltip text', $

But that isn't possible. Perhaps raise an NFR? Get many people to add their weight to the NFR and perhaps it will be considered in a favourable light?

Who knows, the "FOCUS Nation" (to coin a phrase) managed to persuade product division to add items such as F5 to run, block commenting etc. in Dev Studio before.

Personally, I think that it would be a worthy and immensely beneficial enhancement - anyone else?

T

This message has been edited. Last edited by: Tony A,

Ok, so I've just started a WF7.7.03 VM and can confirm that your code works on that version.

Time for you to contact tech support I think.

T

It's me again, with some alternative code that will give you a similar effect but with a little more coding -

DEFINE FILE CAR 
S_POPUP/A300='type=data, column=W_POPUP, when=MODEL EQ '''|MODEL|''', javascript=void(0), alt='''||CAR | ' ' | MODEL|''', $'; 
END 

TABLE FILE CAR
PRINT S_POPUP AS ''
BY COUNTRY NOPRINT
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SAVE AS MYPOPUP
END
-RUN

TABLE FILE CAR 
PRINT 
     COUNTRY 
     COMPUTE W_POPUP/A1 = 'A';
     CAR 
     MODEL NOPRINT 
     DEALER_COST 
     RETAIL_COST 
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE * 
  INCLUDE = endeflt, $
  TYPE=REPORT, HFREEZE=ON, $ 
-INCLUDE mypopup.ftm
ENDSTYLE 
END

T

Tony,

Thanks for all your support, the coding you send works fine. I will make a cass for this.

kind regards
Mark