Is there a[n easy] way to get a list of files (fex & html) that reside on the EDASERVE that use SQL pass-thru?
I tried logging into the server and just doing a Windows search, but all I get are html files, none of the fex files, and I know there are a bunch.

Thanks,
Deb

This message has been edited. Last edited by: DWaybright,

Deb

There is a free download called Windows GREP that will allow you to search for strings of data at a directory level. I think you can do the same with Notepad ++ as well

Windows GREP is still around? I haven't used that in ages! I'll look for it.
Thanks!

Windows GREP is part of GNU Utilities

If you are in a hurry or are not allowed to install grep, Windows has the findstr command. For example:

findstr /i /n /s "sqlmss" c:\ibi\apps\*.fex 

Learn about all the options with:

findstr /? 

This looks like a good resource for findstr undocumented features

This message has been edited. Last edited by: dbeagan,

dbeagan - That's what I ended up using. Thanks for posting!

This is great and I can see this working on CMD console, but how did you end up using via Table FILE as a report?
Thanks!

I did something like this:

-DEFAULT &File  = '*';
-DEFAULT &Ext   = 'fex';
-DEFAULT &Find  = 'while';
-DEFAULT &Case  = 'ignore';
-SET     &Mesg  = IF &Find EQ 'FOC_NONE' THEN ' '  ELSE 'Found: ' | &Find;
-SET     &Icase = IF &Case EQ 'ignore'   THEN '/i' ELSE ' ';
-SET     &dlm   = CHAR(255);
 
!findstr &Icase/n/s /c:"&Find" c:\ibi\apps\&File..&Ext > list.txt
 
 FILEDEF list   DISK list.txt
 FILEDEF master DISK list.mas
-RUN
 
-WRITE master FILENAME=LIST, SUFFIX=DFIX, $
-WRITE master  SEGMENT=LIST, SEGTYPE=S0,  $
-WRITE master   FIELD=Record, , A300, A300, $
-WRITE master   FIELD=DELIMITER, ALIAS='&dlm', A1, A1,$
 
 SET PAGE=NOLEAD,LINES=998
 
 DEFINE FILE list
 Pathfile/A200 = TOKEN(Record,':',1) | ':' | TOKEN(Record,':',2);
 Line/A10      = TOKEN(Record,':',3);
 length/I11    = CHAR_LENGTH(RTRIM(Pathfile)) + CHAR_LENGTH(RTRIM(Line));
 Found/A200V   = SUBSTRING(Record, length+3, 200);
 File/A100     = TOKEN(Pathfile,'\',-1);
 Posit/I9      = POSITION(File, Pathfile);
 Path/A200     = SUBSTRING(Pathfile, 1, Posit-1);
 END
 
 TABLE FILE list
   PRINT File
         Found    AS '&Mesg' 
      BY Path      
      BY Pathfile NOPRINT
 ON TABLE SET STYLE *
 TYPE=REPORT, FONT=CONSOLAS, $
 TYPE=DATA, COLUMN=N, SIZE=11, COLOR=SILVER, $
 TYPE=DATA, BACKCOLOR=(RGB(248 248 248) WHITE), BORDER=LIGHT, BORDER-COLOR=RGB(240 240 240), $
 ENDSTYLE
 END