I'd like to add our logo to a PDF report I've created.
When I try to change the report to a document I get the error message
"(FOC3201) DUPLICATE KEYWORD IN SYTLESHEET FILE AT LINE 72:"
Which I think is the

INCLUDE=IBFS:/CFG/FILE/IBI_HTML_DIR/javaassist/intl/EN/ENIADefault_combine.sty,$

line entry. But why is that a problem?

Even if I get this converted to a document I've read online that inserting a logo won't work for PDF output - only HTML.
Any suggested solutions? I would love to create a custom stylesheet, but don't know where to start.
Thanks in advance.

This message has been edited. Last edited by: TRue,

Can you post yopur code, and what format is the logo ?

Logo's are added differently depending on whether its PDF or HTML

TRue,

usually this means that in the .sty a certain component is define twice.

TYPE=DATA
COLOR=RED,
$
TYPE=DATA
COLOR=BLACK,
$

it simply doesn't know what to do and tells you so.

Yes, you can agrue it should take the first or the last, like .css. But it doesn't. It's called a stylesheet but that doesn't mean it has the same workings as .css stylesheets.

e.g.
check the contents of your .sty

G'luck,
Dave

I tried picking a different style sheet, since nothing stood out to me as duplicate, and I've done all modifications through the UI so I'm not sure where things went wrong. Here's my code:

 ON TABLE PCHOLD FORMAT HTML
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE SET HTMLCSS ON
ON TABLE SET HTMLENCODE ON
ON TABLE SET EMPTYREPORT ON
ON TABLE SET STYLE *
INCLUDE=IBFS:/CFG/FILE/IBI_HTML_DIR/javaassist/intl/EN/combine_templates/ENgray_theme.sty,$
TYPE=REPORT, LEFTGAP=0.1, RIGHTGAP=0.1, LEFTMARGIN=0.5, TOPMARGIN=0.5, RIGHTMARGIN=0.5, BOTTOMMARGIN=0.5, ORIENTATION=LANDSCAPE, $
TYPE=TABHEADING, LINE=1, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=1, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=NORMAL, $
TYPE=TABHEADING, LINE=2, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=2, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=2, ITEM=1, OBJECT=FIELD, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=2, ITEM=2, OBJECT=TEXT, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=3, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=3, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TITLE, COLUMN=N5, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N7, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N2, JUSTIFY=CENTER, STYLE=BOLD, $
TYPE=TITLE, COLUMN=N3, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N9, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N8, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N4, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N6, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N10, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N11, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N12, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N13, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N1, JUSTIFY=CENTER, $
TYPE=DATA, COLUMN=N5, JUSTIFY=CENTER, $
TYPE=DATA, COLUMN=N7, JUSTIFY=CENTER, $
TYPE=DATA, COLUMN=N2, JUSTIFY=CENTER, STYLE=BOLD, $
TYPE=DATA, COLUMN=N3, JUSTIFY=CENTER, $
TYPE=DATA, COLUMN=N9, JUSTIFY=CENTER, $
TYPE=DATA, COLUMN=N8, JUSTIFY=CENTER, $
TYPE=DATA, COLUMN=N1, JUSTIFY=CENTER, $
TYPE=SUBHEAD, BY=TRADES.TRADES.CUSTOMERID, LINE=1, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=BOLD, $
ENDSTYLE
END

 

I even switched to a different theme template just to see if it would wipe out the problem, but no matter if I am in PDF format or HTML for the report - when I try to switch to Document view I get the same error, but with no line entry reference.

P.S. I've tried this with my report in both PDF and HTML format but I get the same error.

This message has been edited. Last edited by: TRue,

Can you replicate this with one of the sample FOC files and post the code ?

We use our logo on all PDF output. We have the below code inside a .sty style that we made;

 
TYPE=REPORT,
     IMAGE=inside-top-logo.jpg,
     POSITION=(0.50000 0.25),
	 SIZE = (3.0625 0.50),
     ALT='KVCC Logo',
$
 

This will allow us to always have our logo in the same spot on every PDF output.

Hope it helps.

Waz, sorry, I don't know about sample FOC files.

MAdams1 - this is what I'd like to do, ideally, is to create our own .sty with the logo. Do you have any information on how I can create one - or does it have to be done in DevStudio?

The easiest way to make your own style is in the GUI, however, it can be done in code. In Dev Studio Explorer, right click on the 'Other' folder within an application folder(usually right below the 'procedures' folder). Select 'New', then 'STY File'. This basically opens notepad for you to create your own style and when you save it will be saved as a .sty file. This is not the same as a CSS style file, this is all WebFocus code. Below is code you can use to start with if you like, just copy it into the notepad that is opened above and make your own adjustments. It's probably easier for you to do a test fex and style it the way you want then save that style. There are always many ways to accomplish the same results though.

 
     LEFTMARGIN=0.500000,
     RIGHTMARGIN=0.500000,
     TOPMARGIN=0.250000,
     BOTTOMMARGIN=0.250000,
	 PAGESIZE='LETTER',
$

	 DEFMACRO=LAND,  WIDTH='10.000', STYLE=NORMAL,
$
	 DEFMACRO=PORT,  WIDTH='7.000', STYLE=NORMAL,
$

TYPE=REPORT,
     IMAGE=inside-top-logo.jpg,
     POSITION=(0.50000 0.25),
	 SIZE = (3.0625 0.50),
     ALT='Your Text Goes Here',
$
TYPE=REPORT,
	 GRID=OFF,
     FONT='VERDANA',
     SIZE=10,
	 COLOR='BLACK',
	 STYLE=NORMAL,
	 RIGHTGAP=0.125,
	 LEFTGAP=0.125,
$
TYPE=TABFOOTING,
	 SIZE=8,
$
TYPE=TABFOOTING,
     LINE=2,
     STYLE=BOLD,
	 SIZE=10,
$
TYPE=TABFOOTING,
     LINE=3,
     JUSTIFY=CENTER,
	 SIZE=8,
$
TYPE=TABFOOTING,
     LINE=4,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=UNDERLINE,
$
TYPE=TABFOOTING,
     LINE=5,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=UNDERLINE,
$
TYPE=TABFOOTING,
     LINE=7,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=UNDERLINE,
$
TYPE=FOOTING,
	 SIZE=9,
     STYLE=NORMAL,
     JUSTIFY=LEFT,
$
TYPE=HEADING,
     SIZE=11,
	 STYLE=BOLD,
	 JUSTIFY=CENTER,
$
TYPE=HEADING,
	 LINE=2,
     SIZE=18,
$
TYPE=HEADING,
	 LINE=3,
     SIZE=12,
	 STYLE=BOLD,
	 JUSTIFY=CENTER,
$
TYPE=TITLE,
	 FONT='VERDANA',
     SIZE=10,
	 STYLE=NORMAL,
$
TYPE=TABHEADING,
     LINE=2,
	 SIZE=12,
	 STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=TABHEADING,
	 SIZE=11,
	 STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=SUBTOTAL,
     BACKCOLOR=RGB(241 241 241),
	 SIZE=10,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(241 241 241),
     STYLE=BOLD,
	 SIZE=10,
$

 

Good Luck

I just noticed you use InfoAssist only. I guess I would just open Notepad and try that. Save it as a .sty file and use it that way. I don't use InfoAssist so can't help you with that.

Thanks MAdams1, I'll have my dev team help me out with creating a template since I'm only using InfoAssist.

Having said that, I still can't get the report I've created to turn into a document without getting the 'duplicate keyword in stylesheet' error message. I'm pasting in the entire code here, from when I try changing it into a document, since nothing is standing out to me as an issue. I even tried erasing the formatting of each individual field (that little eraser icon in IA) to allow the default stylesheet to do all the work.

 COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=Section_1, LAYOUT=ON, PAGESIZE=LETTER, ORIENTATION=LANDSCAPE, SHOW_GLOBALFILTER=OFF, LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=0.5, $
PAGELAYOUT=1, LEFTMARGIN=0.25, RIGHTMARGIN=0.25, TOPMARGIN=0.25, BOTTOMMARGIN=0.25, $
COMPONENT=Table_1, COMPONENT-TYPE=REPORT, POSITION=(0.104166 0.104166), DIMENSION=(* *), METADATA='VERSION:1.0;WIDTH:6.864583;HEIGHT:1.0;LEFT:0.104166;TOP:0.104166;COMPONENTS_INCLUDED:ContractDate,SellAmt,BuyAmt,ExchRate,Received,TransDate,Pending,PayAmount,PayPending,Customer,StartDate,EndDate,Account,Join_1,Join_2,Join_3', $
END

-*COMPONENT=Join_J001
JOIN TRADES.TRADES.TRADEID IN TRADES
TO MULTIPLE VUNRECONCILEDTRANSACTIONS.VUNRECONCILEDTRANSACTIONS.TRADEID IN VUNRECONCILEDTRANSACTIONS TAG J001 AS T2VUN
END
-*COMPONENT=Join_J003
JOIN TRADES.TRADES.BUYINGCURRENCYID IN TRADES
TO UNIQUE CURRENCIES.CURRENCIES.CURRENCYID IN CURRENCIES TAG J003 AS T2Cbuy
END
-*COMPONENT=Join_J004
JOIN TRADES.TRADES.SELLINGCURRENCYID IN TRADES
TO UNIQUE CURRENCIES.CURRENCIES.CURRENCYID IN CURRENCIES TAG J004 AS T2Csell
END
-*COMPONENT=Define_TRADES
DEFINE FILE TRADES
ContractDate/MDYY=HDATE ( TRADES.TRADES.BOOKEDON , 'MDYY' ) ;
SellAmt/D12.2C=TRADES.TRADES.SELLINGAMOUNT ;
BuyAmt/D12.2C=TRADES.TRADES.BUYINGAMOUNT ;
ExchRate/D10.4=TRADES.TRADES.EXCHANGERATE ;
Received/D12.2C=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS NOT MISSING THEN J001.VUNRECONCILEDTRANSACTIONS.MONEYIN ELSE 0 ;
TransDate/MDYY=HDATE ( J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE , 'MDYY' ) ;
Pending/D12.2C=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS MISSING THEN J001.VUNRECONCILEDTRANSACTIONS.MONEYIN ELSE 0 ;
PayAmount/D12.2CS=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS MISSING THEN 0 ELSE J001.VUNRECONCILEDTRANSACTIONS.MONEYOUT ;
PayPending/D12.2CS=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS MISSING THEN J001.VUNRECONCILEDTRANSACTIONS.MONEYOUT ELSE 0 ;
Customer/I9=TRADES.TRADES.CUSTOMERID ;
StartDate/MDYY=ContractDate ;
EndDate/MDYY=ContractDate ;
Account/I11=J001.VUNRECONCILEDTRANSACTIONS.CUSTOMERACCOUNT ;
END
SET COMPONENT=Table_1
-*component_type report
TABLE FILE TRADES
SUM Received/D12.2CS AS 'Incoming,Settlement,Applied'
Pending/D12.2CS
PayAmount/D12.2CS AS 'Outgoing,Payment,Processed'
PayPending/D12.2CS AS 'Pending'
BY Account NOPRINT SUBTOTAL 
BY TRADES.TRADES.TRADEID AS 'Trade #'
BY ContractDate AS 'Trade Date,mm/dd/yyyy'
BY SellAmt AS 'Customer,Buys'
BY J004.CURRENCIES.CURRENCYCODE AS 'Buy,Curr'
BY BuyAmt AS 'Customer,Owes,FIRMA'
BY J003.CURRENCIES.CURRENCYCODE AS 'Owe,Curr'
BY ExchRate AS 'Exch,Rate'
BY TransDate AS 'Settlement,or Payment,Date'
WHERE Account EQ '&Account.Customer Account #: (ie 90037458).';
WHERE StartDate GE '&StartDate.Start Date: (mm/dd/yyyy).';
WHERE EndDate LE '&EndDate.End Date:.';
ON TABLE SUBHEAD
" "
"Client:<Account<+0> - &Name:"
"Statement of Account for &StartDate to &EndDate"
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE SET HTMLCSS ON
ON TABLE SET HTMLENCODE ON
ON TABLE SET EMPTYREPORT ON
ON TABLE SET STYLE *
INCLUDE=IBFS:/CFG/FILE/IBI_HTML_DIR/javaassist/intl/EN/ENIADefault_combine.sty,$
TYPE=REPORT, LEFTGAP=0.1, RIGHTGAP=0.1, LEFTMARGIN=0.5, TOPMARGIN=0.5, RIGHTMARGIN=0.5, BOTTOMMARGIN=0.5, ORIENTATION=LANDSCAPE, $
TYPE=TABHEADING, LINE=1, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=1, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=NORMAL, $
TYPE=TABHEADING, LINE=2, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=2, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=2, ITEM=1, OBJECT=FIELD, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=2, ITEM=2, OBJECT=TEXT, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=3, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=3, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=BOLD+ITALIC, $
TYPE=TITLE, COLUMN=N5, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N7, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N2, JUSTIFY=CENTER, STYLE=BOLD, $
TYPE=TITLE, COLUMN=N3, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N9, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N8, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N4, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N6, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N10, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N11, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N12, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N13, JUSTIFY=CENTER, $
TYPE=TITLE, COLUMN=N1, JUSTIFY=CENTER, $
TYPE=SUBHEAD, BY=TRADES.TRADES.CUSTOMERID, LINE=1, ITEM=1, OBJECT=TEXT, SIZE=12, STYLE=BOLD, $
ENDSTYLE
END

COMPOUND END
 

Any idea what I should try to edit out to make this document work?

Thanks again.

quote:

INCLUDE=IBFS:/CFG/FILE/IBI_HTML_DIR/javaassist/intl/EN/ENIADefault_combine.sty,$

Whenever you include a style you have to do it like this

-INCLUDE mystyle.sty
$

Has to start with a dash(for dialogue manager code) no = sign and no comma at the end

Try that.

If that doesn't work, would you post your code from your style and I'll see if I see anything in there causing the issue.

When I try changing the code as you suggested and running the report I get "ibi.webfoc.wfmre.mrutil.WFMRError: MR object denoted by provided path IBFS:/CFG/FILE/IBI_HTML_DIR/javaassist/intl/EN/ENIADefault_combine.sty $ does not exist."

That line is written into the code automatically upon every report creation in IA - It's the default stylesheet automatically applied. I have other reports using this default stylesheet line entry which I can turn into a document with no error given, and I've used them to insert my logo and prove that it works, just not in this particular report.

I tried removing the line entry altogether, tried erasing the IA formatting on every field in the report, tried manually removing all the bold and sizing references in the code, etc. All did nothing, I still get the duplicate keyword error message. Yet I can turn other reports with the same (default) stylesheet into a document and insert my logo. Arg!

I re-created the entire report.
Changed it to a document, no error message.
Inserted logo.
STILL HAVE NO IDEA WHAT THE PROBLEM WAS!
Here's the code, in the document that actually works: (still has the default style line)

 COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=Section_1, LAYOUT=ON, PAGESIZE=LETTER, ORIENTATION=LANDSCAPE, SHOW_GLOBALFILTER=OFF, $
PAGELAYOUT=1, LEFTMARGIN=0.25, RIGHTMARGIN=0.25, TOPMARGIN=0.25, BOTTOMMARGIN=0.25, $
COMPONENT=Table_1, COMPONENT-TYPE=REPORT, POSITION=(0.104166 0.5625), DIMENSION=(* *), METADATA='VERSION:1.0;WIDTH:10.98958;HEIGHT:4.208333;LEFT:0.104166;TOP:0.5625;COMPONENTS_INCLUDED:ContractDate,SellAmt,BuyAmt,ExchRate,Received,TransDate,Pending,PayAmount,PayPending,Customer,StartDate,EndDate,Account,Join_1,Join_2,Join_3', $
OBJECT=IMAGE, NAME=PageItemImage_1, POSITION=(7.927083 0.28125), IMAGE=FIRMA_LOGO_PLUM_ENGLISH 250PX.JPG, DIMENSION=(2.604166 0.510416), $
END

-*COMPONENT=Join_J001
JOIN TRADES.TRADES.TRADEID IN TRADES
TO MULTIPLE VUNRECONCILEDTRANSACTIONS.VUNRECONCILEDTRANSACTIONS.TRADEID IN VUNRECONCILEDTRANSACTIONS TAG J001 AS J001
END
-*COMPONENT=Join_J002
JOIN TRADES.TRADES.BUYINGCURRENCYID IN TRADES
TO UNIQUE CURRENCIES.CURRENCIES.CURRENCYID IN CURRENCIES TAG J002 AS J002
END
-*COMPONENT=Join_J003
JOIN TRADES.TRADES.SELLINGCURRENCYID IN TRADES
TO UNIQUE CURRENCIES.CURRENCIES.CURRENCYID IN CURRENCIES TAG J003 AS J003
END
-*COMPONENT=Define_TRADES
DEFINE FILE TRADES
ContractDate/MDYY=HDATE ( TRADES.TRADES.BOOKEDON , 'MDYY' ) ;
SellAmt/D12.2C=TRADES.TRADES.SELLINGAMOUNT ;
BuyAmt/D12.2C=TRADES.TRADES.BUYINGAMOUNT ;
ExchRate/D10.4=TRADES.TRADES.EXCHANGERATE ;
Received/D12.2C=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS NOT MISSING THEN J001.VUNRECONCILEDTRANSACTIONS.MONEYIN ELSE 0 ;
TransDate/MDYY=HDATE ( J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE , 'MDYY' ) ;
Pending/D12.2C=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS MISSING THEN J001.VUNRECONCILEDTRANSACTIONS.MONEYIN ELSE 0 ;
PayAmount/D12.2CS=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS MISSING THEN 0 ELSE J001.VUNRECONCILEDTRANSACTIONS.MONEYOUT ;
PayPending/D12.2CS=IF J001.VUNRECONCILEDTRANSACTIONS.TRANSACTIONDATE IS MISSING THEN J001.VUNRECONCILEDTRANSACTIONS.MONEYOUT ELSE 0 ;
Customer/I9=TRADES.TRADES.CUSTOMERID ;
StartDate/MDYY=ContractDate ;
EndDate/MDYY=ContractDate ;
Account/I11=J001.VUNRECONCILEDTRANSACTIONS.CUSTOMERACCOUNT ;
END
SET COMPONENT=Table_1
-*component_type report
TABLE FILE TRADES
SUM Received AS 'Incoming,Settlement,Applied'
Pending
PayAmount AS 'Outgoing,Payment,Processed'
PayPending AS 'Pending'
BY Account NOPRINT SUBTOTAL 
BY J001.VUNRECONCILEDTRANSACTIONS.TRADEID AS 'Trade #'
BY ContractDate AS 'Trade Date,mm/dd/yyyy'
BY SellAmt AS 'Customer,Buys'
BY J002.CURRENCIES.CURRENCYCODE AS 'Buy,Curr'
BY BuyAmt AS 'Customer,Owes,FIRMA'
BY J003.CURRENCIES.CURRENCYCODE AS 'Owe,Curr'
BY ExchRate AS 'Exch,Rate'
BY TransDate AS 'Settlement,or Payment,Date'
WHERE Account EQ '&Account.Customer Account #: (ie 90037458).';
WHERE StartDate GE '&StartDate.Start Date: (mm/dd/yyyy).';
WHERE EndDate LE '&EndDate.End Date:.';
ON TABLE SUBHEAD
"Client: &Account - &Name:"
"Statement of Account for &StartDate to &EndDate"
ON TABLE SUBFOOT
"Run Date: &DATEtrM&DATED,&DATEYY "
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE SET HTMLCSS ON
ON TABLE SET HTMLENCODE ON
ON TABLE SET EMPTYREPORT ON
ON TABLE SET STYLE *
INCLUDE=IBFS:/CFG/FILE/IBI_HTML_DIR/javaassist/intl/EN/ENIADefault_combine.sty,$
TYPE=REPORT, ORIENTATION=LANDSCAPE, $
TYPE=TABHEADING, LINE=1, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=1, ITEM=1, OBJECT=TEXT, SIZE=14, STYLE=BOLD+ITALIC, $
TYPE=TABHEADING, LINE=2, JUSTIFY=LEFT, $
TYPE=TABHEADING, LINE=2, ITEM=1, OBJECT=TEXT, SIZE=14, STYLE=BOLD+ITALIC, $
TYPE=TABFOOTING, LINE=1, JUSTIFY=CENTER, $
TYPE=TABFOOTING, LINE=1, ITEM=1, OBJECT=TEXT, SIZE=8, STYLE=NORMAL, $
ENDSTYLE
END

COMPOUND END
 

I'm marking this as solved, but I still don't know how it was, so any insight is helpful for similar problems in the future.