I can't seem to get the correct results for my maling labels. I am supposed to be returning 35 records, but I only get 1 record.

Here is my code:

SET ALL=ON
SET EMPTYREPORT=ON
SET NODATA=' '


TABLE FILE MAILING_LABELS_VIEW
LIST REL_SEI_CD
	MAILING_TYPE_DESCR
	RECIP_INTRO
	RECIP_FIRST_NM
	RECIP_LAST_NM
	RECIP_TITLE
	RECIP_OTHER_NM
	ADDR_LINE1
	ADDR_LINE2
	ADDR_CITY
	ADDR_STATE_PROV_SHORT_DESCR
	ADDR_POSTAL_CD
WHERE REL_SEI_CD EQ 'XCEL'
 AND ACCT_RECIP_ACTIVE_FL EQ 'Y';
 END
HOLD AS MLV 


TABLE FILE MLV
BY
     REL_SEI_CD NOPRINT
BY	MAILING_TYPE_DESCR NOPRINT
BY	RECIP_INTRO NOPRINT
BY	RECIP_FIRST_NM NOPRINT
BY	RECIP_LAST_NM NOPRINT
BY	RECIP_TITLE NOPRINT
BY	RECIP_OTHER_NM NOPRINT
BY	ADDR_LINE1 NOPRINT
BY	ADDR_LINE2 NOPRINT
BY	ADDR_CITY NOPRINT
BY	ADDR_STATE_PROV_SHORT_DESCR NOPRINT
BY	ADDR_POSTAL_CD NOPRINT

HEADING
"<25><MAILING_TYPE_DESCR"
"<RECIP_INTRO <RECIP_FIRST_NM <RECIP_LAST_NM"
"<RECIP_TITLE"
"<RECIP_OTHER_NM"
"<ADDR_LINE1"
"<ADDR_LINE2"
"<ADDR_CITY , <ADDR_STATE_PROV_SHORT_DESCR <ADDR_POSTAL_CD"
ON TABLE SET PAGE-NUM OFF
-*"<25><MAILING_TYPE_DESCR "
-*"<RECIP_INTRO <RECIP_FIRST_NM <RECIP_LAST_NM "
-*"<RECIP_TITLE "
-*"<RECIP_OTHER_NM "
-*"<ADDR_LINE1 "
-*"<ADDR_LINE2 "
-*"<ADDR_CITY , <ADDR_STATE_PROV_SHORT_DESCR <ADDR_POSTAL_CD "


ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     LEFTMARGIN=0.152778,
     RIGHTMARGIN=0.000000,
     TOPMARGIN=0.500000,
     BOTTOMMARGIN=0.000000,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
     PAGEMATRIX=(2 5),
     ELEMENT=(4.000000 2.000000),
     GUTTER=(0.180556 0.000000),
     MATRIXORDER=VERTICAL,
     LABELNAME=AVERY  5163 ADDRESS / SHIPPING,
     LABELPROMPT=OFF,
 $

ENDSTYLE
END

This message has been edited. Last edited by: Kerry,

If you take the HOLD off the first section...do you have all the records?

Negative. It seems LIST gives me the correct count of records but I can't get them to diplay on the page. I even tried using HTML using the example in the documentation. Has anyone had experience with Mailing Labels?

Thanks

Yes I believe List Verb is your problem and no by fields. Try using Print...and by fields...holding the file and then Use List.

Here's an example using the CAR file that is similar to what I have used for printing mailing labels.

SET PAGE-NUM=NOPAGE
-*
TABLE FILE CAR
PRINT
COMPUTE CNTR/I6 = CNTR + 1;
BY COUNTRY
BY CAR
BY MODEL
ON TABLE HOLD AS HLD_LBLS
END
-*
DEFINE FILE HLD_LBLS
CNT/I6 = 1;
T_LINE1/A30 = '******************************';
T_LINE2/A30 = 'CNT: ' | EDIT(CNTR);
T_LINE3/A30 = 'COU: ' | COUNTRY;
T_LINE4/A30 = 'CAR: ' | CAR;
T_LINE5/A30 = 'MOD: ' | MODEL;
T_LINE6/A30 = '******************************';
END
TABLE FILE HLD_LBLS
SUM CNT NOPRINT
SUM T_LINE1 AS ''
OVER T_LINE2 AS ''
OVER T_LINE3 AS ''
OVER T_LINE4 AS ''
OVER T_LINE5 AS ''
OVER T_LINE6 AS ''
BY CNTR NOPRINT
ON CNTR PAGE-BREAK
ON TABLE PAGE-BREAK AND SUBHEAD
" "
"FORUM827_MAIL_LBLS"
"&DATE"
"# OF LABELS: <CNT "
"THIS IS A TEST"
"ONE...TWO...THREE"
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
TYPE=REPORT,
UNITS=IN,
PAGESIZE='Letter',
LEFTMARGIN=0.152778,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.500000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
PAGEMATRIX=(2 5),
ELEMENT=(4.000000 2.000000),
GUTTER=(0.180556 0.000000),
MATRIXORDER=VERTICAL,
$
ENDSTYLE
END

Let me know if this helps.
Jim