Hi all,

When running the procedure below and setting &FIELDNAME to UNITS (or any other non-alpha format field from GGSALES) it works just fine.

When setting &FIELDNAME to PRODUCT (or any alpha format field from GGSALES) I get an error
(FOC36355) INVALID TYPE OF ARGUMENT #2 FOR USER FUNCTION TRIMV

My assumption here is that when FLDINIT does equal 'A' that the statement would skip the 'THEN' portion and go straight to the 'ELSE' portion. Apparently that is not happening and it is trying to use the alpha field in the EDIT function which is where the error is created.

How can I get around this?

-SET &ECHO = ALL;

-DEFAULT &DATASOURCE=GGSALES;
-DEFAULT &FIELDNAME=UNITS;
-DEFAULT &BLOCKSIZE=100;
-DEFAULT &BLOCK=0;


TABLE FILE &DATASOURCE
  WRITE
    COMPUTE ROWNUM/I7 = LAST ROWNUM-(-1);
    COMPUTE BLOCK /I5 = 1-(-(INT((ROWNUM-1)/&BLOCKSIZE)));
  BY &FIELDNAME
ON TABLE HOLD AS FOCCACHE/HOLDKEYS
END
-RUN

CHECK FILE &DATASOURCE HOLD AS DS_HLD
TABLE FILE DS_HLD
SUM FST.FORMAT
WHERE FIELDNAME EQ '&FIELDNAME';
ON TABLE SAVE
END
-RUN

-READ SAVE &FLDTYPE.A8.


DEFINE FILE FOCCACHE/HOLDKEYS
FLDINIT/A1 = SUBSTR(8, '&FLDTYPE', 1, 1, 1, 'A1');

-*  The next line is where I get tripped up.  If &FIELDNAME is a non-alpha it works, if &FIELDNAME is alpha it breaks
FLDNAM/A99V = IF (FLDINIT NE 'A') THEN (TRIMV('L', EDIT(&FIELDNAME), 99, '0', 98, 'A99V')) ELSE ('&FIELDNAME');
-*  *****************************************************************************************************************

END

TABLEF FILE FOCCACHE/HOLDKEYS
 WRITE
 FST.ROWNUM AS LOROW
 LST.ROWNUM AS HIROW
 FST.&FIELDNAME   AS LOKEY
 LST.&FIELDNAME   AS HIKEY
 FST.FLDNAM
 LST.FLDNAM
 FLDINIT
COMPUTE RANGE/A99V =
   IF (LST.ROWNUM GT FST.ROWNUM)
   THEN FST.FLDNAM || ' ~ ' | LST.FLDNAM
   		ELSE FST.FLDNAM;
 BY BLOCK
ON TABLE SET HOLDLIST PRINTONLY AND ASNAMES ON
ON TABLE PCHOLD FORMAT HTML
END

Thanks!

Dan

This message has been edited. Last edited by: Dan Pinault,

Dan, the problem is caused by the EDIT(XXX) code - if the field is an alpha field, the EDIT tries to convert it to integer, but because the value (e.g. Atlanta) is not convertible to integer you get an error. The solution is to prepare for the TRIMV function in Dialogue Manager.

-SET &ECHO = ALL;

-DEFAULT &DATASOURCE=GGSALES;
-DEFAULT &FIELDNAME=CITY;
-DEFAULT &BLOCKSIZE=100;
-DEFAULT &BLOCK=0;

TABLE FILE &DATASOURCE
  WRITE
    COMPUTE ROWNUM/I7 = LAST ROWNUM-(-1);
    COMPUTE BLOCK /I5 = 1-(-(INT((ROWNUM-1)/&BLOCKSIZE)));
  BY &FIELDNAME
ON TABLE HOLD AS FOCCACHE/HOLDKEYS
END
-RUN

CHECK FILE &DATASOURCE HOLD AS DS_HLD
TABLE FILE DS_HLD
SUM FST.FORMAT
WHERE FIELDNAME EQ '&FIELDNAME';
ON TABLE SAVE
END
-RUN

-READ SAVE &FLDTYPE.A8.

-SET &FLDINIT = EDIT(&FLDTYPE,'9$');

-SET &XFIELD = IF (&FLDINIT NE 'A') THEN 'EDIT(&FIELDNAME.EVAL)' ELSE '&FIELDNAME.EVAL';

DEFINE FILE FOCCACHE/HOLDKEYS
FLDINIT/A1 = SUBSTR(8, '&FLDTYPE', 1, 1, 1, 'A1');
FLDNAM/A99V = (TRIMV('L', &XFIELD, 99, '0', 98, 'A99V'));
END

TABLEF FILE FOCCACHE/HOLDKEYS
 WRITE
 FST.ROWNUM AS LOROW
 LST.ROWNUM AS HIROW
 FST.&FIELDNAME   AS LOKEY
 LST.&FIELDNAME   AS HIKEY
FST.FLDNAM
LST.FLDNAM
 FLDINIT
COMPUTE RANGE/A99V =
  IF (LST.ROWNUM GT FST.ROWNUM)
  THEN FST.FLDNAM || ' ~ ' | LST.FLDNAM
  ELSE FST.FLDNAM;
BY BLOCK
ON TABLE SET HOLDLIST PRINTONLY AND ASNAMES ON
ON TABLE PCHOLD FORMAT HTML
END

quote:

My assumption here is that when FLDINIT does equal 'A' that the statement would skip the 'THEN' portion and go straight to the 'ELSE' portion. Apparently that is not happening and it is trying to use the alpha field in the EDIT function which is where the error is created.

The problem is that BEFORE ANY evaluation of fields takes place, the &vars are evaluated and then the syntax of the statement is checked before placing it on the FOCSTACK for execution. When &FIELDNAME is alpha, that makes the syntax invalid and throws your error before it even starts reading records to to see what the value of FLDINIT is.

Francis' suggestion is one way around it. His way makes sure that the statement that is sent for execution always contains valid syntax, regardless of what the format of the field value is.

Francis - Thanks for the solution!

Darin - Thanks for the explanation!

Cheers,

Dan