November 10, 2006, 01:35 AM
SyedYes I am using Heading in my report:
Here's the complete code:
SET ASNAMES=ON
SET PRINTPLUS = ON
SET ONLINE-FMT = PDF
SET LINES=99999
-INCLUDE sccr_popsel.fex
-*****The below variables are used for testing purposes
-*SET &P_FORMAT = 'PDF';
-*SET &P_DEPTID=21;
-*SET &P_MONTH=7;
-*SET &P_YEAR= 2006;
-*SET &P_EXPCTRNAME='Total Store';
-****************Retrieving the data from AGGREGATE table based on the filter conditions for account groups/subgroups in ACCT_GRP_SUBGRP table
TABLE FILE T_DB2C_GL_ACTL_BAL_AGG_REP
SUM
COMPUTE V_CURR_YR_MTD_ACTL_A/P20.2B = CURR_YR_MTD_ACTL_A/1000;
COMPUTE V_CURR_YR_YTD_ACTL_A/P20.2B = CURR_YR_YTD_ACTL_A/1000;
COMPUTE V_CURR_YR_MTD_BDGT_A/P20.2B = CURR_YR_MTD_BDGT_A/1000;
COMPUTE V_CURR_YR_YTD_BDGT_A/P20.2B = CURR_YR_YTD_BDGT_A/1000;
COMPUTE V_PREV_YR_MTD_ACTL_A/P20.2B = PREV_YR_MTD_ACTL_A/1000;
COMPUTE V_PREV_YR_YTD_ACTL_A/P20.2B = PREV_YR_YTD_ACTL_A/1000;
COMPUTE V_PREV_YR_MTD_BDGT_A/P20.2B = PREV_YR_MTD_BDGT_A/1000;
COMPUTE V_PREV_YR_YTD_BDGT_A/P20.2B = PREV_YR_YTD_BDGT_A/1000;
COMPUTE V_REF_ACCT_I/A10=REF_GL_ACCT_I;
BY
REF_GL_ACCT_I
-******Filters on Accounts, Locations, Expense Centers, Month and Year as entered by the user,
IF REF_GL_ACCT_I IS (TEMP_ACCT)
IF REF_CO_LOC_I IS (TEMP_STOR_LOC)
&V_WHEREEC
WHERE FSCL_YR_I EQ &P_YEAR
WHERE FSCL_PER_I EQ &P_MONTH
-*****Holding the data in a hold file
ON TABLE HOLD AS TEMP_ACT_BAL_AGGT FORMAT FOCUS INDEX V_REF_ACCT_I
END
-**** HANDLING ERROR AND NO DATA CONDITION
-*RUN
-*SET &EPM_ERRMSG08 = IF &FOCERRNUM NE 0 THEN 'TEMP_DC_OVRD' ELSE ' ';
-*IF &FOCERRNUM NE 0 THEN GOTO :LPCTRL_ER ;
-*IF &LINES EQ 0 THEN GOTO :LPCTRL_ZR;
-****** Box 4 of landing page-tdd begins
-******** Reading begin date, end date from CAL_DATE
TABLE FILE GL_ACTL_BAL_AGG_TIME
PRINT
PER_BEG_D
PER_END_D
-*****Filter on Year and Month entered by the user
WHERE FSCL_YR_I EQ &P_YEAR
WHERE FSCL_PER_I EQ &P_MONTH
-*****Holding the data in a hold file
ON TABLE HOLD AS TEMP_TIME FORMAT ALPHA
END
-**** HANDLING ERROR AND NO DATA CONDITION
-*RUN
-*SET &EPM_ERRMSG08 = IF &FOCERRNUM NE 0 THEN 'TEMP_DC_OVRD' ELSE ' ';
-*IF &FOCERRNUM NE 0 THEN GOTO :LPCTRL_ER ;
-*IF &LINES EQ 0 THEN GOTO :LPCTRL_ZR;
-*******Reading the Period Begin and End dates in two variabls
-RUN
-READ TEMP_TIME &V_PBDATE.A8. &V_PEDATE.A8.
-SET &V_PER_BEG_DT = EDIT(&V_PBDATE,'9999') || '-' || EDIT(&V_PBDATE,'$$$$99') || '-' || EDIT(&V_PBDATE,'$$$$$$99');
-SET &V_PER_END_DT = EDIT(&V_PEDATE,'9999') || '-' || EDIT(&V_PEDATE,'$$$$99') || '-' || EDIT(&V_PEDATE,'$$$$$$99');
-****** Box 5 of landing page-TDD begins
-****** Reading the data from FIN_SALE_SMRY table for the selected date period and location
TABLE FILE T_DB2C_FIN_SALE_SMRY
SUM
COMPUTE V_CMPR_SLS_A/P15.2 = CMPR_SLS_A/1000;
COMPUTE V_CMPR_BASE_SLS_A/P15.2 = CMPR_BASE_SLS_A/1000;
COMPUTE V_ACCT_TYP/A4='SALE';
-***** For all store locations present in tempstor_loc hold file and for the selected begin and end dates
-*****IF CO_LOC_I IS (TEMP_STOR_LOC)
BY
TOTAL V_ACCT_TYP
-*WHERE PER_BEG_D GE '&V_PER_BEG_DT' AND PER_END_D LE '&V_PER_END_DT'
WHERE PER_BEG_D EQ '&V_PER_BEG_DT' AND PER_END_D EQ '&V_PER_END_DT'
-*****Holding the data in a hold file
ON TABLE HOLD AS TEMP_FIN_SALE_SMRY FORMAT FOCUS INDEX V_ACCT_TYP
END
-**** HANDLING ERROR AND NO DATA CONDITION
-*RUN
-*SET &EPM_ERRMSG08 = IF &FOCERRNUM NE 0 THEN 'TEMP_DC_OVRD' ELSE ' ';
-*IF &FOCERRNUM NE 0 THEN GOTO :LPCTRL_ER ;
-*IF &LINES EQ 0 THEN GOTO :LPCTRL_ZR;
-****** BOX 5 OF LANDING PAGE-TDD ENDS
-****** BOX 6 OF LANDING PAGE-TDD STARTS
-****** Joining the ACCT_GRP_SUBGRP table with TEMP_ACT_BAL_AGGT
SET ALL=ON
JOIN
ACCT_GRP_SUBGRP.V_REF_ACCT_I IN ACCT_GRP_SUBGRP TO ALL
TEMP_ACT_BAL_AGGT.V_REF_ACCT_I IN TEMP_ACT_BAL_AGGT AS J0
END
-***** Joining the ACCT_GRP_SUBGRP table with TEMP_FIN_SALE_SMRY
JOIN
ACCT_GRP_SUBGRP.ACCT_GRP_TYPE_C IN ACCT_GRP_SUBGRP TO ALL
TEMP_FIN_SALE_SMRY.V_ACCT_TYP IN TEMP_FIN_SALE_SMRY AS J1
END
TABLE FILE ACCT_GRP_SUBGRP
SUM
V_CURR_YR_MTD_ACTL_A
V_CURR_YR_YTD_ACTL_A
V_CURR_YR_MTD_BDGT_A
V_CURR_YR_YTD_BDGT_A
V_PREV_YR_MTD_ACTL_A
V_PREV_YR_YTD_ACTL_A
V_PREV_YR_MTD_BDGT_A
V_PREV_YR_YTD_BDGT_A
V_CMPR_SLS_A
V_CMPR_BASE_SLS_A
BY
V_DUMMY
BY
V_ACCT_TYP AS ACCT_GRP_TYPE_C
BY
V_ACCT_SU_GRP_I AS V_ACCT_GRP_I
BY
V_ACCT_GRP AS ACCT_GRP_N
BY
V_ACCT_SU_GRP_I AS V_ACCT_SUB_GRP_I
BY
V_ACCT_GRP AS ACCT_SUB_GRP_N
ON TABLE HOLD AS TEMP_GRP_BAL_SMRY FORMAT ALPHA
WHERE ACCT_GRP_TYPE_C EQ 'CEP' OR 'CENP';
END
-**** HANDLING ERROR AND NO DATA CONDITION
-*RUN
-*IF &FOCERRNUM NE 0 THEN GOTO :LPCTRL_ER ;
-*IF &LINES EQ 0 THEN GOTO :LPCTRL_ZR ;
DEFINE FILE TEMP_GRP_BAL_SMRY
V_CUR_MTD_ACTL_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_CURR_YR_MTD_ACTL_A ELSE V_CURR_YR_MTD_ACTL_A;
V_CURR_YR_YTD_ACTL_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_CURR_YR_YTD_ACTL_A ELSE V_CURR_YR_YTD_ACTL_A;
V_CURR_YR_MTD_BDGT_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_CURR_YR_MTD_BDGT_A ELSE V_CURR_YR_MTD_BDGT_A;
V_CURR_YR_YTD_BDGT_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_CURR_YR_YTD_BDGT_A ELSE V_CURR_YR_YTD_BDGT_A;
V_PREV_YR_MTD_ACTL_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_PREV_YR_MTD_ACTL_A ELSE V_PREV_YR_MTD_ACTL_A;
V_PREV_YR_YTD_ACTL_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN V_PREV_YR_YTD_ACTL_A ELSE V_PREV_YR_YTD_ACTL_A;
V_PREV_YR_MTD_BDGT_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_PREV_YR_MTD_BDGT_A ELSE V_PREV_YR_MTD_BDGT_A;
V_PREV_YR_YTD_BDGT_A_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_PREV_YR_YTD_BDGT_A ELSE V_PREV_YR_YTD_BDGT_A;
V_CMPR_SLS_A_T/P15.2=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_CMPR_SLS_A ELSE V_CMPR_SLS_A;
V_CMPR_BASE_SLS_A_T/P15.2=IF ACCT_GRP_TYPE_C EQ 'CE' THEN -V_CMPR_BASE_SLS_A ELSE V_CMPR_BASE_SLS_A;
V_ACCT_TYP_T/A4='CP';
V_ACCT_GRP_T/A60='Controllable Profit';
V_ACCT_SU_GRP_I_T/I3=0;
END
TABLE FILE TEMP_GRP_BAL_SMRY
SUM
V_CUR_MTD_ACTL_T AS V_CURR_YR_MTD_ACTL_A
V_CURR_YR_YTD_ACTL_A_T AS V_CURR_YR_YTD_ACTL_A
V_CURR_YR_MTD_BDGT_A_T AS V_CURR_YR_MTD_BDGT_A
V_CURR_YR_YTD_BDGT_A_T AS V_CURR_YR_YTD_BDGT_A
V_PREV_YR_MTD_ACTL_A_T AS V_PREV_YR_MTD_ACTL_A
V_PREV_YR_YTD_ACTL_A_T AS V_PREV_YR_YTD_ACTL_A
V_PREV_YR_MTD_BDGT_A_T AS V_PREV_YR_MTD_BDGT_A
V_PREV_YR_YTD_BDGT_A_T AS V_PREV_YR_YTD_BDGT_A
V_CMPR_SLS_A_T AS V_CMPR_SLS_A
V_CMPR_BASE_SLS_A_T AS V_CMPR_BASE_SLS_A
BY
V_DUMMY
BY
V_ACCT_TYP_T AS ACCT_GRP_TYPE_C
BY
V_ACCT_SU_GRP_I_T AS V_ACCT_GRP_I
BY
V_ACCT_GRP_T AS ACCT_GRP_N
BY
V_ACCT_SU_GRP_I_T AS V_ACCT_SUB_GRP_I
BY
V_ACCT_GRP_T AS ACCT_SUB_GRP_N
ON TABLE HOLD AS TEMP_GRP_BAL_SMRY FORMAT ALPHA
WHERE ACCT_GRP_TYPE_C EQ 'GM' OR 'CE';
END
-**** HANDLING ERROR AND NO DATA CONDITION
-*RUN
-*IF &FOCERRNUM NE 0 THEN GOTO :LPCTRL_ER ;
-*IF &LINES EQ 0 THEN GOTO :LPCTRL_ZR ;
-* BOX 6 OF LANDING PAGE-TDD ENDS
-* BOX 7 OF LANDING PAGE-TDD BEGINS
DEFINE FILE TEMP_GRP_BAL_SMRY
V_ACCT_SORT/I3 =IF ACCT_GRP_TYPE_C EQ 'SALE' THEN 1 ELSE 2;
V_ACCT_SUBGRP_N/A28 = IF ACCT_GRP_TYPE_C EQ 'SALE' THEN 'Total Sales' ELSE
IF ACCT_GRP_TYPE_C EQ 'GM' THEN 'Total Gross Margin' ELSE
IF ACCT_GRP_TYPE_C EQ 'CE' THEN 'Total Controllable Expense' ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN 'Total Controllable Profit' ELSE SUBSTR(60, ACCT_SUB_GRP_N, 1, 25, 25, V_ACCT_SUBGRP_N);
-* IF ACCT_GRP_TYPE_C EQ 'CP' THEN 'Total Controllable Profit' ELSE 'QWERTYUIOLKJHGFDSAZXCVBNASDF';
V_LY_MTD_SALES_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_PREV_YR_MTD_ACTL_A ELSE 0;
V_CYR_MTD_SALES_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_CURR_YR_MTD_ACTL_A ELSE 0;
V_CURR_YR_MTD_ACTL_A_T/P20.2B=V_CURR_YR_MTD_ACTL_A;
V_CURR_YR_YTD_ACTL_A_T/P20.2B=V_CURR_YR_YTD_ACTL_A;
V_LY_YTD_SALES_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_PREV_YR_YTD_ACTL_A ELSE 0;
V_CYR_YTD_SALES_T/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_CURR_YR_YTD_ACTL_A ELSE 0;
END
TABLE FILE TEMP_GRP_BAL_SMRY
-****Aggregation for calculating variance
SUM
MAX.V_LY_MTD_SALES_T WITHIN V_DUMMY NOPRINT
MAX.V_CYR_MTD_SALES_T WITHIN V_DUMMY NOPRINT
MAX.V_LY_YTD_SALES_T WITHIN V_DUMMY NOPRINT
MAX.V_CYR_YTD_SALES_T WITHIN V_DUMMY NOPRINT
V_CURR_YR_MTD_ACTL_A_T NOPRINT
V_CURR_YR_YTD_ACTL_A_T NOPRINT
BY
V_DUMMY
BY
V_ACCT_SORT
BY
ACCT_GRP_TYPE_C
-* CALCULATING $B/(P)GOAL
PRINT
V_CURR_YR_MTD_ACTL_A AS ''
-* These calcuations are for MTD values
V_CURR_YR_MTD_ACTL_A_T WITHIN ACCT_GRP_TYPE_C AS V_MTD_TOTAL NOPRINT
COMPUTE V_MTD_TOTAL/P20.2=V_CURR_YR_MTD_ACTL_A_T; NOPRINT
V_LY_MTD_SALES_T WITHIN V_DUMMY NOPRINT
V_CYR_MTD_SALES_T WITHIN V_DUMMY NOPRINT
COMPUTE V_MTD_GOAL_LY/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_CURR_YR_MTD_BDGT_A ELSE V_PREV_YR_YTD_ACTL_A; AS ''
COMPUTE V_MTD_BPGOAL_LY/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_CURR_YR_MTD_ACTL_A-V_MTD_GOAL_LY ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN V_CURR_YR_MTD_ACTL_A-V_PREV_YR_MTD_ACTL_A ELSE V_MTD_GOAL_LY; AS ''
-*CHECK V_BPGOAL_LY_PCT FOR cE GROUPS
COMPUTE V_MTD_BPGOAL_LY_RS_PCT/P20.2%B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN (V_CURR_YR_MTD_ACTL_A/V_CURR_YR_MTD_BDGT_A)-1 ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN (V_CURR_YR_MTD_ACTL_A/V_PREV_YR_YTD_ACTL_A)-1 ELSE V_CURR_YR_MTD_ACTL_A/C05;AS ''
COMPUTE V_MTD_COMPSALES_VAR/D5.2%B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN (V_CMPR_SLS_A-V_CMPR_BASE_SLS_A)/V_CMPR_BASE_SLS_A ELSE (V_PREV_YR_MTD_ACTL_A/C01)- (V_CURR_YR_MTD_ACTL_A /C02); AS ''
COMPUTE V_BLANK/A10 = V_DUMMY; AS ''
-***** These calcuations are for YTD values
V_CURR_YR_YTD_ACTL_A AS ''
V_CURR_YR_YTD_ACTL_A_T WITHIN ACCT_GRP_TYPE_C AS V_YTD_TOTAL NOPRINT
COMPUTE V_YTD_TOTAL/P20.2=V_CURR_YR_MTD_ACTL_A_T; NOPRINT
V_LY_YTD_SALES_T WITHIN V_DUMMY AS V_LY_YTD_SALES NOPRINT
V_CYR_YTD_SALES_T WITHIN V_DUMMY AS V_CYR_YTD_SALES NOPRINT
COMPUTE V_YTD_GOAL_LY/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_CURR_YR_YTD_BDGT_A ELSE V_PREV_YR_YTD_ACTL_A; AS ''
COMPUTE V_YTD_BPGOAL_LY/P20.2B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN V_CURR_YR_YTD_ACTL_A-V_YTD_GOAL_LY ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN V_CURR_YR_YTD_ACTL_A-V_PREV_YR_YTD_ACTL_A ELSE V_YTD_GOAL_LY; AS ''
-*****CHECK V_BPGOAL_LY_PCT FOR CE GROUPS
COMPUTE V_YTD_BPGOAL_LY_RS_PCT/P20.2%B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN (V_CURR_YR_YTD_ACTL_A/V_CURR_YR_YTD_BDGT_A)-1 ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN (V_CURR_YR_YTD_ACTL_A/V_PREV_YR_YTD_ACTL_A)-1 ELSE V_CURR_YR_YTD_ACTL_A/C06; AS ''
COMPUTE V_YTD_COMPSALES_VAR/D5.2%B=IF ACCT_GRP_TYPE_C EQ 'SALE' THEN (V_CMPR_SLS_A-V_CMPR_BASE_SLS_A)/V_CMPR_BASE_SLS_A ELSE (V_PREV_YR_YTD_ACTL_A/C03)- (V_CURR_YR_YTD_ACTL_A /C04);AS ''
COMPUTE V_IMG/A250 = IF '&P_FORMAT' EQ 'HTML' THEN (ACCT_GRP_N|'
') ELSE ACCT_GRP_N; NOPRINT
-****** This is to decide color codes for variance AND %B/(P) Goal
COMPUTE V_FLAG_MTD/A2 = IF ACCT_GRP_TYPE_C EQ 'SALE' THEN (IF V_CURR_YR_MTD_ACTL_A GE V_MTD_GOAL_LY THEN 'SG' ELSE IF (V_CURR_YR_MTD_ACTL_A LT V_MTD_GOAL_LY AND V_CURR_YR_MTD_ACTL_A GE (-0.05 * V_MTD_GOAL_LY)) THEN 'SY' ELSE 'SR') ELSE
IF ACCT_GRP_TYPE_C EQ 'CE' THEN (IF V_MTD_COMPSALES_VAR GT 0.05 THEN 'EG' ELSE IF (V_MTD_COMPSALES_VAR LE 0.05 AND V_MTD_COMPSALES_VAR GE -0.05) THEN 'EY' ELSE 'ER') ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN (IF V_MTD_COMPSALES_VAR GT 1.75 THEN 'PG' ELSE IF (V_MTD_COMPSALES_VAR LE 1.75 AND V_MTD_COMPSALES_VAR GE 0.25) THEN 'PY' ELSE 'PR') ELSE 'X'; NOPRINT
COMPUTE V_FLAG_YTD/A2 = IF ACCT_GRP_TYPE_C EQ 'SALE' THEN (IF V_CURR_YR_YTD_ACTL_A GE V_YTD_GOAL_LY THEN 'SG' ELSE IF (V_CURR_YR_YTD_ACTL_A LT V_YTD_GOAL_LY AND V_CURR_YR_YTD_ACTL_A GE (-0.05 * V_YTD_GOAL_LY)) THEN 'SY' ELSE 'SR') ELSE
IF ACCT_GRP_TYPE_C EQ 'CE' THEN (IF V_YTD_COMPSALES_VAR GT 0.05 THEN 'EG' ELSE IF (V_YTD_COMPSALES_VAR LE 0.05 AND V_YTD_COMPSALES_VAR GE -0.05) THEN 'EY' ELSE 'ER') ELSE
IF ACCT_GRP_TYPE_C EQ 'CP' THEN (IF V_YTD_COMPSALES_VAR GT 1.75 THEN 'PG' ELSE IF (V_YTD_COMPSALES_VAR LE 1.75 AND V_YTD_COMPSALES_VAR GE 0.25) THEN 'PY' ELSE 'PR') ELSE 'X'; NOPRINT
COMPUTE V_FLAG_MTD_CENP/I1 = IF ACCT_GRP_TYPE_C EQ 'CENP' THEN (IF TOT.V_MTD_COMPSALES_VAR GT 0.05 THEN 1 ELSE IF (TOT.V_MTD_COMPSALES_VAR LE 0.05 AND TOT.V_MTD_COMPSALES_VAR GE -0.05) THEN 2 ELSE 3) ELSE 0; NOPRINT
COMPUTE V_FLAG_YTD_CENP/I1 = IF ACCT_GRP_TYPE_C EQ 'CENP' THEN (IF TOT.V_YTD_COMPSALES_VAR GT 0.05 THEN 1 ELSE IF (TOT.V_YTD_COMPSALES_VAR LE 0.05 AND TOT.V_YTD_COMPSALES_VAR GE -0.05) THEN 2 ELSE 3) ELSE 0; NOPRINT
BY
V_DUMMY NOPRINT
BY
V_ACCT_SORT NOPRINT
BY
ACCT_GRP_TYPE_C NOPRINT
BY
ACCT_GRP_N NOPRINT
BY
V_ACCT_SUB_GRP_I NOPRINT
BY
V_ACCT_SUBGRP_N AS ''
ON V_ACCT_SORT SUBHEAD NOSPLIT
-*"
" "
" Goal <+0>$B/(P) <+0>%B/(P) <+0>Comp <+0> <+0>Actual <+0>Goal <+0>$B/(P) <+0>%B/(P) <+0>Comp "
"<+0> <+0> <+0> <+0> Goal <+0>Goal <+0>Sales <+0> <+0> <+0> <+0>Goal <+0>Goal <+0>Sales "
WHEN ACCT_GRP_TYPE_C EQ 'SALE'
ON V_ACCT_SORT SUBHEAD NOSPLIT
-*""
" "
" LY <+0>$B/(P) <+0>Rate <+0>Var-<+0> <+0>Actual <+0>LY <+0>$B/(P) <+0>Rate <+0>Var- "
"<+0> <+0> <+0> <+0> LY <+0>of Sale <+0>iance <+0> <+0> <+0> <+0>LY <+0>of Sale <+0>iance "
WHEN ACCT_GRP_TYPE_C NE 'SALE'
ON ACCT_GRP_TYPE_C RECOMPUTE MULTILINES AS 'Total'
ON ACCT_GRP_TYPE_C NOSPLIT
ON ACCT_GRP_TYPE_C SUBFOOT
" "
WHEN ACCT_GRP_TYPE_C NE 'NCE'
-**********Generating Heading for PDF format
-IF &P_FORMAT EQ 'HTML' THEN GOTO LBL_HTML;
HEADING
"Stores Controllable Contribution Report"
" "
" Location:<+0> &P_DEPTID <+0> Expense Center: <+0>&V_EXPCTR_DISP"
" Year :<+0> &P_YEAR <+0> Month :<+0> &V_MONTH_DISP"
" "
" All $ Amounts in ($ 000's) <+0> Current Month <+0> <+0> <+0> <+0> <+0>Year To Date"
-GOTO LBL_QUIT
-LBL_HTML
ON TABLE SUBHEAD
" All $ Amounts in ($ 000's) <+0> Current Month <+0> <+0> <+0> <+0> <+0>Year To Date"
-LBL_QUIT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT &P_FORMAT
ON TABLE SET STYLE *
TYPE=REPORT,
BORDER=OFF,
SIZE=8,
-* CLASS = body,
$
TYPE=REPORT,
LEFTGAP=0.05,
RIGHTGAP=0.05,
$
TYPE = REPORT,
COLUMN = V_BLANK,
WRAP = 0.4,
$
TYPE=TITLE,
BORDER=OFF,
$
TYPE=TABHEADING,
STYLE=BOLD,
HEADALIGN=BODY,
$
TYPE= TABHEADING,
ITEM=2,
COLSPAN= 2,
$
TYPE=TABHEADING,
ITEM=1,
STYLE=NORMAL,
SIZE=7,
COLSPAN=3,
$
TYPE=TABHEADING,
ITEM=7,
COLSPAN=2,
$
TYPE=SUBHEAD,
BORDER=LIGHT,
BACKCOLOR=RGB(236 236 236),
STYLE=BOLD,
HEADALIGN=BODY,
-* CLASS=white,
$
TYPE=SUBHEAD,
OBJECT=FIELD,
ITEM=1,
WHEN=ACCT_GRP_TYPE_C EQ 'CEP',
FOCEXEC=sccr_ctrl_rpt(P_ACCTGRPTYPE ='CEP' P_DEPTID=&P_DEPTID P_DIST=&P_DIST P_ORGLEVEL=&P_ORGLEVEL P_EXPCTRNAME='&P_EXPCTRNAME' P_EXPCTR='&P_EXPCTR' P_MONTH=&P_MONTH P_YEAR=&P_YEAR P_DEPTNAME='&P_DEPTNAME'),TARGET=MY FRAME,
$
TYPE=SUBHEAD,
OBJECT=FIELD,
ITEM=1,
WHEN=ACCT_GRP_TYPE_C EQ 'CENP',
FOCEXEC=sccr_ctrl_rpt(P_ACCTGRPTYPE ='CENP' P_DEPTID=&P_DEPTID P_DIST=&P_DIST P_ORGLEVEL=&P_ORGLEVEL P_EXPCTRNAME='&P_EXPCTRNAME' P_EXPCTR='&P_EXPCTR' P_MONTH=&P_MONTH P_YEAR=&P_YEAR P_DEPTNAME='&P_DEPTNAME'),TARGET=MY FRAME,
$
TYPE=SUBHEAD,
OBJECT=FIELD,
ITEM=1,
WHEN=ACCT_GRP_TYPE_C EQ 'NCE',
FOCEXEC=sccr_ctrl_rpt(P_ACCTGRPTYPE ='NCE' P_DEPTID=&P_DEPTID P_DIST=&P_DIST P_ORGLEVEL=&P_ORGLEVEL P_EXPCTRNAME='&P_EXPCTRNAME' P_EXPCTR='&P_EXPCTR' P_MONTH=&P_MONTH P_YEAR=&P_YEAR P_DEPTNAME='&P_DEPTNAME'),TARGET=MY FRAME,
$
TYPE=DATA,
BORDER=LIGHT,
$
TYPE=DATA,
COLUMN=V_BLANK,
BORDER-TOP=OFF,
$
TYPE=DATA,
COLUMN=V_ACCT_SUBGRP_N,
STYLE=BOLD,
WHEN =ACCT_GRP_TYPE_C EQ 'SALE',
$
TYPE=DATA,
COLUMN=V_ACCT_SUBGRP_N,
STYLE=BOLD,
WHEN =ACCT_GRP_TYPE_C EQ 'GM',
$
TYPE=DATA,
COLUMN=V_ACCT_SUBGRP_N,
STYLE=BOLD,
WHEN =ACCT_GRP_TYPE_C EQ 'CE',
$
TYPE=DATA,
COLUMN=V_ACCT_SUBGRP_N,
STYLE=BOLD,
WHEN =ACCT_GRP_TYPE_C EQ 'CP',
$
-*****COLOR PADDING FOR VARIANCE DATA FOR MTD
TYPE=DATA,
COLUMN= V_MTD_BPGOAL_LY_RS_PCT,
BACKCOLOR= RGB(28 168 35),
WHEN= V_FLAG_MTD EQ 'SG',
$
TYPE=DATA,
COLUMN= V_MTD_BPGOAL_LY_RS_PCT,
BACKCOLOR= 'YELLOW',
WHEN= V_FLAG_MTD EQ 'SY',
$
TYPE=DATA,
COLUMN= V_MTD_BPGOAL_LY_RS_PCT,
BACKCOLOR= 'RED',
WHEN= V_FLAG_MTD EQ 'SR',
$
TYPE=DATA,
COLUMN= V_MTD_COMPSALES_VAR,
BACKCOLOR= RGB(28 168 35),
WHEN= V_FLAG_MTD EQ 'EG',
$
TYPE=DATA,
COLUMN= V_MTD_COMPSALES_VAR,
BACKCOLOR= 'YELLOW',
WHEN= V_FLAG_MTD EQ 'EY',
$
TYPE=DATA,
COLUMN= V_MTD_COMPSALES_VAR,
BACKCOLOR= 'RED',
WHEN= V_FLAG_MTD EQ 'ER',
$
TYPE=DATA,
COLUMN= V_MTD_COMPSALES_VAR,
BACKCOLOR= RGB(28 168 35),
WHEN= V_FLAG_MTD EQ 'PG',
$
TYPE=DATA,
COLUMN= V_MTD_COMPSALES_VAR,
BACKCOLOR= 'YELLOW',
WHEN= V_FLAG_MTD EQ 'PY',
$
TYPE=DATA,
COLUMN= V_MTD_COMPSALES_VAR,
BACKCOLOR= 'RED',
WHEN= V_FLAG_MTD EQ 'PR',
$
-*****COLOR PADDING FOR VARIANCE DATA FOR YTD
TYPE=DATA,
COLUMN= V_YTD_BPGOAL_LY_RS_PCT,
BACKCOLOR= RGB(28 168 35),
WHEN= V_FLAG_YTD EQ 'SG',
$
TYPE=DATA,
COLUMN= V_YTD_BPGOAL_LY_RS_PCT,
BACKCOLOR= 'YELLOW',
WHEN= V_FLAG_YTD EQ 'SY',
$
TYPE=DATA,
COLUMN= V_YTD_BPGOAL_LY_RS_PCT,
BACKCOLOR= 'RED',
WHEN= V_FLAG_YTD EQ 'SR',
$
TYPE=DATA,
COLUMN= V_YTD_COMPSALES_VAR,
BACKCOLOR= RGB(28 168 35),
WHEN= V_FLAG_YTD EQ 'EG',
$
TYPE=DATA,
COLUMN= V_YTD_COMPSALES_VAR,
BACKCOLOR= 'YELLOW',
WHEN= V_FLAG_YTD EQ 'EY',
$
TYPE=DATA,
COLUMN= V_YTD_COMPSALES_VAR,
BACKCOLOR= 'RED',
WHEN= V_FLAG_YTD EQ 'ER',
$
TYPE=DATA,
COLUMN= V_YTD_COMPSALES_VAR,
BACKCOLOR= RGB(28 168 35),
WHEN= V_FLAG_YTD EQ 'PG',
$
TYPE=DATA,
COLUMN= V_YTD_COMPSALES_VAR,
BACKCOLOR= 'YELLOW',
WHEN= V_FLAG_YTD EQ 'PY',
$
TYPE=DATA,
COLUMN= V_YTD_COMPSALES_VAR,
BACKCOLOR= 'RED',
WHEN= V_FLAG_YTD EQ 'PR',
$
TYPE=SUBTOTAL,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=LIGHT,
BORDER-RIGHT=LIGHT,
-* HEADALIGN=INTERNAL,
BACKCOLOR=RGB(236 236 236),
$
TYPE=SUBFOOT,
COLUMN=V_ACCT_SUBGRP_N,
BORDER=LIGHT,
$
TYPE=SUBFOOT,
BORDER=OFF,
$
TYPE=SUBTOTAL,
COLUMN=V_ACCT_SUBGRP_N,
STYLE=BOLD,
$
TYPE=SUBTOTAL,
COLUMN=V_YTD_COMPSALES_VAR,
BORDER=LIGHT,
$
ENDSTYLE
END
November 10, 2006, 06:31 AM
Tom FlynnSyed,
When ever you use SUBTOTAL-SUB-TOTAL-RECOMPUTE-SUMMARIZE, WebFOCUS calculates the length of the column you are doing these on, and, will FOLD-LINE on these total lines if the calculated length overrides the total columns.
If you only want totals on 1 line, I have found COMPUTE with RECAP with SUBFOOT works for me:
COMPUTE
COL1_BL/A13 = ' '; NOPRINT
COMPUTE
COL1_EXP/P13.2C = IF SORT_01 EQ '1' THEN REVISED ELSE 0; NOPRINT
COMPUTE
COL1_RCT/P13.2C = IF SORT_01 EQ '2' THEN REVISED ELSE 0; NOPRINT
COMPUTE
COL2_EXP/P13.2C = IF SORT_01 EQ '1' THEN UNALLOTTED ELSE 0; NOPRINT
COMPUTE
COL2_RCT/P13.2C = IF SORT_01 EQ '2' THEN UNALLOTTED ELSE 0; NOPRINT
COMPUTE
COL3_EXP/P13.2C = IF SORT_01 EQ '1' THEN ALLOTTED ELSE 0; NOPRINT
COMPUTE
COL3_RCT/P13.2C = IF SORT_01 EQ '2' THEN ALLOTTED ELSE 0; NOPRINT
COMPUTE
COL4_EXP/P13.2C = IF SORT_01 EQ '1' THEN MTD ELSE 0; NOPRINT
COMPUTE
COL4_RCT/P13.2C = IF SORT_01 EQ '2' THEN MTD ELSE 0; NOPRINT
COMPUTE
COL5_EXP/P13.2C = IF SORT_01 EQ '1' THEN PTD ELSE 0; NOPRINT
COMPUTE
COL5_RCT/P13.2C = IF SORT_01 EQ '2' THEN PTD ELSE 0; NOPRINT
COMPUTE
COL6_EXP/P13.2C = IF SORT_01 EQ '1' THEN UNEXPENDED ELSE 0; NOPRINT
COMPUTE
COL6_RCT/P13.2C = IF SORT_01 EQ '2' THEN UNEXPENDED ELSE 0; NOPRINT
COMPUTE
COL7_EXP/P13.2C = IF SORT_01 EQ '1' THEN ENCUMB ELSE 0; NOPRINT
COMPUTE
COL7_RCT/P13.2C = IF SORT_01 EQ '2' THEN ENCUMB ELSE 0; NOPRINT
BY FUND_LEV_4 NOPRINT
BY BUDG_CD NOPRINT
BY PROG_CD NOPRINT
BY GRANT_ID NOPRINT NOSPLIT
BY X_FUND NOPRINT
BY SORT_01 NOPRINT
BY SUM_DESC NOPRINT SKIP-LINE
BY X_ACCT NOPRINT
BY ACCT_01 AS 'ACCOUNT - DESC'
BY X_ACTIVITY NOPRINT
BY ACT_01 AS 'ACTIVITY - DESC'
ON SUM_DESC SUBTOTAL AS 'TOTAL '
ON GRANT_ID SUBHEAD
"<GRANT_ID [ <FUND ) - <GRANTTITLE </1"
ON GRANT_ID RECAP
COL1_TOT1/P13.2C = COL1_RCT - COL1_EXP;
COL2_TOT1/P13.2C = COL2_RCT - COL2_EXP;
COL3_TOT1/P13.2C = COL3_RCT - COL3_EXP;
COL4_TOT1/P13.2C = COL4_RCT - COL4_EXP;
COL5_TOT1/P13.2C = COL5_RCT - COL5_EXP;
COL6_TOT1/P13.2C = COL6_RCT - COL6_EXP;
COL7_TOT1/P13.2C = COL7_RCT - COL7_EXP;
SPECIAL/A18 = ' - Appropriations:';;
COLON/A1 = ':';
-*
ON GRANT_ID SUBFOOT
" "
" "
" "
" "
"TOTAL for Grant <GRANT_ID : <COL1_TOT1<COL2_TOT1<COL3_TOT1<COL4_TOT1<COL5_TOT1<COL6_TOT1<COL7_TOT1"
WHEN COL1_TOT1 EQ 0;
ON GRANT_ID SUBFOOT
" "
" "
" "
" "
"TOTAL for Grant <GRANT_ID - Appropriations: <COL1_TOT1<COL2_TOT1<COL3_TOT1<COL4_TOT1<COL5_TOT1<COL6_TOT1<COL7_TOT1"
-*********************
WHEN COL1_TOT1 NE 0;
-*********************
ON GRANT_ID UNDER-LINE
-*
-* BUDGET RECALCULATIONS
-*
ON BUDG_CD RECAP
COL1_TOT2/P13.2C = (COL1_RCT - COL1_EXP);
COL2_TOT2/P13.2C = (COL2_RCT - COL2_EXP);
COL3_TOT2/P13.2C = (COL3_RCT - COL3_EXP);
COL4_TOT2/P13.2C = (COL4_RCT - COL4_EXP);
COL5_TOT2/P13.2C = (COL5_RCT - COL5_EXP);
COL6_TOT2/P13.2C = (COL6_RCT - COL6_EXP);
COL7_TOT2/P13.2C = (COL7_RCT - COL7_EXP);
SUM01_EXP/P13.2C = COL1_EXP;
SUM02_EXP/P13.2C = COL2_EXP;
SUM03_EXP/P13.2C = COL3_EXP;
SUM04_EXP/P13.2C = COL4_EXP;
SUM05_EXP/P13.2C = COL5_EXP;
SUM06_EXP/P13.2C = COL6_EXP;
SUM07_EXP/P13.2C = COL7_EXP;
SUM01_RCT/P13.2C = COL1_RCT;
SUM02_RCT/P13.2C = COL2_RCT;
SUM03_RCT/P13.2C = COL3_RCT;
SUM04_RCT/P13.2C = COL4_RCT;
SUM05_RCT/P13.2C = COL5_RCT;
SUM06_RCT/P13.2C = COL6_RCT;
SUM07_RCT/P13.2C = COL7_RCT;
ON BUDG_CD SUBFOOT
" "
"TOTAL for EXPENSES : <SUM01_EXP<SUM02_EXP<SUM03_EXP<SUM04_EXP<SUM05_EXP<SUM06_EXP<SUM07_EXP"
"TOTAL for RECEIPTS : <SUM01_RCT<SUM02_RCT<SUM03_RCT<SUM04_RCT<SUM05_RCT<SUM06_RCT<SUM07_RCT"
" "
"TOTAL for Budget <BUDG_CD : <COL1_TOT2<COL2_TOT2<COL3_TOT2<COL4_TOT2<COL5_TOT2<COL6_TOT2<COL7_TOT2"
-*********************
WHEN COL1_TOT2 EQ 0;
-*********************
ON BUDG_CD SUBFOOT
" "
"TOTAL for EXPENSES : <SUM01_EXP<SUM02_EXP<SUM03_EXP<SUM04_EXP<SUM05_EXP<SUM06_EXP<SUM07_EXP"
"TOTAL for RECEIPTS : <SUM01_RCT<SUM02_RCT<SUM03_RCT<SUM04_RCT<SUM05_RCT<SUM06_RCT<SUM07_RCT"
" "
"TOTAL for Budget <BUDG_CD - Appropriations: <COL1_TOT2<COL2_TOT2<COL3_TOT2<COL4_TOT2<COL5_TOT2<COL6_TOT2<COL7_TOT2"
-*********************
WHEN COL1_TOT2 NE 0;
-*********************
-*
-* PROGRAM RECALCULATIONS
-*
ON PROG_CD RECAP
COL1_TOT3/P13.2C = (COL1_RCT - COL1_EXP);
COL2_TOT3/P13.2C = (COL2_RCT - COL2_EXP);
COL3_TOT3/P13.2C = (COL3_RCT - COL3_EXP);
COL4_TOT3/P13.2C = (COL4_RCT - COL4_EXP);
COL5_TOT3/P13.2C = (COL5_RCT - COL5_EXP);
COL6_TOT3/P13.2C = (COL6_RCT - COL6_EXP);
COL7_TOT3/P13.2C = (COL7_RCT - COL7_EXP);
SUM11_EXP/P13.2C = COL1_EXP;
SUM12_EXP/P13.2C = COL2_EXP;
SUM13_EXP/P13.2C = COL3_EXP;
SUM14_EXP/P13.2C = COL4_EXP;
SUM15_EXP/P13.2C = COL5_EXP;
SUM16_EXP/P13.2C = COL6_EXP;
SUM17_EXP/P13.2C = COL7_EXP;
SUM11_RCT/P13.2C = COL1_RCT;
SUM12_RCT/P13.2C = COL2_RCT;
SUM13_RCT/P13.2C = COL3_RCT;
SUM14_RCT/P13.2C = COL4_RCT;
SUM15_RCT/P13.2C = COL5_RCT;
SUM16_RCT/P13.2C = COL6_RCT;
SUM17_RCT/P13.2C = COL7_RCT;
ON PROG_CD SUBFOOT
" "
"TOTAL for EXPENSES : <SUM11_EXP<SUM12_EXP<SUM13_EXP<SUM14_EXP<SUM15_EXP<SUM16_EXP<SUM17_EXP"
"TOTAL for RECEIPTS : <SUM11_RCT<SUM12_RCT<SUM13_RCT<SUM14_RCT<SUM15_RCT<SUM16_RCT<SUM17_RCT"
" "
"TOTAL for Program <PROG_CD : <COL1_TOT3<COL2_TOT3<COL3_TOT3<COL4_TOT3<COL5_TOT3<COL6_TOT3<COL7_TOT3"
-*********************
FOOTING
"FWRWCIFD.FEX"
ON TABLE NOTOTAL
-SET &HOLDTYPE = IF &BATCHIND EQ 'Y' THEN 'HOLD' ELSE 'PCHOLD';
ON TABLE &HOLDTYPE FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET GRID OFF
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='LETTER',
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=8,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=TITLE,
SIZE=9,
STYLE=BOLD,
$
TYPE=TABHEADING,
SIZE=9,
STYLE=BOLD,
$
TYPE=HEADING,
SIZE=10,
STYLE=BOLD,
$
TYPE=FOOTING,
SIZE=8,
STYLE=BOLD,
JUSTIFY=LEFT,
$
TYPE=SUBHEAD,
SIZE=10,
STYLE=BOLD,
$
TYPE=SUBFOOT,
HEADALIGN=BODY,
STYLE=BOLD,
$
TYPE=SUBFOOT, LINE=2, ITEM=1, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8,$
TYPE=SUBFOOT, LINE=2, ITEM=2, STYLE=BOLD, SIZE=8, POSITION = REVISED,$
TYPE=SUBFOOT, LINE=2, ITEM=3, STYLE=BOLD, SIZE=8, POSITION = UNALLOTTED,$
TYPE=SUBFOOT, LINE=2, ITEM=4, STYLE=BOLD, SIZE=8, POSITION = ALLOTTED,$
TYPE=SUBFOOT, LINE=2, ITEM=5, STYLE=BOLD, SIZE=8, POSITION = MTD,$
TYPE=SUBFOOT, LINE=2, ITEM=6, STYLE=BOLD, SIZE=8, POSITION = PTD,$
TYPE=SUBFOOT, LINE=2, ITEM=7, STYLE=BOLD, SIZE=8, POSITION = UNEXPENDED,$
TYPE=SUBFOOT, LINE=2, ITEM=8, STYLE=BOLD, SIZE=8, POSITION = ENCUMB,$
-*
TYPE=SUBFOOT, LINE=3, ITEM=1, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8,$
TYPE=SUBFOOT, LINE=3, ITEM=2, STYLE=BOLD, SIZE=8, POSITION = REVISED,$
TYPE=SUBFOOT, LINE=3, ITEM=3, STYLE=BOLD, SIZE=8, POSITION = UNALLOTTED,$
TYPE=SUBFOOT, LINE=3, ITEM=4, STYLE=BOLD, SIZE=8, POSITION = ALLOTTED,$
TYPE=SUBFOOT, LINE=3, ITEM=5, STYLE=BOLD, SIZE=8, POSITION = MTD,$
TYPE=SUBFOOT, LINE=3, ITEM=6, STYLE=BOLD, SIZE=8, POSITION = PTD,$
TYPE=SUBFOOT, LINE=3, ITEM=7, STYLE=BOLD, SIZE=8, POSITION = UNEXPENDED,$
TYPE=SUBFOOT, LINE=3, ITEM=8, STYLE=BOLD, SIZE=8, POSITION = ENCUMB,$
-*
TYPE=SUBFOOT, LINE=4, ITEM=1, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8,$
TYPE=SUBFOOT, LINE=4, ITEM=2, STYLE=BOLD, SIZE=8, POSITION = REVISED,$
TYPE=SUBFOOT, LINE=4, ITEM=3, STYLE=BOLD, SIZE=8, POSITION = UNALLOTTED,$
TYPE=SUBFOOT, LINE=4, ITEM=4, STYLE=BOLD, SIZE=8, POSITION = ALLOTTED,$
TYPE=SUBFOOT, LINE=4, ITEM=5, STYLE=BOLD, SIZE=8, POSITION = MTD,$
TYPE=SUBFOOT, LINE=4, ITEM=6, STYLE=BOLD, SIZE=8, POSITION = PTD,$
TYPE=SUBFOOT, LINE=4, ITEM=7, STYLE=BOLD, SIZE=8, POSITION = UNEXPENDED,$
TYPE=SUBFOOT, LINE=4, ITEM=8, STYLE=BOLD, SIZE=8, POSITION = ENCUMB,$
-*
TYPE=SUBFOOT, LINE=5, ITEM=1, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8,$
TYPE=SUBFOOT, LINE=5, ITEM=2, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8,$
TYPE=SUBFOOT, LINE=5, ITEM=3, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8, COLOR = RED, WHEN=COL1_TOT1 NE 0,$
TYPE=SUBFOOT, LINE=5, ITEM=3, JUSTIFY=LEFT , STYLE=BOLD, SIZE=8, WHEN=COL1_TOT1 EQ 0,$
TYPE=SUBFOOT, LINE=5, ITEM=4, STYLE=BOLD, SIZE=8, POSITION = REVISED,$
TYPE=SUBFOOT, LINE=5, ITEM=5, STYLE=BOLD, SIZE=8, POSITION = UNALLOTTED,$
TYPE=SUBFOOT, LINE=5, ITEM=6, STYLE=BOLD, SIZE=8, POSITION = ALLOTTED,$
TYPE=SUBFOOT, LINE=5, ITEM=7, STYLE=BOLD, SIZE=8, POSITION = MTD,$
TYPE=SUBFOOT, LINE=5, ITEM=8, STYLE=BOLD, SIZE=8, POSITION = PTD,$
TYPE=SUBFOOT, LINE=5, ITEM=9, STYLE=BOLD, SIZE=8, POSITION = UNEXPENDED,$
TYPE=SUBFOOT, LINE=5, ITEM=10, STYLE=BOLD, SIZE=8, POSITION = ENCUMB,$
-*
ENDSTYLE
END
-EXIT
-*****************************************************************************
Tom