I have a problem in conditional styling in PDF.
In an across report I had a conditional background on certain rows, but when I used SQUEEZE=xx on the across column to limit the width this background disappeared only in the first across column not in all others.

I was able to reproduce it with a CAR example.

TABLE FILE IBISAMP/CAR
SUM SALES
BY COUNTRY
ACROSS MODEL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *

TYPE=REPORT,    SQUEEZE=ON,     ORIENTATION=LANDSCAPE,  PAGESIZE='A4', $
TYPE=REPORT,    UNITS=PTS,      FONT='VERDANA', SIZE=9, $
TYPE=REPORT,    COLUMN=SALES,   SQUEEZE=50, $
TYPE=ACROSSVALUE, WRAP=ON, $
TYPE=DATA,      TOPGAP=2,       BOTTOMGAP=2, $
TYPE=DATA,      STYLE=BOLD,     BACKCOLOR=RGB(225 225 225), WHEN=COUNTRY EQ 'JAPAN', $

ENDSTYLE
END

It seems to appear with certain combinations of style settings. Without the squeeze I do not have the problem. If I change the TYPE=DATA GAP line to a TYPE=REPORT GAP line I do not have the problem either.

As it only happens with the first across column it looks like a bug, or am I doing something wrong?

It happens with me in 7.7.05, what about other versions?

Martin.

This message has been edited. Last edited by: Martin vK,

The across column is MODEL (not SALES):

changing the line
TYPE=REPORT, COLUMN=SALES, SQUEEZE=50, $
to
TYPE=REPORT, COLUMN=MODEL, SQUEEZE=50, $

the report works (for me).

This way the conditional styling indeed works, but I can not size the width of the across column.

With COLUMN=MODEL, SQUEEZE=nnn I only accomplish that the column is squeezed to the maximum width of the SALES amounts. SQUEEZE=5 or 50 or 500 or just SQUEEZE=ON all give the same result.

With COLUMN=SALES, SQUEEZE=nnn I can set the desired width of the column, and with TYPE=ACROSSVALUE, WRAP=ON I can wrap the across value (column title) accordingly. But here I loose the conditional styling of the first across column.

WebFOCUS styling is very annoying because it does not cascade and because changing the order of the style commands can have an effect, unlike CSS.

Meanwhile, this works. I have had to do this many times recently, I suspect something has changed internally and we have to live with the change.

TABLE FILE IBISAMP/CAR
SUM SALES
BY COUNTRY
ACROSS MODEL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *

TYPE=REPORT,    SQUEEZE=ON,     ORIENTATION=LANDSCAPE,  PAGESIZE='A4', $
TYPE=REPORT,    UNITS=PTS,      FONT='VERDANA', SIZE=9, $
TYPE=REPORT,    COLUMN=SALES,   SQUEEZE=50, $
TYPE=ACROSSVALUE, WRAP=ON, $

TYPE=DATA,      TOPGAP=2,       BOTTOMGAP=2,
WHEN=COUNTRY NE 'JAPAN', $

TYPE=DATA,      TOPGAP=2,       BOTTOMGAP=2,
STYLE=BOLD,     BACKCOLOR=RGB(225 225 225), 
WHEN=COUNTRY EQ 'JAPAN', $

ENDSTYLE
END

That is indeed a good work-around.
thanks, Martin.