Hey guys:
I'm at a complete loss as to what i could be doing wrong. I created a report in AHTML format with a drilldown link on the total line.

Now the drilldown link seems to work fine in HTML format but when i switch the format to AHTML, the total links are no longer active.

Also, if you switch the styling to

  TYPE=DATA

, the totals show up as they should in AHTML, but when you have

TYPE = GRANDTOTAL

, it no longer works.

Any ideas would be a great help. Thanks.

-DEFAULT &CAR = FOC_NONE;

TABLE FILE CAR
PRINT
COUNTRY
CAR
MODEL
DEALER_COST
RETAIL_COST
ON TABLE RECOMPUTE
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
$
TYPE=GRANDTOTAL,
	TARGET='_BLANK',
	DRILLMENUITEM = 'Cars',
	FOCEXEC=app/car.fex (
	CAR = &CAR.QUOTEDSTRING \
	),
$
END

This message has been edited. Last edited by: <Kathryn Henning>,

quote:

DRILLMENUITEM = 'Cars',

Try removing the DRILLMENUITEM clause - Active HTML reports are not capable of multi-drilldown.

Hey Francis:
The multi drilldown does in fact work with Active report format as I have it working in this same report on a column of data.

However i did take your suggestion and removed the multi drilldown from only the total line and the link is now working.

Why does multi drill work for a column of data but not for a total line in AHTML?

"multi drill work for a column of data" - I couldn't get this to work for a recent project. It may depend on the WebFOCUS version and hotfix...

We are on 7.7.03 hotfix 5 i believe. I was able to get the muti drilldown to work on a by column from the car file.

The multi drilldown options show up in the standard AHTML menu with the other options like 'highlight value' etc.

I just find it weird that a multi drilldown will work on a standard column of data but not work on a grandtotal line.

Any other ideas?

When I find something weird, I open a case with Tech Support. Then I report back here.

Cheers,

Yea, i just opened a ticket to see what the issue is.

Also asked a resident IBI contractor about it. Oddly enough no one here has tried it so it is a bit strange to everyone haha. I'll update once I hear back.

It appears this is a known issue in AHTML for drillable totals:

https://techsupport.informatio...oblems/82782538.html

I asked IBI if there was a status update for this problem.

Turn the Totals into it's own row:

  
-* File ahtml_rpt.fex
-SET &ECHO=ALL;
-DEFAULT &COUNTRY = 'FOC_NONE';
SET BYDISPLAY = ON, ASNAMES = ON
DEFINE FILE CAR
  XCOUNTRY/A10 = 'Total';
  XCAR/A16     = '';
END
TABLE FILE CAR
SUM
   RETAIL_COST
   DEALER_COST
  BY XCOUNTRY AS 'COUNTRY'
  BY XCAR     AS 'CAR'
 ON TABLE HOLD AS HOLD1
END
-RUN
TABLE FILE CAR
SUM
   RETAIL_COST
   DEALER_COST
  BY COUNTRY
  BY CAR
 ON TABLE HOLD AS HOLD2
END
-RUN
TABLE FILE HOLD1
PRINT
   RETAIL_COST
   DEALER_COST
  BY COUNTRY
  BY CAR
 ON TABLE HOLD AS HOLD3
MORE
FILE HOLD2
END
-RUN
DEFINE FILE HOLD3
 XSORT/A1 = IF COUNTRY EQ 'Total' THEN '2' ELSE '1';
END
TABLE FILE HOLD3
PRINT
   RETAIL_COST
   DEALER_COST
  BY XSORT NOPRINT
  BY COUNTRY
  BY CAR

ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
-*     INCLUDE = endeflt,
-*$
TYPE=REPORT,
     LINES-PER-PAGE=20,
$
TYPE=DATA,
     COLUMN=N2,
     TARGET='_blank',
	 DRILLMENUITEM = 'Drill to Detail',
     FOCEXEC=ahtml_rpt_drill( \
     COUNTRY=N2 \
     CAR=N3 \
     ),
$
ENDSTYLE
END
-EXIT

  
-* File ahtml_rpt_drill.fex
-SET &ECHO=ALL;
SET BYDISPLAY = ON
TABLE FILE CAR
SUM
   RETAIL_COST
   DEALER_COST
BY COUNTRY
BY CAR
WHERE COUNTRY EQ '&COUNTRY';
WHERE CAR     EQ '&CAR';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=REPORT,
     LINES-PER-PAGE=20,
$
ENDSTYLE
END
-EXIT

hth

Not a bad idea actually. I was also told to just do a foot with the prefix 'TOT' and hyperlink on that for the time being.

From a performance standpoint, i'd rather not have to pull the same data twice just to get a total line as these tables are rather large.

I'll try both ideas and see which one works best.

Thanks.

Oh heck, may as well since nobody else mentioned it . Let's try McGyver! Same output as Tom's but one pass:

-* Set up McGyver master and data file.
-*
-* Build McGyver MFD
FILEDEF MCMAS DISK MCGYV.MAS
-RUN
-WRITE MCMAS FILENAME=mcgyv, SUFFIX=FIX     , $
-WRITE MCMAS   SEGMENT=ONE, SEGTYPE=S0, $
-WRITE MCMAS     FIELDNAME=CONTROL, USAGE=A1, ACTUAL=A1, $
-WRITE MCMAS   SEGMENT=TWO, SEGTYPE=S0, PARENT=ONE, OCCURS=VARIABLE, $
-WRITE MCMAS     FIELDNAME=CHAR1, USAGE=A1, ACTUAL=A1, $
-WRITE MCMAS     FIELDNAME=CTR, ALIAS=ORDER, USAGE=I4, ACTUAL=I4, $
-*
-* Build McGyver FTM
FILEDEF MCGYV DISK MCGYV.FTM
-RUN
-* Control=X: used as Join cross reference target field
-* CHAR1=A, CTR=1: display detail
-* CHAR1=B, CTR=2: display dynamic subtotals/subfoots
-WRITE MCGYV XAB
-**************************************************************************************
-RUN
JOIN CONTROL WITH BODYTYPE IN CAR TO UNIQUE CONTROL IN MCGYV AS J2
-* CTR=1 display detail, CTR=2 display subtotals/subfoots.
DEFINE FILE CAR
CONTROL      /A1 WITH BODYTYPE='X';
SUM_COUNTRY  /A10 =IF CTR EQ 1 THEN COUNTRY ELSE 'Total';
SUM_CAR      /A18 =IF CTR EQ 1 THEN CAR     ELSE '';
END
-*******
SET BYDISPLAY=ON
TABLE FILE CAR
SUM RETAIL_COST
    DEALER_COST
BY CTR         NOPRINT
BY SUM_COUNTRY AS COUNTRY 
BY SUM_CAR     AS CAR
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET STYLE *
TYPE=DATA,
     COLUMN=P1,
     TARGET='_blank',
	 DRILLMENUITEM = 'Drill to Detail',
     FOCEXEC=ahtml_rpt_drill( \
     COUNTRY=P1 \
     CAR=P2 \
     ),$
ENDSTYLE
END

Mr. Dave Smith,
How the heck are you???
He had 11 posts, wasn't going to suggest McG so quickly.
Also, 1st pass get your Data, 2nd pass Summarize, JOIN 2nd to ALL 1st...

Whatever...

Hey Tom, hangin' in there, as you I'm sure! Yeah, I usually wait for a bakers dozen but I could help myself.