How do I get TITLE1 in the same row as ID s

SET ACROSSTITLE = SIDE
DEFINE FILE CAR
TEST/A100 = 'ID';
END
TABLE FILE CAR
SUM
DEALER_COST
OVER
RETAIL_COST
OVER
RPM
ACROSS COUNTRY NOPRINT
ACROSS TEST AS ''
ACROSS COUNTRY AS ''

ON TABLE SUBHEAD
"HEADING1"
""
""
HEADING
"HEADING2"
"TITLE1"
-*ON TABLE PCHOLD FORMAT EXL2K

ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
$
TYPE=REPORT,
     FONT='VERDANA',
     SIZE=9,
$
ENDSTYLE
END



  

This message has been edited. Last edited by: FP Mod Chuck,

I tried both your examples and it seems to me that the problem appears to be the use of OVER with ACROSS and ACROSSTITLE=SIDE.
Hence I thought of not using OVER, but simulating it:

  
DEFINE FILE CAR
-* Format all fields identically
DEALER_COST/D6=DEALER_COST;
RETAIL_COST/D6=RETAIL_COST;
RPM/D6=RPM;

-* Create labels for each field
TDCOST/A12='DEALER_COST';
TRCOST/A12='RETAIL_COST';
TRPM/A12='RPM';
END

TABLE FILE CAR
-* Output labels and values to a HOLD file
SUM TDCOST DEALER_COST TRCOST RETAIL_COST TRPM RPM
BY COUNTRY
ON TABLE HOLD AS GETIT FORMAT ALPHA
END
-RUN
-* Create an alternate master to the HOLD file, with 2 segments:
-* A parent segment for the country
-* A child segment for the occurences of label/value pairs
EX -LINES 7 EDAPUT MASTER,GETIT,C,MEM
 FILENAME=GETIT   , SUFFIX=FIX     
 SEGMENT=GETIT, SEGTYPE=S0
 FIELDNAME=COUNTRY, ALIAS=E01, USAGE=A10, ACTUAL=A10, $
 SEGMENT=VALS, PARENT=GETIT, SEGTYPE=S0, OCCURS=VARIABLE
 FIELDNAME=TFIELD, ALIAS=E02, USAGE=A12, ACTUAL=A12, $
 FIELDNAME=VALUE, ALIAS=E03, USAGE=D6, ACTUAL=A06, $
-RUN
-* Run the report from the HOLD file, the labels being a BY field, this simulates an OVER 
SET ACROSSTITLE = SIDE
DEFINE FILE GETIT
TEST/A100 = 'ID';
END
TABLE FILE GETIT
SUM VALUE
BY TFIELD AS ''
ACROSS COUNTRY NOPRINT
ACROSS TEST AS 'TITLE1'
ACROSS COUNTRY AS ' '

ON TABLE SUBHEAD
"HEADING1"
""
""
HEADING
"HEADING2"
ON TABLE SET HTMLCSS ON
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
$
TYPE=REPORT,
     FONT='VERDANA',
     SIZE=9,
$
ENDSTYLE
END
 

Good luck!

Thank you Danny. Your Solution works Great!!

You're welcome!