Are there tables available which indicate which MRE reports appear on user lists?

Best wishes for the holidays, for 2013, for IBI and the Focus Nation.

This message has been edited. Last edited by: S.J. Kadish,

ntiko, not in 7.6 anyway.
but i do it, with code.
the MRE repositories tell me what group and therefore what domain each user has.
then for a domain, i read the domain.htm
yep, i write a temporary master , filedef it to the domain's .htm, and read it.
i'm looking for lines that contain 'MRFLAG' and omit 'hidden'...
Does that sound like too much to do? if so, say. if not, i'll help you write some code if you want, Sandy.

I'm sure that Francis posted a synonym for something like this many years ago ...

However, here's one that works on 7.6 onwards (I think )

$ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
$
$ Synonym Name:    mre_processes.mas
$
$ created By:      Anthony Alsford
$
$ Date Created:    5th March 2012
$
$ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 
FILE=MRE_processes, SUFFIX=FIX, $
$ -- Use filedef to identify required file DATASET='e:\ibi\basedir\director\director.htm'
$ -- to point to the relevant .htm file on your server
 
SEGNAME=MRE_LINE, SEGTYPE=S0, $
  FIELD=MRE_LINE, MRE_LINE, A300, A300, MISSING=OFF ,$
 
$ -- Determine standard folder name
DEFINE STD_FOLDER/A70V = IF MRE_LINE CONTAINS '<!--' THEN ''
                   ELSE IF MRE_LINE CONTAINS 'HREF' AND MRE_LINE OMITS '[*]' THEN GETTOK( GETTOK(MRE_LINE, 300, -2, '>', 70, 'A70'), 70, 1, '<', 70, 'A70V')
                   ELSE LAST STD_FOLDER;
 
$ -- Determine standard folder name HREF
DEFINE STD_FLDHREF/A70V = IF MRE_LINE CONTAINS '<!--' THEN ''
                   ELSE IF MRE_LINE CONTAINS 'HREF' AND MRE_LINE OMITS '[*]' THEN GETTOK(MRE_LINE, 300, 2, '''', 70, 'A70V')
                   ELSE LAST STD_FLDHREF;
 
$ -- Determine file name 
DEFINE FEX_HREF/A70V = IF MRE_LINE CONTAINS '<!--' THEN ''
                   ELSE IF STD_FOLDER EQ '' THEN ''
                   ELSE IF MRE_LINE CONTAINS 'HREF' AND MRE_LINE CONTAINS '[*]' THEN TRIMV('T', GETTOK(MRE_LINE, 300, 2, '''', 70, 'A70'), 70, ' ', 1, 'A70V')
                   ELSE '';
 
$ -- Determine descriptive name
DEFINE FEX_NAME/A70V = IF MRE_LINE CONTAINS '<!--' THEN ''
                   ELSE IF MRE_LINE CONTAINS 'HREF' AND MRE_LINE CONTAINS '[*]' THEN GETTOK(GETTOK(MRE_LINE, 300, -2, '>', 70, 'A70'), 70, 1, '<', 70, 'A70V')
                   ELSE LAST FEX_NAME;
 
$ -- Determine MR Flag(s)
DEFINE MRFLAG_START/I3 = POSIT(MRE_LINE, 300, 'MRFLAG=', 6, 'I3') + 8;
DEFINE MRFLAG/A70V = IF MRFLAG_START EQ 8 THEN '' ELSE TRIMV('T', GETTOK(SUBSTR(300, MRE_LINE, MRFLAG_START, MRFLAG_START+69, 70, 'A70'), 70 ,1 ,'''', 70, 'A70'), 70, ' ', 1, 'A70V');

T

so sweet!

Thanks so much. Not quite ready to close this.
All the best for the holidays and WebFocus 8.0

Thanks Sandy for the update and thanks for everyone's input, happy new year to all.

Sandy, please kindly keep us posted on the progress and the final solution, thanks.

Cheers,

Kerry