Hi ALL,

I want to read the below mentioned values from acx file through webfocus coding.

please suggest.

sample.acx

SEGNAME=TABLE_CURR,
TABLENAME=ACT_LIVE_DB&&TD_DBNAME.ACCT_CURR,
CONNECTION=&&WF_CONN,
GUI_PARAMS='0,816,50,864,98,80,120,1', $
SEGNAME=FORG_AGNT,
TABLENAME=ACT_LIVE_DB&&TD_DBNAME.ACCT_AGNT,
CONNECTION=&&WF_CONN,
GUI_PARAMS='0,60,298,108,346,80,120,1', $


Expected Output:
SEGNAME DBNAME TABLENAME CONNECTION
TABLE_CURR ACT_LIVE_DB&&TD_DBNAME ACCT_CURR &&WF_CONN
FORG_AGNT ACT_LIVE_DB&&TD_DBNAME FORG_AGNT &&WF_CONN

This message has been edited. Last edited by: FP Mod Chuck,

Veeramani

This is the best I could do. The internal table systable does not list the segment name and the database name is part of the table name.


TABLE FILE SYSTABLE
BY SYSTABLE.SYSTABLE.NAME AS 'Master File'
BY LOWEST SYSTABLE.SYSTABLE.REALNAME AS 'Table Name'
BY SYSTABLE.SYSTABLE.SERVER AS 'Connection'
WHERE SYSTABLE.SYSTABLE.NAME EQ '&NAME.(FIND SYSTABLE.SYSTABLE.NAME IN SYSTABLE).NAME:.';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END


Hi Veeramani Karuthapandian

Perhaps you should play around in the SYS... tables and see what is available.

As you have seen SYSTABLE is one, SYSCOLUM is another.

Check them out and discover amazing things.

I saved your example if file veeramini.txt in WF application 'focalpoint'

quote:

SEGNAME=TABLE_CURR,
TABLENAME=ACT_LIVE_DB&&TD_DBNAME.ACCT_CURR,
CONNECTION=&&WF_CONN,
GUI_PARAMS='0,816,50,864,98,80,120,1', $
SEGNAME=FORG_AGNT,
TABLENAME=ACT_LIVE_DB&&TD_DBNAME.ACCT_AGNT,
CONNECTION=&&WF_CONN,
GUI_PARAMS='0,60,298,108,346,80,120,1', $

I created the following master file:

  
FILENAME=acx, SUFFIX=COM
SEGMENT=ACX, SEGTYPE=S0
FIELDNAME=SEGNAME, ALIAS=SEGNAME, USAGE=A60, ACTUAL=A60, $
FIELDNAME=TABLENAME, ALIAS=TABLENAME, USAGE=A120, ACTUAL=A120, $
FIELDNAME=CONNECTION, ALIAS=CONNECTION, USAGE=A60, ACTUAL=A60, $
FIELDNAME=GUI_PARAMS, ALIAS=GUI_PARAMS, USAGE=A120, ACTUAL=A120, $
 DEFINE DBNAME/A60=GETTOK(TABLENAME, 120, 1, '.', 60, 'A60');, $
 DEFINE TBNAME/A60=GETTOK(TABLENAME, 120, 2, '.', 60, 'A60');, $

And the procedure:

  
-* FILE ACX.FEX
FILEDEF ACX DISK focalpoint/veeramini.txt
TABLE FILE ACX
PRINT SEGNAME DBNAME TBNAME CONNECTION
END

It's easy to forget that Master and access files are just comma delimeted.

This message has been edited. Last edited by: Waz,

Thanks Danny

That is a great solution!

Thanks Waz & Chuck,
The result of being old but still with a memory...

quote:

The result of being old but still with a memory...

Good to know some are still around.

quote:

Originally posted by FP Mod Chuck:
Veeramani

This is the best I could do. The internal table systable does not list the segment name and the database name is part of the table name.


TABLE FILE SYSTABLE
BY SYSTABLE.SYSTABLE.NAME AS 'Master File'
BY LOWEST SYSTABLE.SYSTABLE.REALNAME AS 'Table Name'
BY SYSTABLE.SYSTABLE.SERVER AS 'Connection'
WHERE SYSTABLE.SYSTABLE.NAME EQ '&NAME.(FIND SYSTABLE.SYSTABLE.NAME IN SYSTABLE).NAME:.';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END


Hi Chuck,

The above mentioned code is returned always single record. But, clustered table details are not able to retrieve. could you please suggest.


Thanks,
Veeramani K

Hi Veeramani Karuthapandian,

If you are not getting the answer you need, I would suggest creating a case in TechSupport, to find out if the information is available.

Veeramani
Are you still trying to retrieve from the acx file?
If so, did you try my suggestion?

quote:

Originally posted by Waz:
Hi Veeramani Karuthapandian,

If you are not getting the answer you need, I would suggest creating a case in TechSupport, to find out if the information is available.

Hi Waz,

Please raise an case in Tech Support. help me to resolve this issue.

quote:

Originally posted by Danny-SRL:
Veeramani
Are you still trying to retrieve from the acx file?
If so, did you try my suggestion?

Hi Danny,

As per my requirement, I want to go-through all access files from all domains under reporting server. Hence, I couldn't able to create a common master file to read the table name detail values.

Thanks,
Veeramani K

Veeramani,

You threw down the gauntlet. Try the following (replace the DEFAULT values with your own):

APPS.mas

  
FILENAME=APPS, SUFFIX=FIX
SEGNAME=APPS, SEGTYPE=S0
FIELDNAME=APPTIME, ALIAS=APPTIME, USAGE=A18, ACTUAL=A18, $
FIELDNAME=APPNAME, ALIAS=APPNAME, USAGE=A64, ACTUAL=A64, $

AFILES.mas

  
FILENAME=AFILES, SUFFIX=FIX
SEGNAME=APPFILES, SEGTYPE=S0
FIELDNAME=FILNAME, ALIAS=FILNAME, USAGE=A70, ACTUAL=A70, $

veeramani.fex

  
-SET &ECHO=ALL;
-* Veeramani
-DEFAULT &APPDISK='C:', &TDISK='D:'
-* Get the names of the apps
APP LIST HOLD
FILEDEF APPS DISK FOCAPPL.FTM
-RUN
TABLE FILE APPS
PRINT APPNAME
ON TABLE HOLD AS APPFILES FORMAT ALPHA
END
-RUN
-SET &NUMAPPS=&LINES;
-REPEAT #GETAPPS FOR &I FROM 1 TO &NUMAPPS;
-* Read each app
-READFILE APPFILES
-* For each app create a file containing all the files in the app
!DIR &APPDISK|\wf82\ibi\apps\&APPNAME /b > &TDISK|\TEMP\AFILES.FTM 
-*-RUN
-* Extract all names of acx files and save this list in a file (ACXFILES)
FILEDEF AFILES DISK &TDISK|\TEMP\AFILES.FTM
TABLE FILE AFILES
PRINT FILNAME 
WHERE FILNAME CONTAINS '.ACX' OR '.acx';
ON TABLE HOLD AS ACXFILES
END
-RUN
-SET &NUMACX=&LINES;
-REPEAT #GETACX FOR &X FROM 1 TO &NUMACX;
-* Read each acx file
-READFILE ACXFILES
-* Create FILEDEF string
-SET &ACXF=&APPNAME || '/' || &FILNAME;
-* Report from acx file containing connection
FILEDEF ACX DISK &ACXF
TABLE FILE ACX
"&ACXF"
PRINT SEGNAME DBNAME TBNAME CONNECTION
WHERE CONNECTION NE ' ';
END
-#GETACX
-CLOSE ACXFILES
-#GETAPPS

Good luck!

Oooops, I forgot to add the acx.mas file which had to be augmented...

  
FILENAME=acx, SUFFIX=COM
SEGMENT=ACX, SEGTYPE=S0
FIELDNAME=SEGNAME, ALIAS=SEGNAME, USAGE=A60, ACTUAL=A60, $
FIELDNAME=TABLENAME, ALIAS=TABLENAME, USAGE=A120, ACTUAL=A120, $
FIELDNAME=CONNECTION, ALIAS=CONNECTION, USAGE=A60, ACTUAL=A60, $
FIELDNAME=GUI_PARAMS, ALIAS=GUI_PARAMS, USAGE=A120, ACTUAL=A120, $
FIELDNAME=WORKSHEET, ALIAS=WORKSHEET, USAGE=A20, ACTUAL=A20, $
FIELDNAME=KEYS, ALIAS=KEYS, USAGE=A2, ACTUAL=A2, $
FIELDNAME=HROWS, ALIAS=HROWS, USAGE=A5, ACTUAL=A5, $
FIELDNAME=NUMDATA, ALIAS=NUMDATA, USAGE=A12, ACTUAL=A12, $
 DEFINE DBNAME/A60=GETTOK(TABLENAME, 120, 1, '.', 60, 'A60');, $
 DEFINE TBNAME/A60=GETTOK(TABLENAME, 120, -1, '.', 60, 'A60');, $

Hi Danny,

Thanks a lot. I will check and let you know..

By
Veeramani