[SOLVED] Adding a column

July 16, 2014, 03:42 AM

Hi

I like to add a column into the next code after car. Is there a way to do this?

The column is hardcoded say :

Norm
44000
34500

 
TABLE FILE CAR
SUM  CAR.BODY.SALES
BY  CAR.COMP.CAR
ACROSS  CAR.CARREC.MODEL
WHERE COUNTRY EQ 'JAPAN'
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
ENDSTYLE
END

This message has been edited. Last edited by: <Kathryn Henning>,

July 16, 2014, 04:11 AM

MichaelBalle

Something like this?

  
DEFINE FILE CAR
  NORM /A5 = IF (CAR EQ 'DATSUN') THEN '44000' ELSE '34500'
END
TABLE FILE CAR
SUM  
-*NORM AS 'Norm'
CAR.BODY.SALES
BY  CAR.COMP.CAR
ACROSS  CAR.CARREC.MODEL
WHERE COUNTRY EQ 'JAPAN'
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
ENDSTYLE
END

July 16, 2014, 04:24 AM

MrM

Hi,

If you uncommand NORM AS 'Norm' you get a NORM column for every CAR.
What I want to achieve is just one column at the beginning.

July 16, 2014, 06:19 AM

Wep5622

Simple enough, use a multi-verb request:

DEFINE FILE CAR
  NORM /A5 = IF (CAR EQ 'DATSUN') THEN '44000' ELSE '34500'
END
TABLE FILE CAR
SUM NORM AS 'Norm'
BY  CAR.COMP.CAR

SUM CAR.BODY.SALES
BY  CAR.COMP.CAR
ACROSS  CAR.CARREC.MODEL
WHERE COUNTRY EQ 'JAPAN'
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
ENDSTYLE
END

WebFOCUS 8.1.03, Windows 7-64/2008-64, IBM DB2/400, Oracle 11g & RDB, MS SQL-Server 2005, SAP, PostgreSQL 11, Output: HTML, PDF, Excel 2010
: Member of User Group Benelux :