-*I had some user selectable column reports that broke. I found that you have to leave off the comma after the last field in your selections. I also found that if you include FOC_NONE as one of the choices, that column will not print when FOC_NONE is selected.

-* I had posted this earlier, this is a replacement for that original post.

-*Report that has user selected columns, user selected BYs and user selected ACROSS.
-*I found the basics of this in the search solutions of the Tech library at
-* http://documentation.informati...s.com/topics_dia.asp
-* The results of that search are at the bottom.
-*When you make a SET command the code for each SET command has to remain on ONE row.
-*(The wrap in the e-mail put the following on two rows)
-*You do not have to have duplicate field names in all of the column selectors.
-*You can mix them up if it makes sense for the report.
-*The FOC_NONE in the SET command allows a column to be ignored.
-*When the FOC_NONE is selected, that field is ignored and no column is created in the report.
-*When you create the Colums and the BY and ACROSS SET commands, do not place a comma after the last column
-*field the user is to pick from. A comma at the end will break the report in later version of WebFOCUS.
-*
-*What I am doing for &FLD14 and &FLD15 isn't necessary with this particular data.
-*This demonstrates how you select on one field and then print a different if that makes sense.
-*In my acutal report, I selected a value field and then printed
-*the associated description field.
-*
-*The defined field NOSORT gives the ability to have no BY and/or no ACROSS sorting happening in the report.
-SET &FLD1 = &CTR1.(DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN1'.;
-SET &FLD2 = &CTR2.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN2'.;
-SET &FLD3 = &CTR3.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN3'.;
-SET &FLD4 = &CTR4.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN4'.;
-SET &FLD5 = &CTR5.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN5'.;
-SET &FLD6 = &CTR6.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN6'.;
-SET &FLD7 = &CTR7.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN7'.;
-SET &FLD8 = &CTR8.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN8'.;
-SET &FLD9 = &CTR9.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN9'.;
-SET &FLD10 = &CTR10.(FOC_NONE, DEALER_COST, RETAIL_COST, SALES, LENGTH, WIDTH, HEIGHT, WEIGHT, WHEELBASE, FUEL_CAP, BHP, RPM, MPG, ACCEL, WARRANTY, STANDARD).'COLUMN10'.;
-SET &FLD11 = &CTR11.(COUNTRY, CAR, BODYTYPE, SEATS, NOSORT).'BY FIELD 1'.;
-SET &FLD14 = IF &FLD11 EQ COUNTRY THEN COUNTRY ELSE IF &FLD11 EQ CAR THEN CAR ELSE IF &FLD11 EQ BODYTYPE THEN BODYTYPE ELSE IF &FLD11 EQ SEATS THEN SEATS ELSE IF &FLD11 EQ NOSORT THEN NOSORT;
-SET &FLD13 = &CTR13.(COUNTRY, CAR, BODYTYPE, SEATS, NOSORT).'BY FIELD 2'.;
-SET &FLD15 = IF &FLD13 EQ COUNTRY THEN COUNTRY ELSE IF &FLD13 EQ CAR THEN CAR ELSE IF &FLD13 EQ BODYTYPE THEN BODYTYPE ELSE IF &FLD13 EQ SEATS THEN SEATS ELSE IF &FLD13 EQ NOSORT THEN NOSORT;
-SET &FLD12 = &CTR12.(BODYTYPE, SEATS, MODEL, CAR, COUNTRY, NOSORT).'ACROSS FIELD 1'.;
DEFINE FILE CAR
NOSORT/A1='1';
END
SET BYDISPLAY = ON
TABLE FILE CAR
SUM
&FLD1
&FLD2
&FLD3
&FLD4
&FLD5
&FLD6
&FLD7
&FLD8
&FLD9
&FLD10
BY &FLD11 NOPRINT
BY &FLD14
BY &FLD13 NOPRINT
BY &FLD15
ACROSS &FLD12
ON &FLD14 SUBTOTAL AS '*TOTAL'
ON &FLD14 SUBTOTAL AS '*TOTAL &FLD14'
HEADING
" USER SELECTABLE REPORT "
FOOTING
"USER SELECTABLE REPORT "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
FONT='TIMES NEW ROMAN',
SIZE=10,
$
TYPE=SUBTOTAL,
BY=2,
BORDER-TOP=MEDIUM,
BORDER-BOTTOM=MEDIUM,
BORDER-LEFT=MEDIUM,
BORDER-RIGHT=MEDIUM,
STYLE=BOLD,
$
STYLE=NORMAL,
$
TYPE=DATA,
IN-RANGES='SUMMARY',
$
TYPE=TITLE,
STYLE=BOLD,
IN-RANGES='SUMMARY',
$
ENDSTYLE
END
-*
-*
-*
-*
-*TECHNIQUE
-*How can I select columns in any order on a report?
-*Case: 40302534 Product: Developer Studio (431>) Release: 760 Primary OS: WIN/XP Date: 08/02/26
-*Case information refers to the Product, Release, and OS for which this question was asked.
-*The solution may apply to other Products, Releases, and Operating Systems.
-*
-*Problem:
-*How can I select columns and choose the order of how each field is displayed
-*and seen within the report?
-*Solution:
-*The example below is working with five choices for each amper variable.
-*(&FLD1, &FLD2, etc...). They consist of a blank value and four other
-*fields, giving the option to select in any order the user chooses whether it is
-*1, 2, 3, or 4 fields at a time within the desired order.
-*Example:
-*-SET &FLD1 = &CTR1.(CAR, COUNTRY, DCOST, RCOST,).FLD1.;
-*-SET &FLD2 = &CTR2.(CAR, COUNTRY, DCOST, RCOST,).FLD2.;
-*-SET &FLD3 = &CTR3.(CAR, COUNTRY, DCOST, RCOST,).FLD3.;
-*-SET &FLD4 = &CTR4.(CAR, COUNTRY, DCOST, RCOST,).FLD4.;
-*TABLE FILE CAR
-*PRINT &FLD1 &FLD2 &FLD3 &FLD4
-*END
-*Product: Developer Studio (431>), DEVSTUDIO
-*Symptom: None Assigned
-*Functional Area: None Assigned
-*Operating System: WIN/XP, WIN/XP
-*Keywords: 40302534, COLUMN, SELECT, ORDER, LIMIT, COLUMNS
-*Docid: 40302534

This message has been edited. Last edited by: Kerry,

Hi Guy,

Thank you for sharing with all. I will mark this one as [SHARING]. If you have a question for others, please feel free to post.

Cheers,

Kerry