Good Morning. WF 7.0.3

Looking for help displaying the column total within a subgroup but not displaying the value in the grand total.

The column in question is "PCT.MY_COMPARE/D6.2% WITHIN MY_JUDGE2 WITHIN MO_NM AS '% Compare'".

I would like to show the sum of the values in "ON MY_JUDGE2 SUBTOTAL AS 'Total'" group.

I do not want it in the ON TABLE COLUMN-TOTAL section.

Thank you.

  
DEFINE FILE HOLD_JUDGE_COMPARE2
MY_REQUIRED/D6.2 = MY_CNT;
MY_COMPARE/D6.2 = MY_CNT;
END

TABLE FILE HOLD_JUDGE_COMPARE2
SUM
     PCT.MY_REQUIRED AS '% Required'
     MY_CNT/I8C AS '#'
     PCT.MY_COMPARE/D6.2%  WITHIN MY_JUDGE2 WITHIN MO_NM AS '% Compare'
BY  MY_JUDGE2 AS 'Judge Comparison'
BY  TASK_RSLT_RSN_DESC AS 'Judge'
ACROSS LOWEST MO_NM AS ''
ON MY_JUDGE2 SUBTOTAL AS  'Total'
ON TABLE SUBHEAD
""
HEADING
""
ON TABLE SET ACROSSPRT COMPRESS
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL PCT.MY_REQUIRED
ON TABLE COLUMN-TOTAL MY_CNT
ON TABLE SUMMARIZE AS 'Total Required' 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON

This message has been edited. Last edited by: Kathleen Butler,

Here is an example using the CAR item.

I would still like to sum the TOTINCOUNTRY within each COUNTRY....but not show it in the grand total.

Thanks.

 
DEFINE FILE CAR
RETAIL2/D6=RETAIL_COST;
END
 
TABLE FILE CAR
SUM 
     CAR.BODY.RETAIL2 NOPRINT 
BY  CAR.ORIGIN.COUNTRY
SUM 
     CAR.BODY.RETAIL_COST
     COMPUTE TOTINCOUNTRY/D10.4 = 100 * RETAIL_COST / RETAIL2;
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR
BY  CAR.CARREC.MODEL
     
ON CAR.ORIGIN.COUNTRY SUBTOTAL AS '*TOTAL'
ON TABLE COLUMN-TOTAL  RETAIL_COST
END

Well, I'm afraid that SUBTOTAL alone won't make it. So here is an example using SUBFOOT:

  
-* File Ubl01.fex
DEFINE FILE CAR
RETAIL2/D6=RETAIL_COST;
DUM/A1=' ';
END
 
TABLE FILE CAR
SUM 
     CAR.BODY.RETAIL2 NOPRINT 
BY DUM NOPRINT
BY  CAR.ORIGIN.COUNTRY
SUM 
     CAR.BODY.RETAIL_COST
     COMPUTE TOTINCOUNTRY/D10.4 = 100 * RETAIL_COST / RETAIL2;
BY DUM NOPRINT
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR
BY  CAR.CARREC.MODEL
ON TABLE NOTOTAL     
ON CAR.ORIGIN.COUNTRY SUBTOTAL AS '*TOTAL'
ON DUM SUBFOOT
"**GRAND TOTAL<CT.RETAIL_COST "
ON TABLE SET STYLE *
TYPE=SUBFOOT, HEADALIGN=BODY, $
TYPE=SUBFOOT, BY=DUM, ITEM=2, COLSPAN=3, JUSTIFY=RIGHT, $
ENDSTYLE
END

Thank you. It works.