Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] Putting More Data After ACROSS Matrix

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[CLOSED] Putting More Data After ACROSS Matrix
 Login/Join
 
kennethb
Member
posted
Got a report that has an across matrix in it, but I need to put some more data (alphanumeric) after the across matrix.

Say I've got this code

TABLE FILE FOO
SUM ACROSS_FIELD1
ACROSS_FIELD2
ACROSS_FIELD3
BY DATA1
BY DATA2
BY DATA3
BY DATA3

ACROSS FOCLIST

ON TABLE PCHOLD FORMAT EXL2K

END

The DATA1, DATA2, DATA3, and DATA4 fields all appear before the ACROSS matrix on the report. Is it possible to have DATA1 and DATA2 appear before the ACROSS matrix, and DATA3 and DATA4 to appear after the ACROSS matrix? Thanks!

This message has been edited. Last edited by: <Kathryn Henning>,


WebFOCUS 8.1.03, Windows 10/64, Oracle 11g & RDB, Output: HTML, PDF, Excel 2010
 
Posts: 6 | Registered: October 16, 2012Report This Post
MartinY
Virtuoso
posted Hide Post
Having something placed after the ACROSS, I don't think that it's possible.
But maybe this may suit your needs:
TABLE FILE CAR
SUM RETAIL_COST
    SEATS
BY COUNTRY
SUM DEALER_COST
BY COUNTRY
BY BODYTYPE
ACROSS CAR
END


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
David Briars
Master
posted Hide Post
Martin is showing a nice way to put data columns before the 'across matrix'. To put data columns after as well, take a look at...
APP PREPENDPATH IBISAMP
SET ONLINE-FMT = STANDARD, PANEL = 200, NODATA = ' '
TABLE FILE CAR
SUM RETAIL_COST
    SEATS NOPRINT 
BY  COUNTRY
SUM DEALER_COST
BY  COUNTRY
BY  BODYTYPE
ACROSS CAR
COMPUTE SEATS_OUT/I8 = C2;
WHERE CAR EQ 'AUDI' OR 'BMW' OR 'DATSUN' 
END  

1 PAGE     1
  
  
                                      CAR 
                                      AUDI             BMW              DATSUN            SEATS_OUT
  COUNTRY    RETAIL_COST BODYTYPE     DEALER_COST      DEALER_COST      DEALER_COST                
  -------------------------------------------------------------------------------------------------
  JAPAN            3,139 SEDAN                                                2,626               4
  W GERMANY       64,732 SEDAN              5,063           49,500                               34
 
Posts: 822 | Registered: April 23, 2003Report This Post
Dan Satchell
Virtuoso
posted Hide Post
You can also use the StyleSheet parameter SEQUENCE to move columns around in a report. But then you must dynamically determine where to move things, if you want to avoid hard-coding column positions.

TABLE FILE CAR
 COUNT DST.COUNTRY/I9
 ON TABLE SAVE AS COUNTRY_COUNT
END
-RUN
-READ COUNTRY_COUNT &COUNTRY_COUNT.9.
-SET &MODEL_COLUMN = &COUNTRY_COUNT + 2 ;
-*
TABLE FILE CAR
 SUM SALES
 BY CAR
 BY MODEL
 ACROSS COUNTRY
 ON TABLE SET STYLE *
  TYPE=REPORT, COLUMN=MODEL, SEQUENCE=&MODEL_COLUMN, $
 ENDSTYLE
END


WebFOCUS 7.7.05
 
Posts: 1213 | Location: Seattle, Washington - USA | Registered: October 22, 2007Report This Post
kennethb
Member
posted Hide Post
Interesting. Will that work with alphabetic data or just numeric? Some of the data I need to put after the across is alphabetic. Thanks!

quote:
Originally posted by David Briars:
Martin is showing a nice way to put data columns before the 'across matrix'. To put data columns after as well, take a look at...
APP PREPENDPATH IBISAMP
SET ONLINE-FMT = STANDARD, PANEL = 200, NODATA = ' '
TABLE FILE CAR
SUM RETAIL_COST
    SEATS NOPRINT 
BY  COUNTRY
SUM DEALER_COST
BY  COUNTRY
BY  BODYTYPE
ACROSS CAR
COMPUTE SEATS_OUT/I8 = C2;
WHERE CAR EQ 'AUDI' OR 'BMW' OR 'DATSUN' 
END  

1 PAGE     1
  
  
                                      CAR 
                                      AUDI             BMW              DATSUN            SEATS_OUT
  COUNTRY    RETAIL_COST BODYTYPE     DEALER_COST      DEALER_COST      DEALER_COST                
  -------------------------------------------------------------------------------------------------
  JAPAN            3,139 SEDAN                                                2,626               4
  W GERMANY       64,732 SEDAN              5,063           49,500                               34


WebFOCUS 8.1.03, Windows 10/64, Oracle 11g & RDB, Output: HTML, PDF, Excel 2010
 
Posts: 6 | Registered: October 16, 2012Report This Post
David Briars
Master
posted Hide Post
APP PREPENDPATH IBISAMP
SET ONLINE-FMT = STANDARD, PANEL = 200, NODATA = ' '
DEFINE FILE CAR
 CONTINENT/A6 = IF COUNTRY EQ 'JAPAN' THEN 'ASIA' ELSE 'EUROPE';
END
TABLE FILE CAR
SUM RETAIL_COST
    CONTINENT NOPRINT
BY  CONTINENT NOPRINT
BY  COUNTRY
SUM DEALER_COST
BY  CONTINENT NOPRINT
BY  COUNTRY
BY  BODYTYPE
ACROSS CAR
COMPUTE CONT_OUT/A6 = C2;
WHERE CAR EQ 'AUDI' OR 'BMW' OR 'DATSUN'
END  

1 PAGE     1
  
  
                                      CAR 
                                      AUDI             BMW              DATSUN            CONT_OUT
  COUNTRY    RETAIL_COST BODYTYPE     DEALER_COST      DEALER_COST      DEALER_COST               
  ------------------------------------------------------------------------------------------------
  JAPAN            3,139 SEDAN                                                2,626         ASIA  
  W GERMANY       64,732 SEDAN              5,063           49,500                          EUROPE
 
Posts: 822 | Registered: April 23, 2003Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] Putting More Data After ACROSS Matrix

Copyright © 1996-2020 Information Builders