I have a focexec that creates a report that has formatting similar to what the code below produces. How do I get the vertical borders in the column total line, as an extension of the borders in the data lines?

TABLE FILE EMPDATA
SUM
     CNT.PIN
     SALARY
     CNT.PIN
     SALARY
     CNT.PIN
     SALARY
     CNT.PIN
     SALARY
BY DIV
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
TYPE=DATA,
     COLUMN=N1,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N2,
     BORDER-LEFT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N3,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N4,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N5,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N6,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N7,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N8,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N9,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=TITLE,
     COLUMN=N1,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N2,
     BORDER-LEFT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N3,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
$
TYPE=TITLE,
     COLUMN=N4,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N5,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
$
TYPE=TITLE,
     COLUMN=N6,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N7,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
$
TYPE=TITLE,
     COLUMN=N8,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N9,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
     COLOR='NAVY',
     STYLE=BOLD,
$
ENDSTYLE
END
 

John,

See below:

  
TABLE FILE CAR
PRINT SALES RCOST DCOST
BY COUNTRY BY BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE COLUMN-TOTAL
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, BORDER=LIGHT, $
ENDSTYLE
END

This puts borders everywhere. Maybe you need to explicitly code "grid=off" in your fex.

Thank you Daniel.

However, I want only vertical borders on the right side of specific columns, and no horizontal or left borders. Getting this on the data lines is the easy part. I need to be able to continue those vertical border lines down into the column total line.

John

John,

See the two following examples.

Ex 1:

  
TABLE FILE CAR
PRINT SALES RCOST DCOST
BY COUNTRY BY BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE COLUMN-TOTAL AS Total
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$
TYPE=REPORT, BORDER-RIGHT=LIGHT, $
ENDSTYLE
END

Here you will have right borders on all fields and they continue down to the total.

Ex 2:

  
TABLE FILE CAR
PRINT SALES RCOST DCOST
BY COUNTRY BY BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE COLUMN-TOTAL AS Total
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$
TYPE=REPORT, COLUMN=SALES, BORDER-RIGHT=LIGHT, $
TYPE=REPORT, COLUMN=DCOST, BORDER-RIGHT=LIGHT, $
ENDSTYLE
END

Here you have the border on only the SALES and the DCOST fields, but you will see that there is an interruption before the total line.
I suggest you open a case with IBI.

BTW are you at the summit. If so, we can meet.

Thank you, Daniel! This is exactly what I'm looking for. No problem with the interruption before the total line. I think in some cases it improves the readability of the report.

No, I'm not at Summit. Maybe next year.

Regards,

John